Определяет API поставщика, загружающего конфигурацию во время запуска.

Поставщики конфигурации обычно используются во время релизов для загрузки внешней конфигурации во время запуска системы. Это делается путем запуска VM с минимальным количеством работающих приложений, затем вызовом всех поставщиков и перезапуском системы. Это требует изменяемого конфигурационного файла на диске, так как результаты работы поставщиков записываются в файловую систему. Более подробную информацию о конфигурации во время выполнения см. на странице mix release.

Множественные файлы конфигурации

Одно из распространенных применений поставщиков конфигурации — указание нескольких файлов конфигурации в релизе. Elixir поставляется с одним поставщиком, называемым Config.Reader, который способен обрабатывать встроенные файлы конфигурации Elixir.

Например, предположим, что вы хотите вывести некоторую основную конфигурацию в встроенном файле config/runtime.exs Mix, но также хотите поддерживать дополнительные файлы конфигурации. Для этого можно добавить это в раздел def project вашего mix.exs.

releases: [
  demo: [
    config_providers: [
      {Config.Reader, {:system, "RELEASE_ROOT", "/extra_config.exs"}}
    ]
  ]
]

Вы можете разместить этот extra_config.exs файл в релизе несколькими способами:

1. Если он доступен на хосте при сборке релиза, вы можете разместить его в "rel/overlays/extra_config.exs", и он будет автоматически скопирован в корень релиза.

2. Если он доступен на целевом сервере во время развертывания, вы можете просто скопировать его в корень релиза как шаг в процессе развертывания.

Теперь после запуска системы она загрузит как config/runtime.exs, так и extra_config.exs на ранней стадии процесса запуска. Более подробную информацию о других возможностях можно найти на странице Config.Reader.

Настройка пользовательского поставщика конфигурации

Вы также можете реализовать пользовательских поставщиков конфигурации, аналогично тому, как работает Config.Reader. Например, представьте, что вам нужно загрузить некоторую конфигурацию из файла JSON и загрузить ее в систему. Такой поставщик конфигурации будет выглядеть следующим образом:

defmodule JSONConfigProvider do
  @behaviour Config.Provider

  # Let's pass the path to the JSON file as config
  @impl true
  def init(path) when is_binary(path), do: path

  @impl true
  def load(config, path) do
    # We need to start any app we may depend on.
    {:ok, _} = Application.ensure_all_started(:jason)

    json = path |> File.read!() |> Jason.decode!()

    Config.Reader.merge(
      config,
      my_app: [
        some_value: json["my_app_some_value"],
        another_value: json["my_app_another_value"],
      ]
    )
  end
end

Затем при указании релиза вы можете указать поставщика в конфигурации релиза:

releases: [
  demo: [
    config_providers: [
      {JSONConfigProvider, "/etc/config.json"}
    ]
  ]
]