Запуск внешних программ

Julia заимствует обрамление обратной косой чертой для команд из оболочки, Perl и Ruby. Однако в Julia запись

julia> `echo hello`
`echo hello`

отличается в нескольких аспектах от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды, обрамление обратной косой чертой создаёт объект Cmd для представления команды. Вы можете использовать этот объект для соединения команды с другими через конвейеры, запустить её и читать или писать в неё.
• При запуске команды Julia не захватывает её вывод, если вы не организуете это специально. Вместо этого вывод команды по умолчанию отправляется в STDOUT так же, как при использовании libc‘s вызова system.
• Команда никогда не запускается с оболочкой. Вместо этого Julia парсит синтаксис команды напрямую, соответствующим образом интерполируя переменные и разбивая на слова, как это делает оболочка, соблюдая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia с использованием fork и exec вызовов.

Вот простой пример запуска внешней программы:

julia> run(`echo hello`)
hello

hello — это вывод команды echo, отправленный в STDOUT. Сам метод run возвращает nothing, и выбрасывает ErrorException, если внешняя команда не выполняется успешно.

Если вы хотите прочитать вывод внешней команды, можно использовать readstring():

julia> a=readstring(`echo hello`)
"hello\n"

julia> (chomp(a)) == "hello"
true

Более общее использование — open() для чтения или записи во внешнюю команду.

julia> open(`less`, "w", STDOUT) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Интерполяция

Предположим, вы хотите сделать что-то немного посложнее и использовать имя файла в переменной file в качестве аргумента команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Строки):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространённая ошибка при запуске внешних программ через оболочку заключается в том, что если имя файла содержит символы, являющиеся специальными для оболочки, это может привести к нежелаемому поведению. Например, вместо /etc/passwd, предположим, что мы хотим отсортировать содержимое файла /Volumes/External HD/data.csv. Попробуем:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла оказалось в кавычках? Julia знает, что file должно интерполироваться как один аргумент, поэтому она цитирует слово за вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в реальном цитировании; кавычки вставляются только для отображения пользователю. Это будет работать даже если вы интерполируете значение как часть слова оболочки:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path правильно экранирован. А что, если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"


julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив как часть слова оболочки, Julia эмулирует генерацию аргументов {a,b,c} оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Кроме того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартовых произведений оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать массивы в виде литералов, вы можете использовать эту функциональность генерации, не создавая временных объектов массивов:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитирование

Неизбежно, что вы захотите написать команды, которые не так просты, и это станет необходимостью использования кавычек. Вот простой пример однострочного скрипта Perl в командной строке оболочки:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Выражение Perl должно быть в одинарных кавычках по двум причинам: чтобы пробелы не разбили выражение на несколько слов оболочки, и чтобы использования переменных Perl, таких как $| (да, это имя переменной в Perl), не приводило к интерполяции. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В целом, синтаксис обрамления обратной косой чертой в Julia тщательно разработан так, что вы можете просто скопировать-вставить команды оболочки в обрамление обратной косой чертой, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как и в оболочке. Единственное отличие заключается в том, что интерполяция интегрирована и учитывает представление Julia о том, что является одной строковой величиной, а что является контейнером для нескольких значений. Попробуем два вышеприведённых примера в Julia:

julia> `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(ans)
0
1
2
3

julia> first = "A"; second = "B";

julia> `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(ans)
1: A
2: B

Результаты идентичны, и поведение интерполяции Julia имитирует поведение оболочки с некоторыми улучшениями благодаря тому, что Julia поддерживает итерируемые объекты первого класса, тогда как большинство оболочек используют строки, разделённые пробелами для этого, что вводит неоднозначность. При попытке перенести команды оболочки в Julia, сначала попробуйте скопировать-вставить. Поскольку Julia показывает вам команды перед их запуском, вы можете легко и безопасно просто изучить её интерпретацию, не нанося никакого вреда.

Конвейеры

Метасимволы оболочки, такие как |, &, и >, не являются специальными внутри обрамления обратной косой чертой Julia: в отличие от оболочки, внутри обрамления обратной косой чертой Julia конвейер всегда просто конвейер:

julia> run(`echo hello | sort`)
hello | sort

Это выражение вызывает команду echo со тремя словами в качестве аргументов: «hello», «|», и «sort». Результат — печать одной строки: «hello | sort». Внутри обрамления обратной косой чертой «|» — это просто символ конвейера.

Как же создать конвейер? Вместо использования «|» внутри обрамления обратной косой чертой, используйте pipeline():

julia> run(pipeline(`echo hello`, `sort`))
hello

Это передаёт вывод команды echo в команду sort. Конечно, это не очень интересно, так как есть только одна строка, которую нужно отсортировать, но мы можем сделать гораздо более интересные вещи:

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это выводит пять наибольших идентификаторов пользователей в системе UNIX. Команды cut, sort и tail все запускаются как непосредственные дочерние процессы текущего julia процесса, без промежуточного процесса оболочки. Julia сама выполняет работу по настройке конвейеров и соединению дескрипторов файлов, которая обычно выполняется оболочкой. Поскольку Julia выполняет это сама, она сохраняет больший контроль и может делать некоторые вещи, которые оболочка не может.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`)
world
hello

Порядок вывода здесь не определён, потому что два echo процесса запускаются почти одновременно и соревнуются, чтобы сделать первый запис в STDOUT дескриптор, который они делят друг с другом и с julia родительским процессом. Julia позволяет вам передавать вывод обоих этих процессов в другую программу:

julia> run(pipeline(`echo world` & `echo hello`, `sort`))
hello
world

С точки зрения UNIX-коммуникаций, здесь создаётся один объект UNIX-конвейера, в который записывают оба echo процесса, а другой конец конвейера считывается командой sort.

Перенаправление ввода-вывода может быть выполнено путём передачи ключевых аргументов stdin, stdout и stderr функции pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Предотвращение тупика в конвейерах

При чтении и записи в оба конца конвейера из одного процесса важно избегать принуждения ядра к буферизации всех данных.

Например, при чтении всего вывода из команды, вызовите readstring(out), а не wait(process), так как первый активно потребляет все данные, записанные процессом, а второй попытается сохранить данные в буферах ядра, ожидая подключения читателя.

Другим распространённым решением является разделение читателя и писателя конвейера на отдельные задачи:

writer = @async writeall(process, "data")
reader = @async do_compute(readstring(process))
wait(process)
fetch(reader)

Сложный пример

Сочетание высокоуровневого языка программирования, абстракции команд первого класса и автоматической установки конвейеров между процессами — мощный инструмент. Чтобы дать представление о сложных конвейерах, которые можно легко создать, здесь приведены несколько более сложных примеров, с извинениями за чрезмерное использование однострочных скриптов Perl:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..9){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)))
A 0
B 1
A 2
B 3
A 4
B 5
A 6
B 7
A 8
B 9

Это классический пример одного производителя, питающего двух параллельных потребителей: один perl процесс генерирует строки с числами от 0 до 9, а два параллельных процесса потребляют этот вывод, один добавляя к строкам букву «A», а другой — «B». Какой потребитель получит первую строку, не определено, но как только эта гонка будет выиграна, строки последовательно потребляются одним процессом, а затем другим. (Установление $|=1 в Perl заставляет каждый оператор print сбрасывать буфер STDOUT, что необходимо для работы этого примера. В противном случае весь вывод буферизуется и печатается в конвейер сразу, чтобы прочитать только один процесс потребителя.)

Вот ещё один более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..9){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)))
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5
A X 6
B Y 7
A Z 8
B X 9

Этот пример похож на предыдущий, но есть две стадии потребителей, и стадии имеют разную задержку, поэтому они используют разное количество параллельных рабочих процессов для поддержания насыщенной пропускной способности.

Мы настоятельно рекомендуем попробовать все эти примеры, чтобы увидеть, как они работают.