Запуск внешних программ

Julia заимствует обрамление обратных кавычек для команд из оболочек, Perl и Ruby. Однако в Julia запись

julia> `echo hello`
`echo hello`

отличается по нескольким аспектам от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды, обратные кавычки создают объект Cmd для представления команды. Вы можете использовать этот объект для подключения команды к другим командам через каналы, run ее и read или write к ней.
• При запуске команды Julia не захватывает ее вывод, если вы не организуете это специально. Вместо этого вывод команды по умолчанию направляется в stdout, как это делается с помощью вызова libc's system.
• Команда никогда не запускается с оболочкой. Вместо этого Julia анализирует синтаксис команды напрямую, соответствующим образом интерполируя переменные и разделяя по словам, как это делает оболочка, соблюдая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia с использованием вызовов fork и exec.

Вот простой пример запуска внешней программы:

julia> mycommand = `echo hello`
`echo hello`

julia> typeof(mycommand)
Cmd

julia> run(mycommand);
hello

hello — это вывод команды echo, отправленный в stdout. Сам метод run возвращает nothing, и выбрасывает ErrorException, если внешняя команда не выполняется успешно.

Если вы хотите прочитать вывод внешней команды, можно использовать read:

julia> a = read(`echo hello`, String)
"hello\n"

julia> chomp(a) == "hello"
true

В более общем случае, вы можете использовать open для чтения из или записи во внешнюю команду.

julia> open(`less`, "w", stdout) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Имя программы и отдельные аргументы в команде можно получить и перебрать, как будто команда представляет собой массив строк:

julia> collect(`echo "foo bar"`)
2-element Array{String,1}:
 "echo"
 "foo bar"

julia> `echo "foo bar"`[2]
"foo bar"

Интерполяция

Предположим, вы хотите сделать что-то более сложное и использовать имя файла в переменной file в качестве аргумента команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Строки):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространённая ошибка при запуске внешних программ через оболочку состоит в том, что если имя файла содержит символы, являющиеся специальными для оболочки, это может вызвать нежелательное поведение. Например, вместо /etc/passwd, предположим, что мы хотим отсортировать содержимое файла /Volumes/External HD/data.csv. Попробуем это:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла оказалось в кавычках? Julia знает, что file должно интерполироваться как один аргумент, поэтому она цитирует слово за вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в фактическом цитировании; кавычки вставляются только для отображения пользователю. Это будет работать даже если вы интерполируете значение как часть слова оболочки:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path правильно экранирован. Но что если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"

julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив как часть слова оболочки, Julia эмулирует создание аргументов оболочки {a,b,c}:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Кроме того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартова произведения оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать массивы в прямом виде, вы можете использовать эту функциональность генерации, не создавая временных объектов массивов:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитаты

Неизбежно, что нужно написать команды, которые не так просты, и возникает необходимость в использовании цитат. Вот простой пример Perl-одиночной команды в командной строке оболочки:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Выражение Perl необходимо заключить в одинарные кавычки по двум причинам: чтобы пробелы не разделяли выражение на несколько слов оболочки, и чтобы использование переменных Perl, таких как $| (да, это имя переменной в Perl), не вызывало интерполяцию. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В целом, синтаксис обратных кавычек Julia тщательно разработан, чтобы вы могли просто скопировать и вставить команды оболочки в обратные кавычки, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как у оболочки. Единственное различие заключается в том, что интерполяция интегрирована и учитывает понятие Julia о том, что такое одно строковое значение и что такое контейнер для нескольких значений. Давайте попробуем эти два примера в Julia:

julia> A = `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(A);
0
1
2
3

julia> first = "A"; second = "B";

julia> B = `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(B);
1: A
2: B

Результаты идентичны, и поведение интерполяции Julia имитирует поведение оболочки с некоторыми улучшениями, обусловленными тем, что Julia поддерживает итерируемые объекты первого класса, в то время как большинство оболочек используют для этого строки, разделенные пробелами, что приводит к неоднозначностям. При попытке перенести команды оболочки в Julia, попробуйте сначала скопировать и вставить. Поскольку Julia показывает вам команды перед их запуском, вы можете легко и безопасно просто просмотреть её интерпретацию, не причиняя вреда.

Каналы

Символы метасимволов оболочки, такие как |, &, и >, должны быть заключены в кавычки (или экранированы) внутри обратных кавычек Julia:

julia> run(`echo hello '|' sort`);
hello | sort

julia> run(`echo hello \| sort`);
hello | sort

Это выражение вызывает команду echo с тремя словами в качестве аргументов: hello, |, и sort. Результатом является вывод одной строки: hello | sort. Как тогда создать канал? Вместо использования '|' внутри обратных кавычек, используйте pipeline:

julia> run(pipeline(`echo hello`, `sort`));
hello

Это направляет вывод команды echo в команду sort. Конечно, это не очень интересно, поскольку для сортировки есть только одна строка, но мы можем сделать гораздо более интересные вещи:

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это выводит пять наибольших идентификаторов пользователей в системе UNIX. Команды cut, sort и tail все запускаются как непосредственные дочерние процессы текущего процесса julia без промежуточного процесса оболочки. Julia сама выполняет работу по настройке каналов и соединению дескрипторов файлов, которая обычно выполняется оболочкой. Поскольку Julia делает это самостоятельно, она сохраняет больший контроль и может делать некоторые вещи, которые оболочка не может.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`);
world
hello

Порядок вывода здесь не определен, потому что два процесса echo запускаются почти одновременно и соревнуются за запись в дескриптор stdout, который они разделяют с процессом-родителем julia. Julia позволяет вам направить вывод обоих этих процессов в другую программу:

julia> run(pipeline(`echo world` & `echo hello`, `sort`));
hello
world

С точки зрения UNIX-каналов, здесь происходит создание единственного объекта UNIX-канала, в который записывают оба процесса echo, а другой конец канала читается командой sort.

Перенаправление ввода-вывода можно выполнить, передав ключевые аргументы stdin, stdout, и stderr в функцию pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Избегание тупика в каналах

При чтении и записи в оба конца канала из одного процесса важно избегать принудительного буферизации всех данных.

Например, при чтении всего вывода команды вызовите read(out, String), а не wait(process), поскольку первый активно потребляет все данные, записанные процессом, а второй попытается сохранить данные в буферах ядра, ожидая подключения читателя.

Другим распространённым решением является разделение читателя и записывателя канала на отдельные задачи Task:

writer = @async write(process, "data")
reader = @async do_compute(read(process, String))
wait(process)
fetch(reader)

Сложный пример

Сочетание языка программирования высокого уровня, абстракции команды первого класса и автоматического создания каналов между процессами — мощный инструмент. Чтобы продемонстрировать сложные каналы, которые можно легко создать, здесь приведены несколько более сложных примеров с извинениями за чрезмерное использование Perl-одиночных команд:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)));
B 0
A 1
B 2
A 3
B 4
A 5

Это классический пример одиночного производителя, который кормит двух одновременных потребителей: один процесс perl генерирует строки с числами от 0 до 5, в то время как два параллельных процесса потребляют этот вывод, один добавляет строки с буквой «А», другой — с буквой «B». Какой потребитель получит первую строку, не определено, но после того, как эта гонка будет выиграна, строки последовательно потребляются одним процессом, а затем другим. (Установка $|=1 в Perl заставляет каждую инструкцию print сбрасывать буфер stdout дескриптор, что необходимо для работы этого примера. В противном случае весь вывод буферизуется и печатается в канал сразу, чтобы его прочитал только один процесс потребителя.)

Вот ещё один более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)));
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5

Этот пример похож на предыдущий, за исключением того, что есть два этапа потребителей, и этапы имеют различную задержку, поэтому они используют различное количество параллельных рабочих процессов, чтобы поддерживать насыщенный пропускную способность.

Мы настоятельно рекомендуем вам попробовать все эти примеры, чтобы увидеть, как они работают.