fish_mode_prompt - определение отображения индикатора режима

Краткое описание

function fish_mode_prompt
     echo -n "$fish_bind_mode "
end

Описание

Функция fish_mode_prompt выводит индикатор режима для использования в режиме vi.

По умолчанию функция fish_mode_prompt выведет индикаторы текущего режима редактора Vi слева от обычного приглашения. Определите собственную функцию для настройки отображения индикатора режима. Функция $fish_bind_mode variable может использоваться для определения текущего режима. Он будет одним из default, insert, replace_one, или visual.

Также можно определить пустую функцию fish_mode_prompt для удаления индикаторов режима Vi:

function fish_mode_prompt; end
funcsave fish_mode_prompt

fish_mode_prompt будет выполнено при изменении режима vi. Если она произведёт вывод, он будет отображён и использован. Если нет, то будут выполнены и другие функции приглашения (fish_prompt и fish_right_prompt), если они содержат отображение режима.

Пример

function fish_mode_prompt
  switch $fish_bind_mode
    case default
      set_color --bold red
      echo 'N'
    case insert
      set_color --bold green
      echo 'I'
    case replace_one
      set_color --bold green
      echo 'R'
    case visual
      set_color --bold brmagenta
      echo 'V'
    case '*'
      set_color --bold red
      echo '?'
  end
  set_color normal
end

Вывод нескольких строк не поддерживается в fish_mode_prompt.