Комплексные и рациональные числа

Julia поставляется с предопределенными типами, представляющими как комплексные, так и рациональные числа, и поддерживает все стандартные математические операции над ними. Преобразование и продвижение определены таким образом, что операции над любыми комбинациями предопределенных числовых типов, будь то примитивные или составные, работают как ожидается.

Комплексные числа

Глобальная константа im связана с комплексным числом i, представляющим собой основной квадратный корень из -1. Было сочтено вредным использовать имя i для глобальной константы, поскольку это очень популярное имя переменной индекса. Поскольку Julia позволяет числовым литералам быть составленными с идентификаторами в качестве коэффициентов, это связывание достаточно для обеспечения удобного синтаксиса для комплексных чисел, аналогичного традиционному математическому обозначению:

julia> 1 + 2im
1 + 2im

Вы можете выполнять все стандартные арифметические операции с комплексными числами:

julia> (1 + 2im)*(2 - 3im)
8 + 1im

julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im

julia> (1 + 2im) + (1 - 2im)
2 + 0im

julia> (-3 + 2im) - (5 - 1im)
-8 + 3im

julia> (-1 + 2im)^2
-3 - 4im

julia> (-1 + 2im)^2.5
2.7296244647840084 - 6.960664459571898im

julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im

julia> 3(2 - 5im)
6 - 15im

julia> 3(2 - 5im)^2
-63 - 60im

julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im

Механизм продвижения гарантирует, что сочетания операндов разных типов просто работают:

julia> 2(1 - 1im)
2 - 2im

julia> (2 + 3im) - 1
1 + 3im

julia> (1 + 2im) + 0.5
1.5 + 2.0im

julia> (2 + 3im) - 0.5im
2.0 + 2.5im

julia> 0.75(1 + 2im)
0.75 + 1.5im

julia> (2 + 3im) / 2
1.0 + 1.5im

julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im

julia> 2im^2
-2 + 0im

julia> 1 + 3/4im
1.0 - 0.75im

Обратите внимание, что 3/4im == 3/(4*im) == -(3/4*im), так как коэффициент литерала связывается сильнее, чем деление.

Предоставлены стандартные функции для работы с комплексными значениями:

julia> real(1 + 2im)
1

julia> imag(1 + 2im)
2

julia> conj(1 + 2im)
1 - 2im

julia> abs(1 + 2im)
2.23606797749979

julia> abs2(1 + 2im)
5

julia> angle(1 + 2im)
1.1071487177940904

Как обычно, абсолютное значение (abs()) комплексного числа — это его расстояние от нуля. abs2() возвращает квадрат абсолютного значения и особенно полезен для комплексных чисел, поскольку позволяет избежать вычисления квадратного корня. angle() возвращает фазовый угол в радианах (также известный как функция аргумента или arg). Полный набор других элементарных функций также определен для комплексных чисел:

julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im

julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im

julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991518im

julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im

julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im

Обратите внимание, что математические функции обычно возвращают вещественные значения, когда применяются к вещественным числам, и комплексные значения, когда применяются к комплексным числам. Например, sqrt() ведет себя по-разному при применении к -1 по сравнению с -1 + 0im, даже если -1 == -1 + 0im:

julia> sqrt(-1)
ERROR: DomainError:
sqrt will only return a complex result if called with a complex argument. Try sqrt(complex(x)).
 in sqrt(::Int64) at ./math.jl:211
 ...

julia> sqrt(-1 + 0im)
0.0 + 1.0im

Нотация числового коэффициента литерала не работает при построении комплексного числа из переменных. Вместо этого умножение должно быть явно указано:

julia> a = 1; b = 2; a + b*im
1 + 2im

Однако это не рекомендуется; Используйте функцию complex(), чтобы напрямую построить комплексное значение из его вещественной и мнимой частей:

julia> complex(a,b)
1 + 2im

Это построение избегает операций умножения и сложения.

Inf и NaN распространяются через комплексные числа в вещественной и мнимой частях комплексного числа, как описано в разделе Специальные плавающие значения:

julia> 1 + Inf*im
1.0 + Inf*im

julia> 1 + NaN*im
1.0 + NaN*im

Рациональные числа

Julia имеет тип рационального числа для представления точных отношений целых чисел. Рациональные числа создаются с использованием оператора //:

julia> 2//3
2//3

Если числитель и знаменатель рационального числа имеют общие делители, они сводятся к наименьшим членам так, что знаменатель является неотрицательным:

julia> 6//9
2//3

julia> -4//8
-1//2

julia> 5//-15
-1//3

julia> -4//-12
1//3

Эта нормализованная форма отношения целых чисел уникальна, поэтому равенство рациональных значений можно проверить, проверив равенство числителя и знаменателя. Стандартизированный числитель и знаменатель рационального значения могут быть извлечены с помощью функций num() и den():

julia> num(2//3)
2

julia> den(2//3)
3

Прямое сравнение числителя и знаменателя обычно не требуется, поскольку стандартные арифметические и сравнительные операции определены для рациональных значений:

julia> 2//3 == 6//9
true

julia> 2//3 == 9//27
false

julia> 3//7 < 1//2
true

julia> 3//4 > 2//3
true

julia> 2//4 + 1//6
2//3

julia> 5//12 - 1//4
1//6

julia> 5//8 * 3//12
5//32

julia> 6//5 / 10//7
21//25

Рациональные числа могут быть легко преобразованы в числа с плавающей запятой:

julia> float(3//4)
0.75

Преобразование из рационального в число с плавающей запятой соблюдает следующее тождество для любых целых значений a и b, за исключением случая a == 0 и b == 0:

julia> isequal(float(a//b), a/b)
true

Создание бесконечных рациональных значений допустимо:

julia> 5//0
1//0

julia> -3//0
-1//0

julia> typeof(ans)
Rational{Int64}

Однако попытка создать рациональное значение NaN невозможна:

julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
 in Rational{Int64}(::Int64, ::Int64) at ./rational.jl:8
 in //(::Int64, ::Int64) at ./rational.jl:22
 ...

Как обычно, система продвижения делает взаимодействие с другими числовыми типами без проблем:

julia> 3//5 + 1
8//5

julia> 3//5 - 0.5
0.09999999999999998

julia> 2//7 * (1 + 2im)
2//7 + 4//7*im

julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im

julia> 3//2 / (1 + 2im)
3//10 - 3//5*im

julia> 1//2 + 2im
1//2 + 2//1*im

julia> 1 + 2//3im
1//1 - 2//3*im

julia> 0.5 == 1//2
true

julia> 0.33 == 1//3
false

julia> 0.33 < 1//3
true

julia> 1//3 - 0.33
0.0033333333333332993