Запуск внешних программ

Julia заимствует обозначение команд в обратных кавычках из оболочки, Perl и Ruby. Однако в Julia запись

julia> `echo hello`
`echo hello`

отличается по нескольким аспектам от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды, обратные кавычки создают объект Cmd для представления команды. Вы можете использовать этот объект для подключения команды к другим командам через конвейеры, запустить её и читать или записывать в неё.

• Когда команда запускается, Julia не захватывает её вывод, если вы не организуете это специально. Вместо этого вывод команды по умолчанию отправляется в STDOUT, как это делается с помощью вызова libc's system.

• Команда никогда не запускается с оболочкой. Вместо этого Julia анализирует синтаксис команды непосредственно, соответствующим образом интерполирует переменные и разбивает по словам так же, как это делала бы оболочка, учитывая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia с использованием вызовов fork и exec.

Вот простой пример запуска внешней программы:

julia> mycommand = `echo hello`
`echo hello`

julia> typeof(mycommand)
Cmd

julia> run(mycommand)
hello

hello — это вывод команды echo, отправленный в STDOUT. Сам метод run возвращает nothing, и выбрасывает ErrorException, если внешняя команда не выполняется успешно.

Если вы хотите прочитать вывод внешней команды, вместо этого можно использовать readstring():

julia> a = readstring(`echo hello`)
"hello\n"

julia> chomp(a) == "hello"
true

В более общем случае, вы можете использовать open() для чтения из или записи во внешнюю команду.

julia> open(`less`, "w", STDOUT) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Интерполяция

Предположим, вы хотите сделать что-то немного более сложное и использовать имя файла в переменной file в качестве аргумента команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Строки):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространённая ошибка при запуске внешних программ через оболочку заключается в том, что если имя файла содержит символы, являющиеся специальными для оболочки, это может привести к нежелательному поведению. Например, вместо /etc/passwd, мы хотели бы отсортировать содержимое файла /Volumes/External HD/data.csv. Давайте попробуем:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла оказалось в кавычках? Julia понимает, что file должно интерполироваться как один аргумент, поэтому оно цитирует слово за вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в фактическом цитировании; кавычки вставляются только для отображения пользователю. Это будет работать даже если вы интерполируете значение в рамках оболочкового слова:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path правильно экранирован. Но что если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"

julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив как часть оболочкового слова, Julia эмулирует генерацию аргументов {a,b,c} оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Кроме того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартовых произведений оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать буквальные массивы, вы можете использовать эту функциональность генерации, не создавая предварительно временных объектов массива:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитирование

Неизбежно, что нужно писать команды, которые не так просты, и становится необходимым использовать кавычки. Вот простой пример перлового однострочника в командной строке:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Перловая выражение должно быть в одинарных кавычках по двум причинам: чтобы пробелы не разбили выражение на несколько оболочковых слов, и чтобы использование переменных Perl, таких как $| (да, это имя переменной в Perl), не вызвало интерполяцию. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В общем случае, синтаксис обратных кавычек в Julia тщательно разработан таким образом, что вы можете просто скопировать и вставить команды оболочки в обратные кавычки, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как и в оболочке. Единственное различие заключается в том, что интерполяция интегрирована и учитывает представление Julia о том, что является одиночным строковым значением, а что является контейнером для нескольких значений. Давайте попробуем два вышеупомянутых примера в Julia:

julia> A = `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(A)
0
1
2
3

julia> first = "A"; second = "B";

julia> B = `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(B)
1: A
2: B

Результаты идентичны, и поведение интерполяции Julia имитирует поведение оболочки с некоторыми улучшениями из-за того, что Julia поддерживает итерируемые объекты первого класса, в то время как большинство оболочек используют строки, разделенные пробелами, для этого, что вводит неоднозначности. При попытке перенести команды оболочки в Julia, сначала попробуйте скопировать и вставить. Поскольку Julia показывает вам команды перед их запуском, вы можете легко и безопасно просто проверить её интерпретацию, не причиняя никакого вреда.

Конвейеры

Оболочечные метасимволы, такие как |, &, и >, должны быть в кавычках (или экранированы) внутри обратных кавычек Julia:

julia> run(`echo hello '|' sort`)
hello | sort

julia> run(`echo hello \| sort`)
hello | sort

Это выражение вызывает команду echo со тремя словами в качестве аргументов: hello, |, и sort. Результатом является печать одной строки: hello | sort. Как же тогда построить конвейер? Вместо использования '|' внутри обратных кавычек, используется pipeline():

julia> run(pipeline(`echo hello`, `sort`))
hello

Это отправляет вывод команды echo в команду sort. Конечно, это не очень интересно, поскольку есть только одна строка для сортировки, но мы определённо можем делать гораздо более интересные вещи:

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это выводит пять наибольших идентификаторов пользователей в системе UNIX. Команды cut, sort и tail все запускаются как непосредственные дочерние процессы текущего julia процесса, без вмешательства оболочки. Julia сама выполняет работу по настройке конвейеров и соединению дескрипторов файлов, которая обычно выполняется оболочкой. Так как Julia делает это самостоятельно, она сохраняет больший контроль и может делать некоторые вещи, которые оболочка не может.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`)
world
hello

Порядок вывода здесь не детерминирован, потому что два echo процесса запускаются почти одновременно и соревнуются за выполнение первой записи в дескриптор STDOUT, который они делят друг с другом и с родительским процессом julia. Julia позволяет вам передавать вывод обоих этих процессов в другую программу:

julia> run(pipeline(`echo world` & `echo hello`, `sort`))
hello
world

С точки зрения UNIX-соединений, здесь создается один объект UNIX-конвейера, в который записывают оба echo процесса, а другой конец конвейера считывается командой sort.

Перенаправление ввода-вывода можно выполнить, передав ключевые аргументы stdin, stdout и stderr функции pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Избежание тупика в конвейерах

При чтении и записи в обе стороны конвейера одним процессом важно не заставлять ядро буферизовать все данные.

Например, при чтении всего вывода команды вызывайте readstring(out), а не wait(process), так как первый активно потребляет все данные, записанные процессом, а второй попытается сохранить данные в буферах ядра, ожидая подключения читателя.

Ещё одно распространённое решение — разделение читателя и писателя конвейера на отдельные задачи:

writer = @async writeall(process, "data")
reader = @async do_compute(readstring(process))
wait(process)
fetch(reader)

Сложный пример

Сочетание языка высокого уровня, абстракции команд первого класса и автоматической настройки конвейеров между процессами — мощный инструмент. Чтобы дать представление о сложных конвейерах, которые можно легко создать, вот несколько более сложных примеров, с извинениями за чрезмерное использование перловых однострочников:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..9){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)))
A 0
B 1
A 2
B 3
A 4
B 5
A 6
B 7
A 8
B 9

Это классический пример одного производителя, который питает двух одновременных потребителей: один процесс perl генерирует строки с числами от 0 до 9, а два параллельных процесса потребляют этот вывод, один префиксуя строки буквой "A", другой — буквой "B". Какой потребитель получит первую строку, не определено, но, как только это состязание выиграно, строки потребляются попеременно одним процессом, а затем другим. (Установка $|=1 в Perl заставляет каждую инструкцию print сбрасывать буфер STDOUT , что необходимо для работы этого примера. В противном случае весь вывод буферизуется и печатается в конвейер сразу, чтобы его прочитал только один процесс потребителя.)

Вот ещё более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..9){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)))
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5
A X 6
B Y 7
A Z 8
B X 9

Этот пример похож на предыдущий, но есть две стадии потребителей, и стадии имеют разную задержку, поэтому они используют разное количество параллельных рабочих процессов для поддержания насыщенной пропускной способности.

Мы настоятельно рекомендуем вам попробовать все эти примеры, чтобы увидеть, как они работают.