Характеристики

break(binary()) :: doc_break()

Возвращает документ перевода строки на основе заданного string.

Этот перевод строки может быть отображён как перевод строки или как заданное string, в зависимости от mode выбранного макета.

Примеры

Давайте создадим документ, конкатенировав две строки с переводами строк между ними:

iex> doc = Inspect.Algebra.concat(["a", Inspect.Algebra.break("\t"), "b"])
iex> Inspect.Algebra.format(doc, 80)
["a", "\t", "b"]

Обратите внимание, что перевод строки был представлен заданной строкой, потому что предел строки не был достигнут. Как только он будет достигнут, он заменяется новой строкой:

iex> break = Inspect.Algebra.break("\t")
iex> doc = Inspect.Algebra.concat([String.duplicate("a", 20), break, "b"])
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 10)
["aaaaaaaaaaaaaaaaaaaa", "\n", "b"]

Характеристики

collapse_lines(pos_integer()) :: doc_collapse()

Сжимает все новые строки и пробелы после этого узла, выводя до max новых строк.

Характеристики

color(t(), Inspect.Opts.color_key(), Inspect.Opts.t()) :: doc_color()

Окрашивает документ, если в параметрах есть цвет для color_key.

Характеристики

concat([t()]) :: t()

Конкатенирует список документов, возвращая новый документ.

Примеры

iex> doc = Inspect.Algebra.concat(["a", "b", "c"])
iex> Inspect.Algebra.format(doc, 80)
["a", "b", "c"]

Характеристики

concat(t(), t()) :: t()

Конкатенирует два документа, возвращая новый документ.

Примеры

iex> doc = Inspect.Algebra.concat("hello", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", "world"]

Характеристики

container_doc(
  t(),
  [any()],
  t(),
  Inspect.Opts.t(),
  (term(), Inspect.Opts.t() -> t()),
  keyword()
) :: t()

Оборачивает collection в left и right в соответствии с лимитом и содержимым.

Использует предоставленные документы left и right в качестве окружающих, а документ-разделитель separator для разделения элементов в docs. Если все записи в коллекции являются простыми документами (текстами или строками), функция пытается поместить как можно больше элементов в одну строку. Если они не простые, отображается только по одной записи на строку, если они не помещаются.

Учитывается ограничение в заданном inspect_opts, и при его достижении функция прекращает обработку и выводит "...".

Параметры

• :separator - разделитель между каждым документом
• :break - Если :strict, всегда переносит строку между каждым элементом. Если :flex, переносит строку только при необходимости. Если :maybe, выбирает :flex только если все элементы текстовые, в противном случае :strict

Примеры

iex> inspect_opts = %Inspect.Opts{limit: :infinity}
iex> fun = fn i, _opts -> to_string(i) end
iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]", inspect_opts, fun)
iex> Inspect.Algebra.format(doc, 5) |> IO.iodata_to_binary()
"[1,\n 2,\n 3,\n 4,\n 5]"

iex> inspect_opts = %Inspect.Opts{limit: 3}
iex> fun = fn i, _opts -> to_string(i) end
iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]", inspect_opts, fun)
iex> Inspect.Algebra.format(doc, 20) |> IO.iodata_to_binary()
"[1, 2, 3, ...]"

iex> inspect_opts = %Inspect.Opts{limit: 3}
iex> fun = fn i, _opts -> to_string(i) end
iex> opts = [separator: "!"]
iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]", inspect_opts, fun, opts)
iex> Inspect.Algebra.format(doc, 20) |> IO.iodata_to_binary()
"[1! 2! 3! ...]"

Характеристики

empty() :: :doc_nil

Возвращает сущность документа, используемую для представления пустоты.

Примеры

iex> Inspect.Algebra.empty()
:doc_nil

Характеристики

flex_break(binary()) :: doc_break()

Возвращает документ гибкого перевода строки на основе заданного string.

Гибкий перевод строки всё ещё вызывает разрыв группы, как в break/1, но переоценивается при рендеринге документа.

Например, рассмотрим документ группы, представленный как [1, 2, 3] , где пробел после каждой запятой — это перевод строки. Когда документ выше не помещается на одной строке, все переводы строк активируются, что приводит к рендерингу документа как:

[1,
 2,
 3]

Однако, если используются гибкие переводы строк, каждый перевод строки переоценивается при рендеринге, поэтому документ может быть отображён как:

[1, 2,
 3]

Отсюда и название «гибкий». Они более гибкие, когда дело доходит до размещения документа. С другой стороны, они дороже, поскольку каждый перевод строки должен быть переоценён.

Эта функция используется в container_doc/6 и других, чтобы максимизировать количество записей в одной строке.

Характеристики

flex_glue(t(), binary(), t()) :: t()

Соединяет два документа (doc1 и doc2) вставляя flex_break/1, заданный break_string между ними.

Эта функция используется в container_doc/6 и других, чтобы максимизировать количество записей в одной строке.

Характеристики

fold_doc([t()], (t(), t() -> t())) :: t()

Складывает список документов в документ с помощью заданной функции слияния.

Список документов складывается «справа»; в этом смысле эта функция похожа на List.foldr/3, за исключением того, что она не ожидает начального накопителя и использует последний элемент docs в качестве начального накопителя.

Примеры

iex> docs = ["A", "B", "C"]
iex> docs =
...>   Inspect.Algebra.fold_doc(docs, fn doc, acc ->
...>     Inspect.Algebra.concat([doc, "!", acc])
...>   end)
iex> Inspect.Algebra.format(docs, 80)
["A", "!", "B", "!", "C"]

Характеристики

force_unfit(t()) :: doc_force()

Принудительно делает текущую группу непригодной.

Характеристики

format(t(), non_neg_integer() | :infinity) :: iodata()

Форматирует данный документ для заданной ширины.

Принимает максимальную ширину и документ для вывода в качестве аргументов и возвращает представление данных ввода-вывода лучшей компоновки для размещения документа в заданной ширине.

Документ начинается плоским (без переносов) до тех пор, пока не будет найдена группа.

Примеры

iex> doc = Inspect.Algebra.glue("hello", " ", "world")
iex> doc = Inspect.Algebra.group(doc)
iex> doc |> Inspect.Algebra.format(30) |> IO.iodata_to_binary()
"hello world"
iex> doc |> Inspect.Algebra.format(10) |> IO.iodata_to_binary()
"hello\nworld"

Характеристики

glue(t(), binary(), t()) :: t()

Присоединяет два документа (doc1 и doc2) вставляя заданный разрыв break_string между ними.

Подробнее о том, как вставляется разрыв, см. break/1.

Примеры

iex> doc = Inspect.Algebra.glue("hello", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", " ", "world"]

iex> doc = Inspect.Algebra.glue("hello", "\t", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", "\t", "world"]

Характеристики

group(t(), :self | :inherit) :: doc_group()

Возвращает группу, содержащую указанный документ doc.

Документы в группе пытаются отображаться вместе, насколько это возможно.

Режим группы также может быть установлен на :inherit, что означает автоматический разрыв, если родительская группа также разорвана.

Примеры

iex> doc =
...>   Inspect.Algebra.group(
...>     Inspect.Algebra.concat(
...>       Inspect.Algebra.group(
...>         Inspect.Algebra.concat(
...>           "Hello,",
...>           Inspect.Algebra.concat(
...>             Inspect.Algebra.break(),
...>             "A"
...>           )
...>         )
...>       ),
...>       Inspect.Algebra.concat(
...>         Inspect.Algebra.break(),
...>         "B"
...>       )
...>     )
...>   )
iex> Inspect.Algebra.format(doc, 80)
["Hello,", " ", "A", " ", "B"]
iex> Inspect.Algebra.format(doc, 6)
["Hello,", "\n", "A", "\n", "B"]

Характеристики

line() :: t()

Обязательный перевод строки.

Группа с переводами строк поместится, если все строки в группе помещаются.

Примеры

iex> doc =
...>   Inspect.Algebra.concat(
...>     Inspect.Algebra.concat(
...>       "Hughes",
...>       Inspect.Algebra.line()
...>     ),
...>     "Wadler"
...>   )
iex> Inspect.Algebra.format(doc, 80)
["Hughes", "\n", "Wadler"]

Характеристики

line(t(), t()) :: t()

Вставляет обязательный перевод строки между двумя документами.

См. line/0.

Примеры

iex> doc = Inspect.Algebra.line("Hughes", "Wadler")
iex> Inspect.Algebra.format(doc, 80)
["Hughes", "\n", "Wadler"]

Характеристики

nest(t(), non_neg_integer() | :cursor | :reset, :always | :break) :: doc_nest()

Вкладывает заданный документ на заданный level.

Если level — целое число, это отступ, добавляемый к переводу строки всякий раз, когда он встречается. Если уровень — :cursor, текущая позиция «курсора» в документе становится вложением. Если уровень — :reset, он устанавливается обратно в 0.

mode может быть :always, что означает, что вложение всегда происходит, или :break, что означает, что вложение происходит только внутри группы, которая была разорвана.

Примеры

iex> doc = Inspect.Algebra.nest(Inspect.Algebra.glue("hello", "world"), 5)
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 5)
["hello", "\n     ", "world"]

Характеристики

next_break_fits(t(), :enabled | :disabled) :: doc_fits()

Рассматривает следующий разрыв как подходящий.

mode может быть :enabled или :disabled. Когда :enabled, документ будет считаться подходящим, как только он найдёт следующий разрыв, фактически отменяя разрыв. Он также проигнорирует любые force_unfit/1 в поисках следующего разрыва.

При отключении он ведёт себя как обычно и проигнорирует любые дальнейшие инструкции next_break_fits/2.

Примеры

Это используется форматировщиком кода Elixir, чтобы избежать разрыва кода в определённых местах. Например, рассмотрим этот код:

some_function_call(%{..., key: value, ...})

Теперь представьте, что этот код не помещается в строку. Форматировщик кода вставляет разрывы внутри ( и ) и внутри %{ и }. Таким образом, документ будет разбит как:

some_function_call(
  %{
    ...,
    key: value,
    ...
  }
)

Форматировщик оборачивает документ алгебры, представляющий карту, в next_break_fits/1, поэтому код форматируется как:

some_function_call(%{
  ...,
  key: value,
  ...
})

Характеристики

space(t(), t()) :: t()

Вставляет обязательный одиночный пробел между двумя документами.

Примеры

iex> doc = Inspect.Algebra.space("Hughes", "Wadler")
iex> Inspect.Algebra.format(doc, 5)
["Hughes", " ", "Wadler"]

Характеристики

string(String.t()) :: doc_string()

Создает документ, представленный строкой.

Хотя Inspect.Algebra принимает бинарные данные в качестве документов, они учитываются по размеру в байтах. С другой стороны, документы string измеряются количеством графем для определения размера документа.

Примеры

Следующий документ имеет 10 байтов и поэтому не форматируется до ширины 9 без разрывов:

iex> doc = Inspect.Algebra.glue("olá", " ", "mundo")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 9)
["olá", "\n", "mundo"]

Однако, если мы используем string, длина строки используется вместо размера в байтах, что правильно подгоняет документ:

iex> string = Inspect.Algebra.string("olá")
iex> doc = Inspect.Algebra.glue(string, " ", "mundo")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 9)
["olá", " ", "mundo"]

Характеристики

to_doc(any(), Inspect.Opts.t()) :: t()

Преобразует термин Elixir в документ алгебры в соответствии с протоколом Inspect.