Выполнение внешних программ

Julia заимствует обозначение команд с обратными апострофами из оболочки, Perl и Ruby. Однако в Julia запись

julia> `echo hello`
`echo hello`

отличается по нескольким аспектам от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды, обратные апострофы создают объект Cmd для представления команды. Вы можете использовать этот объект для соединения команды с другими командами через каналы, run его, и read или write к нему.
• При запуске команды Julia не захватывает ее вывод, если вы не организуете это явно. Вместо этого вывод команды по умолчанию направляется в stdout, как это делается при использовании libc's вызова system.
• Команда никогда не запускается с оболочкой. Вместо этого Julia анализирует синтаксис команды напрямую, соответствующим образом интерполируя переменные и разбивая по словам, как это делает оболочка, соблюдая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia с использованием вызовов fork и exec.

Вот простой пример запуска внешней программы:

julia> mycommand = `echo hello`
`echo hello`

julia> typeof(mycommand)
Cmd

julia> run(mycommand);
hello

Вывод hello - это вывод команды echo, отправленный в stdout. Сам метод run возвращает nothing, и выбрасывает ErrorException, если внешняя команда завершится неудачно.

Если вы хотите прочитать вывод внешней команды, можно использовать read:

julia> a = read(`echo hello`, String)
"hello\n"

julia> chomp(a) == "hello"
true

Более обобщенно, вы можете использовать open для чтения из или записи во внешнюю команду.

julia> open(`less`, "w", stdout) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Имя программы и отдельные аргументы в команде можно получить и перебрать, как если бы команда была массивом строк:

julia> collect(`echo "foo bar"`)
2-element Array{String,1}:
 "echo"
 "foo bar"

julia> `echo "foo bar"`[2]
"foo bar"

Интерполяция

Предположим, вы хотите сделать что-то немного более сложное и использовать имя файла в переменной file в качестве аргумента команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Strings):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространённая ошибка при запуске внешних программ через оболочку заключается в том, что если имя файла содержит символы, являющиеся специальными для оболочки, они могут привести к нежелательному поведению. Предположим, например, что вместо /etc/passwd, мы хотели отсортировать содержимое файла /Volumes/External HD/data.csv. Попробуем:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла было взято в кавычки? Julia знает, что file должно интерпретироваться как один аргумент, поэтому цитирует слово за вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в фактическом цитировании; кавычки вставляются только для представления пользователю. Это будет работать даже если вы интерполируете значение как часть слова оболочки:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path должным образом экранирован. Но что, если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"

julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив как часть слова оболочки, Julia эмулирует генерацию аргументов {a,b,c} оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Более того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартова произведения оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать литеральные массивы, вы можете использовать эту функциональность генерации без необходимости предварительного создания временных массивов:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитаты

Неизбежно возникает необходимость писать более сложные команды, и необходимо использовать кавычки. Вот простой пример однострочной команды Perl в командной строке оболочки:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Выражение Perl необходимо поместить в одинарные кавычки по двум причинам: чтобы пробелы не разбивали выражение на несколько слов оболочки, и чтобы использование переменных Perl, таких как $| (да, это имя переменной в Perl), не вызывало интерполяцию. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В общем случае синтаксис Julia с обратными апострофами тщательно разработан таким образом, что вы можете просто скопировать и вставить команды оболочки в обратные апострофы, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как у оболочки. Единственное отличие состоит в том, что интерполяция интегрирована и учитывает представление Julia о том, что такое одиночное строковое значение и что является контейнером для нескольких значений. Давайте попробуем эти два примера в Julia:

julia> A = `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(A);
0
1
2
3

julia> first = "A"; second = "B";

julia> B = `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(B);
1: A
2: B

Результаты идентичны, и поведение интерполяции Julia имитирует поведение оболочки с некоторыми улучшениями благодаря тому, что Julia поддерживает итерируемые объекты первого класса, в то время как большинство оболочек используют для этого строки, разделённые пробелами, что приводит к неоднозначности. При попытке перенести команды оболочки в Julia, сначала попробуйте скопировать и вставить. Поскольку Julia отображает команды перед их запуском, вы можете легко и безопасно просто проверить её интерпретацию, не нанося никакого вреда.

Каналы

Символы метакоманд оболочки, такие как |, &, и >, необходимо цитировать (или экранировать) внутри обратных апострофов Julia:

julia> run(`echo hello '|' sort`);
hello | sort

julia> run(`echo hello \| sort`);
hello | sort

Это выражение вызывает команду echo с тремя словами в качестве аргументов: hello, |, и sort. Результатом является вывод одной строки: hello | sort. Как же тогда построить канал? Вместо использования '|' внутри обратных апострофов, используется pipeline:

julia> run(pipeline(`echo hello`, `sort`));
hello

Это направляет вывод команды echo в команду sort.

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это печатает пять наибольших идентификаторов пользователей в системе UNIX. Команды cut, sort и tail запускаются как непосредственные дочерние процессы текущего процесса julia без промежуточного процесса оболочки. Julia сама выполняет работу по настройке каналов и соединению дескрипторов файлов, которая обычно выполняется оболочкой. Поскольку Julia делает это сама, она сохраняет больший контроль и может делать некоторые вещи, которые оболочки не могут.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`);
world
hello

Порядок вывода здесь не определён, поскольку два процесса echo запускаются почти одновременно и соревнуются, чтобы первыми записать в дескриптор stdout, который они разделяют друг с другом и с родительским процессом julia. Julia позволяет вам направлять вывод обоих этих процессов в другую программу:

julia> run(pipeline(`echo world` & `echo hello`, `sort`));
hello
world

С точки зрения UNIX-соединений, здесь создаётся один объект UNIX-канала, в который записывают оба процесса echo, и другой конец канала считывается командой sort.

Перенаправление ввода-вывода можно осуществить, передав ключевые аргументы stdin, stdout, и stderr функции pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Избегание тупика в каналах

При чтении и записи на обоих концах канала из одного процесса важно избегать принуждения ядра к буферизации всех данных.

Например, при чтении всего вывода команды следует вызывать read(out, String), а не wait(process), так как первый активно потребляет все данные, записанные процессом, тогда как второй попытается сохранить данные в буферах ядра, ожидая подключения читателя.

Другое распространённое решение - разделить читателя и записывателя канала на отдельные задачи Task:

writer = @async write(process, "data")
reader = @async do_compute(read(process, String))
wait(process)
fetch(reader)

Сложный пример

Сочетание языка высокого уровня, абстракции команд первого класса и автоматической настройки каналов между процессами является мощным инструментом. Чтобы дать представление о сложных каналах, которые можно легко создать, ниже приведены некоторые более сложные примеры с извинениями за чрезмерное использование однострочных команд Perl:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)));
B 0
A 1
B 2
A 3
B 4
A 5

Это классический пример одиночного производителя, который питает двух параллельных потребителей: один процесс perl генерирует строки с числами от 0 до 5, в то время как два параллельных процесса потребляют этот вывод, один добавляя к строкам префикс «A», другой «B». Какой потребитель получит первую строку, неопределённо, но как только эта гонка будет выиграна, строки будут поочерёдно потребляться одним процессом, а затем другим. (Установка $|=1 в Perl заставляет каждый оператор print очищать дескриптор stdout, что необходимо для работы этого примера. В противном случае весь вывод буферизуется и выводится в канал сразу, чтобы его прочитал только один процесс-потребитель.)

Вот ещё более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)));
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5

Этот пример аналогичен предыдущему, за исключением того, что есть два этапа потребителей, и этапы имеют различную задержку, поэтому они используют разное количество параллельных рабочих потоков, чтобы поддерживать насыщенный пропускную способность.

Мы настоятельно рекомендуем вам попробовать все эти примеры, чтобы увидеть, как они работают.