Запуск внешних программ

Julia заимствует обрамление обратных кавычек для команд из оболочки, Perl и Ruby. Однако в Julia написание

julia> `echo hello`
`echo hello`

отличается в нескольких аспектах от поведения в различных оболочках, Perl или Ruby:

• Вместо немедленного запуска команды обратные кавычки создают объект Cmd для представления команды. Вы можете использовать этот объект для подключения команды к другим через каналы, run ее и read или write к ней.
• При запуске команды Julia не захватывает ее вывод, если вы не организуете это явно. Вместо этого вывод команды по умолчанию отправляется в stdout, как если бы вы использовали libc с вызовом system.
• Команда никогда не запускается с оболочкой. Вместо этого Julia анализирует синтаксис команды непосредственно, корректно интерполирует переменные и разделяет по словам, как это делала бы оболочка, соблюдая синтаксис цитирования оболочки. Команда запускается как непосредственный дочерний процесс julia с использованием fork и exec вызовов.

Вот простой пример запуска внешней программы:

julia> mycommand = `echo hello`
`echo hello`

julia> typeof(mycommand)
Cmd

julia> run(mycommand);
hello

hello — это вывод команды echo, отправленный в stdout. Сам метод run возвращает nothing, и выбрасывает ErrorException, если внешняя команда не выполняется успешно.

Если вы хотите прочитать вывод внешней команды, вместо этого можно использовать read:

julia> a = read(`echo hello`, String)
"hello\n"

julia> chomp(a) == "hello"
true

В более общем случае, вы можете использовать open для чтения из или записи во внешнюю команду.

julia> open(`less`, "w", stdout) do io
           for i = 1:3
               println(io, i)
           end
       end
1
2
3

Имя программы и отдельные аргументы в команде могут быть доступны и перебираемы, как если бы команда была массивом строк:

julia> collect(`echo "foo bar"`)
2-element Array{String,1}:
 "echo"
 "foo bar"

julia> `echo "foo bar"`[2]
"foo bar"

Интерполяция

Предположим, вы хотите сделать что-то немного более сложное и использовать имя файла в переменной file в качестве аргумента для команды. Вы можете использовать $ для интерполяции так же, как и в строковой литерале (см. Strings):

julia> file = "/etc/passwd"
"/etc/passwd"

julia> `sort $file`
`sort /etc/passwd`

Распространенная ошибка при запуске внешних программ через оболочку заключается в том, что если имя файла содержит символы, которые являются специальными для оболочки, они могут вызвать нежелательное поведение. Например, вместо /etc/passwd, мы хотели отсортировать содержимое файла /Volumes/External HD/data.csv. Давайте попробуем:

julia> file = "/Volumes/External HD/data.csv"
"/Volumes/External HD/data.csv"

julia> `sort $file`
`sort '/Volumes/External HD/data.csv'`

Как имя файла оказалось в кавычках? Julia понимает, что file предназначено для интерполяции как единого аргумента, поэтому цитирует слово за вас. На самом деле, это не совсем точно: значение file никогда не интерпретируется оболочкой, поэтому нет необходимости в фактическом цитировании; кавычки вставляются только для представления пользователю. Это также будет работать, если вы интерполируете значение в качестве части слова оболочки:

julia> path = "/Volumes/External HD"
"/Volumes/External HD"

julia> name = "data"
"data"

julia> ext = "csv"
"csv"

julia> `sort $path/$name.$ext`
`sort '/Volumes/External HD/data.csv'`

Как видите, пробел в переменной path должным образом экранирован. Но что, если вы хотите интерполировать несколько слов? В этом случае просто используйте массив (или любой другой итерируемый контейнер):

julia> files = ["/etc/passwd","/Volumes/External HD/data.csv"]
2-element Array{String,1}:
 "/etc/passwd"
 "/Volumes/External HD/data.csv"

julia> `grep foo $files`
`grep foo /etc/passwd '/Volumes/External HD/data.csv'`

Если вы интерполируете массив в качестве части слова оболочки, Julia эмулирует генерацию аргументов оболочки {a,b,c}:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> `grep xylophone $names.txt`
`grep xylophone foo.txt bar.txt baz.txt`

Кроме того, если вы интерполируете несколько массивов в одно и то же слово, эмулируется поведение генерации декартова произведения оболочки:

julia> names = ["foo","bar","baz"]
3-element Array{String,1}:
 "foo"
 "bar"
 "baz"

julia> exts = ["aux","log"]
2-element Array{String,1}:
 "aux"
 "log"

julia> `rm -f $names.$exts`
`rm -f foo.aux foo.log bar.aux bar.log baz.aux baz.log`

Поскольку вы можете интерполировать буквальные массивы, вы можете использовать эту генеративную функциональность, не создавая временные объекты массивов:

julia> `rm -rf $["foo","bar","baz","qux"].$["aux","log","pdf"]`
`rm -rf foo.aux foo.log foo.pdf bar.aux bar.log bar.pdf baz.aux baz.log baz.pdf qux.aux qux.log qux.pdf`

Цитирование

Неизбежно, что нужно написать команды, которые не такие простые, и возникает необходимость в использовании кавычек. Вот простой пример Perl-однострочника в командной строке оболочки:

sh$ perl -le '$|=1; for (0..3) { print }'
0
1
2
3

Выражение Perl должно быть в одинарных кавычках по двум причинам: чтобы пробелы не разбили выражение на несколько слов оболочки, и чтобы использование переменных Perl, таких как $| (да, это имя переменной в Perl), не вызвало интерполяцию. В других случаях вы можете использовать двойные кавычки, чтобы интерполяция произошла:

sh$ first="A"
sh$ second="B"
sh$ perl -le '$|=1; print for @ARGV' "1: $first" "2: $second"
1: A
2: B

В целом, синтаксис обратных кавычек в Julia тщательно разработан таким образом, чтобы вы могли просто скопировать и вставить команды оболочки в обратные кавычки, и они будут работать: поведение экранирования, цитирования и интерполяции такое же, как у оболочки. Единственное отличие заключается в том, что интерполяция интегрирована и учитывает представление Julia о том, что такое единичное строковое значение и что является контейнером для нескольких значений. Давайте попробуем эти два примера в Julia:

julia> A = `perl -le '$|=1; for (0..3) { print }'`
`perl -le '$|=1; for (0..3) { print }'`

julia> run(A);
0
1
2
3

julia> first = "A"; second = "B";

julia> B = `perl -le 'print for @ARGV' "1: $first" "2: $second"`
`perl -le 'print for @ARGV' '1: A' '2: B'`

julia> run(B);
1: A
2: B

Результаты идентичны, и поведение интерполяции в Julia имитирует поведение оболочки с некоторыми улучшениями из-за того, что Julia поддерживает итерируемые объекты первого класса, в то время как большинство оболочек используют для этого строки, разделенные пробелами, что вводит неоднозначность. При попытке перенести команды оболочки в Julia, сначала попробуйте скопировать и вставить. Поскольку Julia показывает вам команды перед их запуском, вы можете легко и безопасно просто изучить их интерпретацию, не причиняя никакого вреда.

Каналы

Символы метакоманд оболочки, такие как |, &, и >, должны быть цитированы (или экранированы) внутри обратных кавычек Julia:

julia> run(`echo hello '|' sort`);
hello | sort

julia> run(`echo hello \| sort`);
hello | sort

Это выражение вызывает команду echo с тремя словами в качестве аргументов: hello, |, и sort. Результатом является вывод одной строки: hello | sort. Как же тогда построить канал? Вместо использования '|' внутри обратных кавычек, используется pipeline:

julia> run(pipeline(`echo hello`, `sort`));
hello

Это передает вывод команды echo команде sort. Конечно, это не очень интересно, так как сортировать нужно только одну строку, но мы можем делать намного более интересные вещи:

julia> run(pipeline(`cut -d: -f3 /etc/passwd`, `sort -n`, `tail -n5`))
210
211
212
213
214

Это выводит пять самых высоких идентификаторов пользователей в системе UNIX. Команды cut, sort и tail все запускаются как непосредственные дочерние процессы текущего julia процесса без промежуточных процессов оболочки. Julia сама выполняет работу по настройке каналов и соединению дескрипторов файлов, что обычно выполняет оболочка. Так как Julia делает это сама, она сохраняет больший контроль и может делать некоторые вещи, которые оболочка не может.

Julia может запускать несколько команд параллельно:

julia> run(`echo hello` & `echo world`);
world
hello

Порядок вывода здесь не детерминированный, потому что два процесса echo запускаются почти одновременно и соревнуются за выполнение первой записи в дескриптор stdout, который они совместно используют с друг другом и с процессом julia родителя. Julia позволяет вам передавать вывод обоих этих процессов другой программе:

julia> run(pipeline(`echo world` & `echo hello`, `sort`));
hello
world

С точки зрения UNIX-соединений, здесь создается один объект канала UNIX, в который записывают оба процесса echo, а с другой стороны канала читает команда sort.

Перенаправление ввода-вывода может быть выполнено путем передачи ключевых аргументов stdin, stdout, и stderr функции pipeline:

pipeline(`do_work`, stdout=pipeline(`sort`, "out.txt"), stderr="errs.txt")

Избегание тупика в каналах

При чтении и записи на обоих концах канала из одного процесса важно избегать принуждения ядра к буферизации всех данных.

Например, при чтении всего вывода из команды используйте read(out, String), а не wait(process), так как первый активно потребляет все данные, написанные процессом, в то время как второй попытается сохранить данные в буферах ядра, ожидая подключения читателя.

Еще одно распространенное решение — разделить читателя и писателя канала на отдельные задачи Task:

writer = @async write(process, "data")
reader = @async do_compute(read(process, String))
wait(writer)
fetch(reader)

Сложный пример

Сочетание высокоуровневого языка программирования, абстракции команд первого класса и автоматической настройки каналов между процессами — мощный инструмент. Чтобы дать представление о сложных каналах, которые можно легко создать, вот еще несколько усложненных примеров, с извинениями за чрезмерное использование Perl-однострочников:

julia> prefixer(prefix, sleep) = `perl -nle '$|=1; print "'$prefix' ", $_; sleep '$sleep';'`;

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`, prefixer("A",2) & prefixer("B",2)));
B 0
A 1
B 2
A 3
B 4
A 5

Это классический пример одного производителя, который питает двух одновременных потребителей: один процесс perl генерирует строки с числами от 0 до 5, а два параллельных процесса потребляют этот вывод, один добавляет к строкам букву «A», а другой — букву «B». Какой потребитель получит первую строку, не определено, но, как только эта гонка завершится, строки будут попеременно потребляться одним процессом, а затем другим. (Установка $|=1 в Perl заставляет каждую инструкцию print очищать обработчик stdout, что необходимо для работы этого примера. В противном случае весь вывод буферизуется и выводится в канал сразу, чтобы его прочитал только один процесс потребителя.)

Вот еще один более сложный пример многоступенчатого производителя-потребителя:

julia> run(pipeline(`perl -le '$|=1; for(0..5){ print; sleep 1 }'`,
           prefixer("X",3) & prefixer("Y",3) & prefixer("Z",3),
           prefixer("A",2) & prefixer("B",2)));
A X 0
B Y 1
A Z 2
B X 3
A Y 4
B Z 5

Этот пример похож на предыдущий, но есть два этапа потребителей, и у этапов разная задержка, поэтому они используют разное количество параллельных рабочих процессов для поддержания насыщенной пропускной способности.

Мы настоятельно рекомендуем вам попробовать все эти примеры, чтобы увидеть, как они работают.