Запуск внешних программ

Julia заимствует нотацию команд с обратными кавычками из оболочек, Perl и Ruby. Однако в Julia запись

julia> `echo hello`
`echo hello`

отличается по нескольким аспектам от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды обратные кавычки создают объект Cmd, представляющий команду. Вы можете использовать этот объект для подключения команды к другим командам через конвейеры, run её и read или write к ней.
• При запуске команды Julia не захватывает её вывод, если вы его не запросите. Вместо этого вывод команды по умолчанию отправляется в stdout, как если бы использовалась функция libc's system.
• Команда никогда не запускается с оболочкой. Вместо этого Julia парсит синтаксис команды напрямую, корректно интерполируя переменные и разбивая на слова так, как это делает оболочка, учитывая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia, используя fork и exec вызовы.

Вот простой пример запуска внешней программы:

julia> mycommand = `echo hello`
`echo hello`

julia> typeof(mycommand)
Cmd

julia> run(mycommand);
hello

hello — это вывод команды echo, отправленный в stdout. Сам метод run возвращает nothing и выбрасывает ErrorException, если внешняя команда не выполняется успешно.

Если вы хотите прочитать вывод внешней команды, можно использовать read:

julia> a = read(`echo hello`, String)
"hello\n"

julia> chomp(a) == "hello"
true

Более обобщённо, вы можете использовать open для чтения из или записи во внешнюю команду.

julia> open(`less`, "w", stdout) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Имя программы и отдельные аргументы в команде можно получить и перебрать, как если бы команда была массивом строк:

julia> collect(`echo "foo bar"`)
2-element Array{String,1}:
 "echo"
 "foo bar"

julia> `echo "foo bar"`[2]
"foo bar"

Интерполяция

Предположим, вы хотите выполнить что-то более сложное и использовать имя файла в переменной file в качестве аргумента команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Strings):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространённая ошибка при запуске внешних программ через оболочку заключается в том, что если имя файла содержит символы, являющиеся специальными для оболочки, это может привести к нежелательному поведению. Например, вместо /etc/passwd, мы хотели бы отсортировать содержимое файла /Volumes/External HD/data.csv. Давайте попробуем:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла было заключено в кавычки? Julia понимает, что file должно интерполироваться как один аргумент, поэтому цитирует его для вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в фактическом цитировании; кавычки вставляются только для отображения пользователю. Это будет работать даже если вы интерполируете значение как часть слова оболочки:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path корректно экранирован. Но что если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"

julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив как часть слова оболочки, Julia эмулирует генерацию аргументов оболочки {a,b,c}:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Кроме того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартова произведения оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать литеральные массивы, вы можете использовать эту функциональность генерации без необходимости предварительного создания временных объектов массивов:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитирование

Неизбежно, что нужно писать команды, которые не такие простые, и возникает необходимость в использовании кавычек. Вот простой пример однострочной команды Perl в командной строке:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Выражение Perl должно быть в одинарных кавычках по двум причинам: чтобы пробелы не разбивали выражение на несколько слов оболочки, и чтобы использование переменных Perl, таких как $| (да, это имя переменной в Perl), не вызывало интерполяцию. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В общем, синтаксис обратных кавычек Julia тщательно разработан таким образом, чтобы вы могли просто скопировать и вставить команды оболочки в обратные кавычки, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как у оболочки. Единственное отличие заключается в том, что интерполяция интегрирована и учитывает понятие Julia о том, что является одной строковой величиной, а что является контейнером для нескольких значений. Давайте попробуем два вышеприведённых примера в Julia:

julia> A = `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(A);
0
1
2
3

julia> first = "A"; second = "B";

julia> B = `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(B);
1: A
2: B

Результаты идентичны, и поведение интерполяции Julia имитирует поведение оболочки с некоторыми улучшениями благодаря тому, что Julia поддерживает итерируемые объекты первого класса, в то время как большинство оболочек используют строки, разделённые пробелами для этого, что вводит неоднозначность. При попытке перенести команды оболочки в Julia, сначала попробуйте скопировать и вставить. Поскольку Julia показывает вам команды перед их запуском, вы можете легко и безопасно просто просмотреть её интерпретацию, не причиняя никакого вреда.

Конвейеры

Метасимволы оболочки, такие как |, & и >, должны быть заключены в кавычки (или экранированы) внутри обратных кавычек Julia:

julia> run(`echo hello '|' sort`);
hello | sort

julia> run(`echo hello \| sort`);
hello | sort

Это выражение вызывает команду echo с тремя словами в качестве аргументов: hello, | и sort. Результатом является вывод одной строки: hello | sort. Как же тогда построить конвейер? Вместо использования '|' внутри обратных кавычек, используется pipeline:

julia> run(pipeline(`echo hello`, `sort`));
hello

Это направляет вывод команды echo в команду sort. Конечно, это не очень интересно, так как есть только одна строка для сортировки, но мы можем сделать гораздо более интересные вещи:

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это выводит пять самых высоких идентификаторов пользователей в системе UNIX. Команды cut, sort и tail все запускаются в качестве непосредственных дочерних процессов текущего процесса julia без промежуточных процессов оболочки. Julia сама выполняет работу по настройке конвейеров и подключению дескрипторов файлов, обычно выполняемую оболочкой. Так как Julia делает это сама, она сохраняет лучший контроль и может делать некоторые вещи, которые оболочки не могут.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`);
world
hello

Порядок вывода здесь не детерминирован, потому что два процесса echo запускаются почти одновременно и соревнуются за выполнение первого записи в дескриптор stdout, который они разделяют друг с другом и с родительским процессом julia. Julia позволяет вам направить вывод этих двух процессов в другую программу:

julia> run(pipeline(`echo world` & `echo hello`, `sort`));
hello
world

С точки зрения UNIX-соединений, здесь создается один объект UNIX-конвейера, в который записывают оба процесса echo, а другой конец конвейера считывается командой sort.

Перенаправление ввода-вывода можно выполнить, передав ключевые аргументы stdin, stdout и stderr функции pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Избегание тупика в конвейерах

При чтении и записи в оба конца конвейера одним процессом важно избежать принудительного буферирования всех данных ядром.

Например, при чтении всего вывода из команды вызовите read(out, String), а не wait(process), так как первый активно потребляет все данные, записанные процессом, а второй попытается хранить данные в буферах ядра, ожидая подключения читателя.

Другим распространённым решением является разделение читателя и записывателя конвейера на отдельные задачи Task:

writer = @async write(process, "data")
reader = @async do_compute(read(process, String))
wait(process)
fetch(reader)

Сложный пример

Сочетание языка высокого уровня, абстракции команд первого класса и автоматической настройки конвейеров между процессами является мощным. Чтобы дать представление о сложных конвейерах, которые можно легко создать, вот несколько более сложных примеров, с извинениями за чрезмерное использование однострочных команд Perl:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)));
B 0
A 1
B 2
A 3
B 4
A 5

Это классический пример одного производителя, подающего два одновременных потребителя: один процесс perl генерирует строки с числами от 0 до 5, а два параллельных процесса потребляют этот вывод, один добавляет префикс "A", другой "B" к строкам. Какой потребитель получит первую строку не детерминировано, но после того, как эта гонка будет выиграна, строки будут потребляться поочерёдно одним процессом, а затем другим. (Установление $|=1 в Perl заставляет каждую операцию print сбрасывать буфер stdout, что необходимо для работы этого примера. В противном случае весь вывод буферизуется и выводится в конвейер сразу, чтобы быть прочитанным только одним процессом-потребителем.)

Вот ещё один более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)));
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5

Этот пример похож на предыдущий, за исключением того, что есть два этапа потребителей, и этапы имеют разную задержку, поэтому они используют разное количество параллельных работников, чтобы поддерживать насыщенный пропускную способность.

Мы настоятельно рекомендуем вам попробовать все эти примеры, чтобы увидеть, как они работают.