8.57 COUNT — Функция Count

Описание:

Подсчитывает количество .TRUE. элементов в логической MASK, или, если задан аргумент DIM, подсчитывает количество элементов по каждой строке массива в направлении DIM. Если массив имеет нулевой размер или все элементы MASK являются .FALSE., то результат равен 0.

Стандарт:

Fortran 95 и более поздние версии, с аргументом KIND Fortran 2003 и более поздние версии

Класс:

Функция преобразования

Синтаксис:

RESULT = COUNT(MASK [, DIM, KIND])

Аргументы:

MASK	Тип должен быть LOGICAL.
DIM	(Необязательно) Тип должен быть INTEGER.
KIND	(Необязательно) Выражение инициализации, указывающее параметр типа результата.

Возвращаемое значение:

Возвращаемое значение имеет тип INTEGER и тип KIND. Если KIND отсутствует, возвращаемое значение имеет стандартный целочисленный тип. Если DIM присутствует, результат является массивом с рангом на единицу меньше, чем ранг ARRAY, и размером, соответствующим форме ARRAY с удалённым измерением DIM.

Пример:

program test_count
    integer, dimension(2,3) :: a, b
    logical, dimension(2,3) :: mask
    a = reshape( (/ 1, 2, 3, 4, 5, 6 /), (/ 2, 3 /))
    b = reshape( (/ 0, 7, 3, 4, 5, 8 /), (/ 2, 3 /))
    print '(3i3)', a(1,:)
    print '(3i3)', a(2,:)
    print *
    print '(3i3)', b(1,:)
    print '(3i3)', b(2,:)
    print *
    mask = a.ne.b
    print '(3l3)', mask(1,:)
    print '(3l3)', mask(2,:)
    print *
    print '(3i3)', count(mask)
    print *
    print '(3i3)', count(mask, 1)
    print *
    print '(3i3)', count(mask, 2)
end program test_count