Пропущенные значения

Julia предоставляет поддержку представления пропущенных значений в статистическом смысле, то есть для ситуаций, когда для переменной в наблюдении нет значения, но теоретически существует допустимое значение. Пропущенные значения представляются объектом missing, который является одиночным экземпляром типа Missing. missing эквивалентно NULL в SQL и NA в R, и ведет себя подобно им в большинстве ситуаций.

Распространение пропущенных значений

missing значения распространяются автоматически при передаче в стандартные математические операторы и функции. Для этих функций неопределенность относительно значения одного из операндов вызывает неопределенность относительно результата. На практике это означает, что математическая операция, включающая в себя missing значение, обычно возвращает missing

julia> missing + 1
missing

julia> "a" * missing
missing

julia> abs(missing)
missing

Поскольку missing является обычным объектом Julia, это правило распространения работает только для функций, которые выбрали реализовать это поведение. Это может быть достигнуто либо посредством определения специального метода для аргументов типа Missing, либо просто путем принятия аргументов этого типа и передачи их функциям, которые их распространяют (например, стандартным математическим операторам). Пакеты должны учитывать, целесообразно ли распространять пропущенные значения при определении новых функций и определять соответствующие методы, если это необходимо. Передача missing значения функции, для которой не определен метод, принимающий аргументы типа Missing, приводит к ошибке MethodError, как и для любого другого типа.

Функции, которые не распространяют missing значения, могут быть заменены на такие, которые это делают, путем обертывания их в функцию passmissing, предоставляемую пакетом Missings.jl. Например, f(x) становится passmissing(f)(x).

Операторы равенства и сравнения

Стандартные операторы равенства и сравнения следуют правилу распространения, представленному выше: если любой из операндов является missing, результат является missing. Вот несколько примеров

julia> missing == 1
missing

julia> missing == missing
missing

julia> missing < 1
missing

julia> 2 >= missing
missing

В частности, обратите внимание, что missing == missing возвращает missing, поэтому == нельзя использовать для проверки того, является ли значение пропущенным. Чтобы проверить, является ли x missing, используйте ismissing(x).

Специальные операторы сравнения isequal и === являются исключениями из правила распространения: они всегда возвращают Bool значение, даже в присутствии missing значений, рассматривая missing как равное missing и отличное от любого другого значения. Поэтому их можно использовать для проверки того, является ли значение missing

julia> missing === 1
false

julia> isequal(missing, 1)
false

julia> missing === missing
true

julia> isequal(missing, missing)
true

Оператор isless — другое исключение: missing считается больше, чем любое другое значение. Этот оператор используется функцией sort, которая, следовательно, помещает missing значения после всех других значений.

julia> isless(1, missing)
true

julia> isless(missing, Inf)
false

julia> isless(missing, missing)
false

Логические операторы

Логические (или булевы) операторы |, & и xor — это еще один особый случай, поскольку они распространяют missing значения только тогда, когда это логически необходимо. Для этих операторов неопределенность результата зависит от конкретной операции, следуя хорошо установленным правилам трехзначной логики, которые также реализованы в NULL в SQL и NA в R. Это абстрактное определение на самом деле соответствует относительно естественному поведению, которое лучше всего объяснить на конкретных примерах.

Давайте проиллюстрируем этот принцип на примере логического оператора «или» |. В соответствии с правилами булевой логики, если один из операндов является true, значение другого операнда не влияет на результат, который всегда будет true

julia> true | true
true

julia> true | false
true

julia> false | true
true

Исходя из этого наблюдения, мы можем сделать вывод, что если один из операндов является true, а другой missing, мы знаем, что результат будет true, несмотря на неопределенность относительно фактического значения одного из операндов. Если бы мы смогли наблюдать фактическое значение второго операнда, оно могло бы быть только true или false, и в обоих случаях результатом было бы true. Следовательно, в этом конкретном случае пропущенность не распространяется

julia> true | missing
true

julia> missing | true
true

Напротив, если один из операндов является false, результат может быть либо true, либо false, в зависимости от значения другого операнда. Следовательно, если этот операнд является missing, результат также должен быть missing

julia> false | true
true

julia> true | false
true

julia> false | false
false

julia> false | missing
missing

julia> missing | false
missing

Поведение логического оператора «и» & аналогично поведению оператора |, с той разницей, что пропущенность не распространяется, когда один из операндов является false. Например, когда это относится к первому операнду

julia> false & false
false

julia> false & true
false

julia> false & missing
false

С другой стороны, пропущенность распространяется, когда один из операндов является true, например, первый

julia> true & true
true

julia> true & false
false

julia> true & missing
missing

Наконец, логический оператор «исключающее или» xor всегда распространяет missing значения, поскольку оба операнда всегда влияют на результат. Также обратите внимание, что оператор отрицания ! возвращает missing, когда операнд является missing, как и другие унарные операторы.

Операторы управления потоком и короткого замыкания

Операторы управления потоком, включая if, while и условный оператор x ? y : z, не допускают пропущенных значений. Это связано с неопределенностью того, будет ли фактическое значение true или false при его наблюдении, что подразумевает, что мы не знаем, как программа должна вести себя. Ошибка TypeError возникает, как только встречается missing значение в этом контексте

julia> if missing
           println("here")
       end
ERROR: TypeError: non-boolean (Missing) used in boolean context

По той же причине, в отличие от логических операторов, представленных выше, операторы короткого замыкания && и || не допускают missing значений в ситуациях, когда значение операнда определяет, будет ли оцениваться следующий операнд или нет. Например

julia> missing || false
ERROR: TypeError: non-boolean (Missing) used in boolean context

julia> missing && false
ERROR: TypeError: non-boolean (Missing) used in boolean context

julia> true && missing && false
ERROR: TypeError: non-boolean (Missing) used in boolean context

С другой стороны, ошибка не возникает, когда результат может быть определен без missing значений. Это происходит, когда код короткого замыкания происходит до оценки missing операнда, и когда missing операнд является последним

julia> true && missing
missing

julia> false && missing
false

Массивы с пропущенными значениями

Массивы, содержащие пропущенные значения, могут быть созданы как и другие массивы

julia> [1, missing]
2-element Array{Union{Missing, Int64},1}:
 1
  missing

Как показывает этот пример, тип элементов таких массивов является Union{Missing, T}, где T — тип значений, которые не являются пропущенными. Это просто отражает тот факт, что элементы массива могут быть либо типа T (здесь Int64), либо типа Missing. Такой массив использует эффективное хранение памяти, эквивалентное Array{T} , содержащему фактические значения, в сочетании с Array{UInt8} , указывающим на тип элемента (то есть, является ли он Missing или T).

Массивы, допускающие пропущенные значения, могут быть созданы со стандартной синтаксической конструкцией. Используйте Array{Union{Missing, T}}(missing, dims) для создания массивов, заполненных пропущенными значениями:

julia> Array{Union{Missing, String}}(missing, 2, 3)
2×3 Array{Union{Missing, String},2}:
 missing  missing  missing
 missing  missing  missing

Массив, допускающий missing значения, но не содержащий таких значений, может быть преобразован обратно в массив, не допускающий пропущенных значений, с помощью convert. Если массив содержит missing значения, во время преобразования генерируется MethodError

julia> x = Union{Missing, String}["a", "b"]
2-element Array{Union{Missing, String},1}:
 "a"
 "b"

julia> convert(Array{String}, x)
2-element Array{String,1}:
 "a"
 "b"

julia> y = Union{Missing, String}[missing, "b"]
2-element Array{Union{Missing, String},1}:
 missing
 "b"

julia> convert(Array{String}, y)
ERROR: MethodError: Cannot `convert` an object of type Missing to an object of type String

Пропуск пропущенных значений

Поскольку missing значения распространяются стандартными математическими операторами, функции редукции возвращают missing при вызове на массивах, содержащих пропущенные значения

julia> sum([1, missing])
missing

В этой ситуации используйте функцию skipmissing для пропуска пропущенных значений

julia> sum(skipmissing([1, missing]))
1

Эта функция удобства возвращает итератор, который эффективно фильтрует missing значения. Таким образом, она может использоваться с любой функцией, поддерживающей итераторы

julia> x = skipmissing([3, missing, 2, 1])
skipmissing(Union{Missing, Int64}[3, missing, 2, 1])

julia> maximum(x)
3

julia> mean(x)
2.0

julia> mapreduce(sqrt, +, x)
4.146264369941973

Объекты, созданные с помощью вызова skipmissing для массива, могут индексироваться с использованием индексов из родительского массива. Индексы, соответствующие пропущенным значениям, не являются допустимыми для этих объектов, и при попытке их использования возникает ошибка (они также пропускаются keys и eachindex)

julia> x[1]
3

julia> x[2]
ERROR: MissingException: the value at index (2,) is missing
[...]

Это позволяет функциям, работающим с индексами, работать в сочетании с skipmissing. Это особенно актуально для функций поиска и нахождения, которые возвращают индексы, допустимые для объекта, возвращенного skipmissing, которые также являются индексами соответствующих элементов в родительском массиве

julia> findall(==(1), x)
1-element Array{Int64,1}:
 4

julia> findfirst(!iszero, x)
1

julia> argmax(x)
1

Используйте collect для извлечения значений, не являющихся missing, и сохранения их в массиве

julia> collect(x)
3-element Array{Int64,1}:
 3
 2
 1

Логические операции над массивами

Трехзначная логика, описанная выше для логических операторов, также используется логическими функциями, применяемыми к массивам. Таким образом, тесты на равенство массивов с использованием оператора == возвращают missing всякий раз, когда результат нельзя определить без знания фактического значения missing элемента. На практике это означает, что возвращается missing , если все не пропущенные значения сравниваемых массивов равны, но один или оба массива содержат пропущенные значения (возможно, в разных позициях)

julia> [1, missing] == [2, missing]
false

julia> [1, missing] == [1, missing]
missing

julia> [1, 2, missing] == [1, missing, 2]
missing

Что касается отдельных значений, используйте isequal, чтобы рассматривать missing значения как равные другим missing значениям, но отличные от не пропущенных значений

julia> isequal([1, missing], [1, missing])
true

julia> isequal([1, 2, missing], [1, missing, 2])
false

Функции any и all также следуют правилам трехзначной логики, возвращая missing , когда результат нельзя определить

julia> all([true, missing])
missing

julia> all([false, missing])
false

julia> any([true, missing])
true

julia> any([false, missing])
missing