OptionParser

Функции для разбора параметров командной строки.

Основной функцией в этом модуле является parse/2, которая позволяет разработчикам разбить список аргументов на параметры:

iex> OptionParser.parse(["--debug"], strict: [debug: :boolean])
{[debug: true], [], []}

OptionParser предоставляет некоторые удобства «из коробки», такие как псевдонимы и автоматическая обработка переключателей отрицания.

Функция parse_head/2 является альтернативой parse/2, которая останавливает разбор, как только находит значение, которое не является переключателем ни значением для предыдущего переключателя.

Этот модуль также предоставляет функции низкого уровня, такие как next/2, для ручного разбора переключателей, а также split/1 и to_argv/1 для разбора из строк и преобразования переключателей в строки.

Краткое описание

Типы

argv()

errors()

options()

parsed()

Функции

next(argv, opts \\ [])

Функция низкого уровня, которая разбирает один параметр.

parse(argv, opts \\ [])

Разбирает argv в список ключевых слов.

parse!(argv, opts \\ [])

То же самое, что и parse/2, но вызывает исключение OptionParser.ParseError, если указаны какие-либо недопустимые параметры.

parse_head(argv, opts \\ [])

Аналогично parse/2, но анализирует только начало argv; как только находит параметр, не являющийся переключателем, прекращает разбор.

parse_head!(argv, opts \\ [])

То же самое, что и parse_head/2, но вызывает исключение OptionParser.ParseError, если указаны какие-либо недопустимые параметры.

split(string)

Разделяет строку на фрагменты argv/0.

to_argv(enum, options \\ [])

Принимает перечислимую по ключу-значению и преобразует ее в argv/0.

Типы

argv()

argv() :: [String.t()]

errors()

errors() :: [{String.t(), String.t() | nil}]

options()

options() :: [switches: keyword(), strict: keyword(), aliases: keyword()]

parsed()

parsed() :: keyword()

Функции

next(argv, opts \\ [])

next(argv(), options()) ::
  {:ok, key :: atom(), value :: term(), argv()}
  | {:invalid, String.t(), String.t() | nil, argv()}
  | {:undefined, String.t(), String.t() | nil, argv()}
  | {:error, argv()}

Функция низкого уровня, которая разбирает один параметр.

Она принимает те же параметры, что и parse/2 и parse_head/2, так как обе функции построены на этой функции. Эта функция может вернуть:

• {:ok, key, value, rest} - параметр key с value был успешно разобран

• {:invalid, key, value, rest} - параметр key некорректен с value (возвращается, когда значение не может быть обработано в соответствии с типом переключателя)

• {:undefined, key, value, rest} - параметр key не определен (возвращается в строгом режиме, когда переключатель неизвестен или отсутствует в атомах)

• {:error, rest} - в начале заданных argv нет переключателей

parse(argv, opts \\ [])

parse(argv(), options()) :: {parsed(), argv(), errors()}

Разбирает argv в список ключевых слов.

Возвращает кортеж из трех элементов вида {parsed, args, invalid}, где:

• parsed — это список ключевых слов обработанных переключателей со вложенными кортежами {switch_name, value}; switch_name — это атом, представляющий имя переключателя, а value — это значение для этого переключателя, разобранное в соответствии с opts (см. раздел «Примеры» для получения дополнительной информации)
• args — это список оставшихся аргументов в argv в виде строк
• invalid — это список недопустимых параметров в виде {option_name, value}, где option_name — это исходный параметр, а value — это nil , если параметр не ожидался, или строковое значение, если значение не имело ожидаемого типа для соответствующего параметра

Elixir преобразует переключатели в атомы с подчеркиванием, поэтому --source-path становится :source_path. Это сделано для лучшего соответствия соглашениям Elixir. Однако это означает, что переключатели не могут содержать подчеркивания, а переключатели, содержащие подчеркивания, всегда возвращаются в списке недопустимых переключателей.

При разборе обычно указываются переключатели и их ожидаемые типы:

iex> OptionParser.parse(["--debug"], strict: [debug: :boolean])
{[debug: true], [], []}

iex> OptionParser.parse(["--source", "lib"], strict: [source: :string])
{[source: "lib"], [], []}

iex> OptionParser.parse(
...>   ["--source-path", "lib", "test/enum_test.exs", "--verbose"],
...>   strict: [source_path: :string, verbose: :boolean]
...> )
{[source_path: "lib", verbose: true], ["test/enum_test.exs"], []}

Мы рассмотрим допустимые переключатели и режимы работы парсера параметров ниже.

Параметры

Поддерживаются следующие параметры:

• :switches или :strict — см. раздел «Определения переключателей» ниже
• :allow_nonexistent_atoms — см. раздел «Разбор неизвестных переключателей» ниже
• :aliases — см. раздел «Псевдонимы» ниже

Определения переключателей

Переключатели могут быть заданы одним из двух способов:

• :strict — определяет строгие переключатели. Любой переключатель в argv , который не указан в списке, возвращается в списке недопустимых параметров.
• :switches — определяет некоторые переключатели и их типы. Эта функция по-прежнему пытается разобрать переключатели, которые не указаны в этом списке.

Оба этих параметра принимают список ключевых слов, где ключ — это атом, определяющий имя переключателя, а значение — type переключателя (см. раздел «Типы» ниже для получения дополнительной информации).

Обратите внимание, что вы должны указать только параметр :switches или параметр :strict . Если вы укажете оба параметра, будет вызвано исключение ArgumentError.

Типы

Переключатели, разобранные OptionParser, могут принимать ноль или один аргумент.

Следующие типы переключателей не принимают аргументов:

• :boolean — задает значение true при указании (см. также раздел «Переключатели отрицания» ниже)
• :count — подсчитывает количество раз, когда задается переключатель

Следующие переключатели принимают один аргумент:

• :integer — разбирает значение как целое число
• :float — разбирает значение как число с плавающей запятой
• :string — разбирает значение как строку

Если переключатель не может быть разобран в соответствии с заданным типом, он возвращается в списке недопустимых параметров.

Модификаторы

Переключатели могут быть заданы с модификаторами, которые изменяют их поведение. Поддерживаются следующие модификаторы:

• :keep — сохраняет дублированные элементы вместо их перезаписи; работает со всеми типами, кроме :count. Указание switch_name: :keep предполагает, что тип :switch_name будет :string.

Чтобы использовать :keep с типом, отличным от :string, используйте список в качестве типа для переключателя. Например: [foo: [:integer, :keep]].

Переключатели отрицания

В случае, если переключатель SWITCH задан с типом :boolean, он может быть передан и как --no-SWITCH, что установит параметр в false.

iex> OptionParser.parse(["--no-op", "path/to/file"], switches: [op: :boolean])
{[op: false], ["path/to/file"], []}

Разбор неизвестных переключателей

Когда задан параметр :switches , OptionParser попытается разобрать неизвестные переключатели:

iex> OptionParser.parse(["--debug"], switches: [key: :string])
{[debug: true], [], []}

Несмотря на то, что мы не указали --debug в списке переключателей, он является частью возвращаемых параметров. Это также сработает:

iex> OptionParser.parse(["--debug", "value"], switches: [key: :string])
{[debug: "value"], [], []}

Переключатели, за которыми следует значение, будут назначены значение, как строка. Переключатели без аргумента будут автоматически установлены в true. Поскольку мы не можем утверждать тип значения переключателя, предпочтительнее использовать параметр :strict , который принимает только известные переключатели и всегда проверяет их типы.

Если вы хотите разобрать неизвестные переключатели, помните, что Elixir преобразует переключатели в атомы. Поскольку атомы не собираются мусором, OptionParser будет анализировать только те переключатели, которые преобразуются в атомы, используемые во время выполнения, чтобы избежать утечек атомов. Например, код ниже отбросит переключатель --option-parser-example , потому что атом :option_parser_example нигде не используется:

OptionParser.parse(["--option-parser-example"], switches: [debug: :boolean])
# The :option_parser_example atom is not used anywhere below

Однако код ниже сработает, если атом :option_parser_example используется где-то позже (или раньше) в том же модуле:

{opts, _, _} = OptionParser.parse(["--option-parser-example"], switches: [debug: :boolean])
opts[:option_parser_example]

Другими словами, Elixir сделает правильную вещь и проанализирует только те параметры, которые используются во время выполнения, игнорируя все остальные. Если вы хотите проанализировать все переключатели, независимо от их наличия, вы можете принудительно создать атомы, передав allow_nonexistent_atoms: true в качестве параметра. Используйте этот параметр с осторожностью. Он полезен только при создании приложений командной строки, которые получают динамические имена аргументов, и должен быть избегаем в долгоживущих системах.

Псевдонимы

Набор псевдонимов может быть указан в параметре :aliases:

iex> OptionParser.parse(["-d"], aliases: [d: :debug], strict: [debug: :boolean])
{[debug: true], [], []}

Примеры

Вот несколько примеров работы с различными типами и модификаторами:

iex> OptionParser.parse(["--unlock", "path/to/file"], strict: [unlock: :boolean])
{[unlock: true], ["path/to/file"], []}

iex> OptionParser.parse(
...>   ["--unlock", "--limit", "0", "path/to/file"],
...>   strict: [unlock: :boolean, limit: :integer]
...> )
{[unlock: true, limit: 0], ["path/to/file"], []}

iex> OptionParser.parse(["--limit", "3"], strict: [limit: :integer])
{[limit: 3], [], []}

iex> OptionParser.parse(["--limit", "xyz"], strict: [limit: :integer])
{[], [], [{"--limit", "xyz"}]}

iex> OptionParser.parse(["--verbose"], switches: [verbose: :count])
{[verbose: 1], [], []}

iex> OptionParser.parse(["-v", "-v"], aliases: [v: :verbose], strict: [verbose: :count])
{[verbose: 2], [], []}

iex> OptionParser.parse(["--unknown", "xyz"], strict: [])
{[], ["xyz"], [{"--unknown", nil}]}

iex> OptionParser.parse(
...>   ["--limit", "3", "--unknown", "xyz"],
...>   switches: [limit: :integer]
...> )
{[limit: 3, unknown: "xyz"], [], []}

iex> OptionParser.parse(
...>   ["--unlock", "path/to/file", "--unlock", "path/to/another/file"],
...>   strict: [unlock: :keep]
...> )
{[unlock: "path/to/file", unlock: "path/to/another/file"], [], []}

parse!(argv, opts \\ [])

parse!(argv(), options()) :: {parsed(), argv()}

То же самое, что и parse/2, но вызывает исключение OptionParser.ParseError, если указаны какие-либо недопустимые параметры.

Если ошибок нет, возвращает кортеж {parsed, rest}, где:

• parsed — список обработанных ключей (так же, как и в parse/2)
• rest — список аргументов (так же, как и в parse/2)

Примеры

iex> OptionParser.parse!(["--debug", "path/to/file"], strict: [debug: :boolean])
{[debug: true], ["path/to/file"]}

iex> OptionParser.parse!(["--limit", "xyz"], strict: [limit: :integer])
** (OptionParser.ParseError) 1 error found!
--limit : Expected type integer, got "xyz"

iex> OptionParser.parse!(["--unknown", "xyz"], strict: [])
** (OptionParser.ParseError) 1 error found!
--unknown : Unknown option

iex> OptionParser.parse!(
...>   ["-l", "xyz", "-f", "bar"],
...>   switches: [limit: :integer, foo: :integer],
...>   aliases: [l: :limit, f: :foo]
...> )
** (OptionParser.ParseError) 2 errors found!
-l : Expected type integer, got "xyz"
-f : Expected type integer, got "bar"

parse_head(argv, opts \\ [])

parse_head(argv(), options()) :: {parsed(), argv(), errors()}

Аналогично parse/2, но анализирует только начало argv; как только находит не ключ, прекращает анализ.

См. parse/2 для получения дополнительной информации.

Пример

iex> OptionParser.parse_head(
...>   ["--source", "lib", "test/enum_test.exs", "--verbose"],
...>   switches: [source: :string, verbose: :boolean]
...> )
{[source: "lib"], ["test/enum_test.exs", "--verbose"], []}

iex> OptionParser.parse_head(
...>   ["--verbose", "--source", "lib", "test/enum_test.exs", "--unlock"],
...>   switches: [source: :string, verbose: :boolean, unlock: :boolean]
...> )
{[verbose: true, source: "lib"], ["test/enum_test.exs", "--unlock"], []}

parse_head!(argv, opts \\ [])

parse_head!(argv(), options()) :: {parsed(), argv()}

То же, что и parse_head/2, но вызывает исключение OptionParser.ParseError, если указаны какие-либо недопустимые параметры.

Если ошибок нет, возвращает кортеж {parsed, rest}, где:

• parsed — список обработанных ключей (так же, как и в parse_head/2)
• rest — список аргументов (так же, как и в parse_head/2)

Примеры

iex> OptionParser.parse_head!(
...>   ["--source", "lib", "path/to/file", "--verbose"],
...>   switches: [source: :string, verbose: :boolean]
...> )
{[source: "lib"], ["path/to/file", "--verbose"]}

iex> OptionParser.parse_head!(
...>   ["--number", "lib", "test/enum_test.exs", "--verbose"],
...>   strict: [number: :integer]
...> )
** (OptionParser.ParseError) 1 error found!
--number : Expected type integer, got "lib"

iex> OptionParser.parse_head!(
...>   ["--verbose", "--source", "lib", "test/enum_test.exs", "--unlock"],
...>   strict: [verbose: :integer, source: :integer]
...> )
** (OptionParser.ParseError) 2 errors found!
--verbose : Missing argument of type integer
--source : Expected type integer, got "lib"

split(string)

split(String.t()) :: argv()

Разделяет строку на фрагменты argv/0.

Эта функция разделяет заданную string на список строк аналогично многим оболочкам.

Примеры

iex> OptionParser.split("foo bar")
["foo", "bar"]

iex> OptionParser.split("foo \"bar baz\"")
["foo", "bar baz"]

to_argv(enum, options \\ [])

to_argv(Enumerable.t(), options()) :: argv()

Принимает перечисляемый объект ключ-значение и преобразует его в argv/0.

Ключи должны быть атомами. Ключи со значением nil игнорируются, булевые значения преобразуются в --key или --no-key (если значение соответственно true или false ), а все остальные значения преобразуются с помощью Kernel.to_string/1.

Рекомендуется передавать в to_argv/2 тот же набор options , что и в parse/2. Некоторые ключи могут быть корректно реконструированы только с информацией о :switches.

Примеры

iex> OptionParser.to_argv(foo_bar: "baz")
["--foo-bar", "baz"]
iex> OptionParser.to_argv(bool: true, bool: false, discarded: nil)
["--bool", "--no-bool"]

Некоторые ключи будут выдавать разные значения в зависимости от типа ключей:

iex> OptionParser.to_argv([number: 2], switches: [])
["--number", "2"]
iex> OptionParser.to_argv([number: 2], switches: [number: :count])
["--number", "--number"]