Написание собственных дополнений

Для задания дополнения используйте команду complete. complete принимает в качестве параметра имя команды, для которой нужно задать дополнение. Например, чтобы добавить дополнение для программы myprog, необходимо начать команду дополнения с complete -c myprog ...

Для предоставления списка возможных дополнений для myprog используйте переключатель -a. Если myprog принимает аргументы start и stop, это можно указать как complete -c myprog -a 'start stop'. Аргумент для переключателя -a всегда является одной строкой. Во время завершения работы дополнения она будет разбита на токены по пробелам и табуляциям, и произойдёт подстановка переменных, подстановка команд и другие формы расширения параметров.

fish имеет специальный синтаксис для поддержки задания переключателей, принимаемых командой. Переключатели -s, -l и -o используются для задания короткого переключателя (один символ, например, -l), переключателя в стиле GNU (например, --color) и переключателя в старом стиле (например, -shuffle) соответственно. Если у команды ‘myprog’ есть опция ‘-o’, которую также можно записать как --output, и которая может принимать дополнительное значение «yes» или «no», это можно указать, написав:

complete -c myprog -s o -l output -a "yes no"

Также существуют специальные переключатели для указания того, что переключатель требует аргумента, для отключения завершения имени файла, для создания дополнений, доступных только в некоторых комбинациях и т. д. Для получения полного описания различных переключателей, принимаемых командой complete, см. документацию для встроенной команды complete или напишите complete --help внутри fish оболочки.

В качестве более подробного примера, вот комментированный фрагмент дополнений для systemd’s timedatectl:

# All subcommands that timedatectl knows - this is useful for later.
set -l commands status set-time set-timezone list-timezones set-local-rtc set-ntp

# Disable file completions for the entire command
# because it does not take files anywhere
# Note that this can be undone by using "-F".
#
# File completions also need to be disabled
# if you want to have more control over what files are offered
# (e.g. just directories, or just files ending in ".mp3").
complete -c timedatectl -f

# This line offers the subcommands
# -"status",
# -"set-timezone",
# -"set-time"
# -"list-timezones"
# if no subcommand has been given so far.
#
# The `-n`/`--condition` option takes script as a string, which it executes.
# If it returns true, the completion is offered.
# Here the condition is the `__fish_seen_subcommands_from` helper function.
# If returns true if any of the given commands is used on the commandline,
# as determined by a simple heuristic.
# For more complex uses, you can write your own function.
# See e.g. the git completions for an example.
#
complete -c timedatectl -n "not __fish_seen_subcommand_from $commands" \
    -a "status set-time set-timezone list-timezones"

# If the "set-timezone" subcommand is used,
# offer the output of `timedatectl list-timezones` as completions.
# Each line of output is used as a separate candidate,
# and anything after a tab is taken as the description.
# It's often useful to transform command output with `string` into that form.
complete -c timedatectl -n "__fish_seen_subcommand_from set-timezone" \
    -a "(timedatectl list-timezones)"

# Completion candidates can also be described via `-d`,
# which is useful if the description is constant.
# Try to keep these short, because that means the user gets to see more at once.
complete -c timedatectl -n "not __fish_seen_subcommand_from $commands" \
    -a "set-local-rtc" -d "Maintain RTC in local time"

# We can also limit options to certain subcommands by using conditions.
complete -c timedatectl -n "__fish_seen_subcommand_from set-local-rtc" \
    -l adjust-system-clock -d 'Synchronize system clock from the RTC'

# These are simple options that can be used everywhere.
complete -c timedatectl -s h -l help -d 'Print a short help text and exit'
complete -c timedatectl -l version -d 'Print a short version string and exit'
complete -c timedatectl -l no-pager -d 'Do not pipe output into a pager'

Для примеров написания собственных сложных дополнений изучите дополнения в /usr/share/fish/completions. (Точный путь зависит от выбранного префикса установки и может незначительно отличаться)