Spec-Zone.ru › Julia 1.9

Типы

Системы типов традиционно делятся на два достаточно разных лагеря: статические системы типов, где каждый программный выражение должно иметь тип, вычислимый до выполнения программы, и динамические системы типов, где о типах ничего не известно до времени выполнения, когда доступны фактические значения, обрабатываемые программой. Объектно-ориентированное программирование позволяет некоторую гибкость в статически типизированных языках, позволяя писать код без знания точных типов значений во время компиляции. Способность писать код, который может работать с разными типами, называется полиморфизмом. Весь код в классических динамически типизированных языках является полиморфным: типы любых значений ограничиваются только при явном проверке типов или когда объекты не поддерживают операции во время выполнения.

Система типов Julia динамическая, но она приобретает некоторые преимущества статических систем типов, позволяя указывать, что некоторые значения имеют определенные типы. Это может быть очень полезно для генерации эффективного кода, но, что еще более важно, это позволяет диспатчу методов по типам аргументов функций глубоко интегрироваться с языком. Подробно диспатч методов рассматривается в Методах, но он укоренен в системе типов, представленной здесь.

По умолчанию в Julia, когда типы опущены, значения могут быть любого типа. Таким образом, можно написать многие полезные функции Julia, не используя явно типы. Однако, когда требуется дополнительная выразительность, легко постепенно вводить явные аннотации типов в ранее «нетипизированный» код. Добавление аннотаций служит трем основным целям: использовать мощный механизм множественного диспетчера Julia, повысить читаемость кода человеком и выявить ошибки программиста.

Описывая Julia на языке систем типов, она является: динамической, номинативной и параметрической. Обобщенные типы могут быть параметризованы, а иерархические отношения между типами явным образом объявляются, а не предполагаются по совместимой структуре. Одна из особенно отличительных черт системы типов Julia заключается в том, что конкретные типы не могут быть подтипами друг друга: все конкретные типы являются окончательными и могут иметь только абстрактные типы как свои супертипы. Хотя это может на первый взгляд показаться излишне ограничительно, это имеет много полезных последствий с удивительно небольшим количеством недостатков. Оказывается, что возможность наследования поведения гораздо важнее, чем возможность наследования структуры, а наследование обоих приводит к значительным трудностям в традиционных объектно-ориентированных языках. Другие аспекты высокого уровня системы типов Julia, которые следует упомянуть с самого начала:

  • Нет разделения между объектами и значениями, не являющимися объектами: все значения в Julia являются истинными объектами, имеющими тип, принадлежащий одному полностью соединенному графу типов, все узлы которого являются равноправными типами.
  • Нет осмысленного понятия «типа во время компиляции»: единственный тип значения — его фактический тип во время выполнения программы. Это называется «типом во время выполнения» в объектно-ориентированных языках, где сочетание статической компиляции с полиморфизмом делает это различие значимым.
  • Типы имеют только значения, а не переменные — переменные просто имена, связанные со значениями, хотя для простоты мы можем сказать «тип переменной» как сокращение от «тип значения, которому переменная ссылается».
  • И абстрактные, и конкретные типы могут быть параметризованы другими типами. Они также могут быть параметризованы символами, значениями любого типа, для которого isbits возвращает true (по существу, такие вещи, как числа и булевы значения, которые хранятся как типы C или struct без указателей на другие объекты), а также кортежами из них. Параметры типа могут быть опущены, когда они не должны быть упомянуты или ограничены.

Система типов Julia разработана для того, чтобы быть мощной и выразительной, но ясной, интуитивно понятной и незаметной. Многие программисты Julia могут никогда не чувствовать необходимости писать код, который явно использует типы. Однако некоторые типы программирования становятся более ясными, простыми, быстрыми и надежными с объявленными типами.

Объявления типов

Оператор :: может использоваться для добавления аннотаций типа к выражениям и переменным в программах. Есть две основные причины для этого:

  1. Как утверждение, чтобы подтвердить, что ваша программа работает так, как вы ожидаете,
  2. Чтобы предоставить дополнительную информацию о типе компилятору, который может в некоторых случаях улучшить производительность

При добавлении к выражению, вычисляющему значение, оператор :: читается как «является экземпляром». Его можно использовать в любом месте, чтобы утверждать, что значение выражения слева является экземпляром типа справа. Когда тип справа является конкретным, значение слева должно иметь этот тип как реализацию — вспомните, что все конкретные типы являются окончательными, поэтому никакая реализация не является подтипом любой другой. Когда тип является абстрактным, достаточно, чтобы значение реализовывалось конкретным типом, который является подтипом абстрактного типа. Если утверждение типа неверно, выбрасывается исключение, в противном случае возвращается значение левой части:

julia> (1+2)::AbstractFloat
ERROR: TypeError: in typeassert, expected AbstractFloat, got a value of type Int64

julia> (1+2)::Int
3

Это позволяет прикрепить утверждение типа к любому выражению на месте.

При добавлении к переменной в левой части присваивания или как часть объявления local, оператор :: означает нечто немного другое: он объявляет переменную как имеющую всегда указанный тип, как объявление типа в статически типизированном языке, таком как C. Каждое присваивание переменной будет преобразовано в объявленный тип с помощью convert:

julia> function foo()
           x::Int8 = 100
           x
       end
foo (generic function with 1 method)

julia> x = foo()
100

julia> typeof(x)
Int8

Эта функция полезна для предотвращения проблем с производительностью, которые могут возникнуть, если одно из присваиваний переменной неожиданно изменит её тип.

Это поведение «объявления» происходит только в определенных контекстах:

local x::Int8  # in a local declaration
x::Int8 = 10   # as the left-hand side of an assignment

и применяется ко всему текущему пространству имен, даже до объявления.

Начиная с Julia 1.8, объявления типов теперь могут использоваться в глобальной области видимости, т. е. к глобальным переменным можно добавить аннотации типов, чтобы сделать доступ к ним стабильным с точки зрения типов.

julia> x::Int = 10
10

julia> x = 3.5
ERROR: InexactError: Int64(3.5)

julia> function foo(y)
           global x = 15.8    # throws an error when foo is called
           return x + y
       end
foo (generic function with 1 method)

julia> foo(10)
ERROR: InexactError: Int64(15.8)

Объявления также могут быть присоединены к определениям функций:

function sinc(x)::Float64
    if x == 0
        return 1
    end
    return sin(pi*x)/(pi*x)
end

Возвращение из этой функции ведет себя так же, как присвоение переменной с объявленным типом: значение всегда преобразуется к Float64.

Абстрактные типы

Абстрактные типы не могут быть экземпляризированы и служат только узлами в графе типов, тем самым описывая наборы родственных конкретных типов: те конкретные типы, которые являются их потомками. Мы начинаем с абстрактных типов, даже если они не имеют экземпляризации, потому что они являются основой системы типов: они образуют концептуальную иерархию, которая делает систему типов Julia чем-то большим, чем просто коллекцией реализаций объектов.

Вспомните, что в Целых и числах с плавающей точкой мы представили различные конкретные типы числовых значений: Int8, UInt8, Int16, UInt16, Int32, UInt32, Int64, UInt64, Int128, UInt128, Float16, Float32 и Float64. Несмотря на разные размеры представления, Int8, Int16, Int32, Int64 и Int128 имеют общее свойство: они являются целыми типами со знаком. Аналогично, UInt8, UInt16, UInt32, UInt64 и UInt128 являются беззнаковыми целыми типами, а Float16, Float32 и Float64 отличаются тем, что являются типами с плавающей запятой, а не целыми числами. Часто бывает так, что фрагмент кода имеет смысл только тогда, когда его аргументы являются целыми числами, но фактически не зависит от того, какого рода целого числа это. Например, алгоритм наибольшего общего делителя работает для всех видов целых чисел, но не работает для чисел с плавающей точкой. Абстрактные типы позволяют построить иерархию типов, предоставляя контекст, в котором могут разместиться конкретные типы. Это позволяет, например, легко программировать для любого типа, являющегося целым числом, без ограничения алгоритма определённым типом целого числа.

Абстрактные типы объявляются с помощью ключевого слова abstract type. Общие синтаксические конструкции для объявления абстрактного типа:

abstract type «name» end
abstract type «name» <: «supertype» end

Ключевое слово abstract type вводит новый абстрактный тип, имя которого задается «name». Это имя может быть необязательно дополнено <: и уже существующим типом, указывающим, что только что объявленный абстрактный тип является подтипом этого «родительского» типа.

Если супертип не указан, по умолчанию супертипом является Any — предопределённый абстрактный тип, экземплярами которого являются все объекты, а подтипами которого являются все типы. В теории типов Any обычно называется «верхним», потому что он находится на вершине графа типов. Julia также имеет предопределённый абстрактный «нижний» тип в самой нижней части графа типов, который записывается как Union{}. Он является точной противоположностью Any: ни один объект не является экземпляром Union{} и все типы являются супертипами Union{}.

Давайте рассмотрим некоторые абстрактные типы, которые образуют числовую иерархию Julia:

abstract type Number end
abstract type Real          <: Number end
abstract type AbstractFloat <: Real end
abstract type Integer       <: Real end
abstract type Signed        <: Integer end
abstract type Unsigned      <: Integer end

Тип Number является прямым дочерним типом Any, а Real — его дочерним. В свою очередь, Real имеет два дочерних типа (их больше, но здесь показаны только два; до других мы доберемся позже): Integer и AbstractFloat, разделяя мир на представления целых и действительных чисел. Представления действительных чисел включают типы с плавающей запятой, но также и другие типы, такие как рациональные числа. AbstractFloat включает только представления действительных чисел с плавающей запятой. Целые числа далее подразделяются на разновидности Signed и Unsigned.

Оператор <: в общем смысле означает «является подтипом», и, используемый в объявлениях, подобных вышеприведённым, он объявляет тип справа немедленным надтипом объявленного типа. Он также может использоваться в выражениях как оператор подтипов, возвращающий true когда его левый операнд является подтипом его правого операнда:

julia> Integer <: Number
true

julia> Integer <: AbstractFloat
false

Важное применение абстрактных типов заключается в предоставлении реализаций по умолчанию для конкретных типов. Для примера рассмотрим:

function myplus(x,y)
    x+y
end

Первым делом следует отметить, что вышеприведенные объявления аргументов эквивалентны x::Any и y::Any. При вызове этой функции, например, как myplus(2,5), диспетчер выбирает наиболее специфический метод с именем myplus , соответствующий заданным аргументам. (Дополнительная информация о множественном диспетчеризации содержится в разделе Методы.)

Предполагая, что метод, более специфичный, чем вышеприведенный, не найден, Julia затем внутренне определяет и компилирует метод под названием myplus специально для двух аргументов Int на основе предоставленной выше обобщенной функции, то есть неявно определяет и компилирует:

function myplus(x::Int,y::Int)
    x+y
end

и, наконец, вызывает этот конкретный метод.

Таким образом, абстрактные типы позволяют программистам писать обобщенные функции, которые впоследствии могут использоваться в качестве метода по умолчанию множеством комбинаций конкретных типов. Благодаря множественному диспетчеризации программист полностью контролирует, используется метод по умолчанию или более специфичный метод.

Следует отметить, что нет потери производительности, если программист полагается на функцию, аргументы которой — абстрактные типы, поскольку она перекомпилируется для каждой кортежи конкретных типов аргументов, с которыми она вызывается. (Однако, может возникнуть проблема производительности в случае аргументов функций, которые являются контейнерами абстрактных типов; см. Рекомендации по производительности.)

Примитивные типы

Почти всегда предпочтительнее обернуть существующий примитивный тип в новый составной тип, чем определять свой собственный примитивный тип.

Эта функциональность существует, чтобы позволить Julia запустить стандартные примитивные типы, которые поддерживает LLVM. После их определения, почти нет оснований для определения большего количества.

Примитивный тип — это конкретный тип, данные которого состоят из обычных битов. Классическими примерами примитивных типов являются целые числа и значения с плавающей точкой. В отличие от большинства языков, Julia позволяет объявлять свои собственные примитивные типы, а не предоставлять только фиксированный набор встроенных.

Фактически, все стандартные примитивные типы определены в самом языке:

primitive type Float16 <: AbstractFloat 16 end
primitive type Float32 <: AbstractFloat 32 end
primitive type Float64 <: AbstractFloat 64 end

primitive type Bool <: Integer 8 end
primitive type Char <: AbstractChar 32 end

primitive type Int8    <: Signed   8 end
primitive type UInt8   <: Unsigned 8 end
primitive type Int16   <: Signed   16 end
primitive type UInt16  <: Unsigned 16 end
primitive type Int32   <: Signed   32 end
primitive type UInt32  <: Unsigned 32 end
primitive type Int64   <: Signed   64 end
primitive type UInt64  <: Unsigned 64 end
primitive type Int128  <: Signed   128 end
primitive type UInt128 <: Unsigned 128 end

Общие синтаксисы для объявления примитивного типа:

primitive type «name» «bits» end
primitive type «name» <: «supertype» «bits» end

Количество битов указывает, сколько памяти требуется типу, а имя присваивает новое имя типу. Примитивный тип можно необязательно объявить как подтип какого-либо надтипа. Если надтип опущен, то тип по умолчанию имеет Any в качестве непосредственного надтипа. Таким образом, объявление Bool означает, что для хранения булевого значения требуется восемь бит и имеет Integer в качестве непосредственного надтипа. В настоящее время поддерживаются только размеры, кратные 8 битам, и вы, вероятно, столкнетесь с ошибками LLVM при размерах, отличных от используемых выше. Поэтому булевы значения, хотя и требуют всего одного бита, не могут быть объявлены меньше, чем восемь битов.

Типы Bool, Int8 и UInt8 имеют одинаковое представление: они представляют собой восьмибитные блоки памяти. Однако, поскольку система типов Julia номинативная, они не взаимозаменяемы, несмотря на идентичную структуру. Основное различие заключается в том, что у них разные надтипы: непосредственный надтип Bool — это Integer, надтип Int8 — Signed, а надтип UInt8 — Unsigned. Все остальные различия между Bool, Int8 и UInt8 — вопросы поведения — то, как функции определены для работы при предоставлении им объектов этих типов в качестве аргументов. Вот почему необходима номинативная система типов: если структура определяла тип, а тип в свою очередь определял поведение, то было бы невозможно заставить Bool вести себя по-другому, чем Int8 или UInt8.

Составные типы

Составные типы называются записями, структурами или объектами в различных языках. Составной тип — это набор именованных полей, экземпляр которого может рассматриваться как одно значение.

Во многих языках составные типы являются единственным видом определяемых пользователем типов, и они являются, пожалуй, наиболее часто используемыми определяемыми пользователем типами в Julia.

В распространённых объектно-ориентированных языках, таких как C++, Java, Python и Ruby, составные типы также имеют связанные с ними именованные функции, и это сочетание называется «объектом». В более чистых объектно-ориентированных языках, таких как Ruby или Smalltalk, все значения являются объектами, независимо от того, являются ли они составными или нет. В менее чистых объектно-ориентированных языках, включая C++ и Java, некоторые значения, такие как целые числа и значения с плавающей точкой, не являются объектами, в то время как экземпляры составных типов, определённых пользователем, являются истинными объектами с соответствующими методами.

В Julia все значения являются объектами, но функции не связаны с объектами, над которыми они работают. Это необходимо, поскольку Julia выбирает, какой метод функции использовать, с помощью множественного диспетчеризации, что означает, что при выборе метода рассматриваются типы всех аргументов функции, а не только первого (см. Методы для получения дополнительной информации о методах и диспетчеризации). Поэтому было бы неуместно, чтобы функции «принадлежали» только своему первому аргументу.

Организация методов в объекты функций, а не именованные наборы методов «внутри» каждого объекта, в конечном итоге является очень полезным аспектом проектирования языка.

Составные типы вводятся с помощью ключевого слова struct, за которым следует блок имён полей, необязательно аннотированных типами с помощью оператора :::

julia> struct Foo
           bar
           baz::Int
           qux::Float64
       end

Поля без аннотации типа по умолчанию имеют тип Any, и соответственно могут содержать значения любого типа.

Новые объекты типа Foo создаются путём применения объекта типа Foo как функции к значениям его полей:

julia> foo = Foo("Hello, world.", 23, 1.5)
Foo("Hello, world.", 23, 1.5)

julia> typeof(foo)
Foo

Когда тип применяется как функция, он называется конструктором. Автоматически генерируются два конструктора (они называются конструкторами по умолчанию). Один принимает любые аргументы и вызывает convert для преобразования их в типы полей, а другой принимает аргументы, которые точно соответствуют типам полей. Причина, по которой оба генерируются, заключается в том, что это облегчает добавление новых определений, не заменяя нечаянно конструктор по умолчанию.

Поскольку поле bar не ограничено типом, подойдёт любое значение. Однако значение для baz должно быть преобразуемо к типу Int:

julia> Foo((), 23.5, 1)
ERROR: InexactError: Int64(23.5)
Stacktrace:
[...]

Список имён полей можно получить с помощью функции fieldnames.

julia> fieldnames(Foo)
(:bar, :baz, :qux)

Значения полей составного объекта можно получить с помощью традиционного обозначения foo.bar:

julia> foo.bar
"Hello, world."

julia> foo.baz
23

julia> foo.qux
1.5

Составные объекты, объявленные с помощью struct , являются неизменяемыми; они не могут быть изменены после создания.

Это может показаться странным на первый взгляд, но у этого есть несколько преимуществ:

  • Это может быть более эффективным. Некоторые структуры могут быть эффективно упакованы в массивы, и в некоторых случаях компилятор может вообще избежать выделения неизменяемых объектов.
  • Невозможно нарушить инварианты, предоставляемые конструкторами типа.
  • Код, использующий неизменяемые объекты, может быть проще для понимания.

Неизменяемый объект может содержать изменяемые объекты, такие как массивы, в качестве полей. Эти содержащиеся объекты останутся изменяемыми; только поля самого неизменяемого объекта не могут быть изменены, чтобы указывать на разные объекты.

В случае необходимости изменяемые составные объекты можно объявить с ключевым словом mutable struct, которое будет обсуждаться в следующей секции.

Если все поля неизменяемой структуры неразличимы (===), то два неизменяемых значения, содержащие эти поля, также неразличимы:

julia> struct X
           a::Int
           b::Float64
       end

julia> X(1, 2) === X(1, 2)
true

Есть много нюансов, касающихся создания экземпляров составных типов, но это обсуждение зависит как от Параметрических типов, так и от Методов, и достаточно важно, чтобы быть рассмотренным в отдельной секции: Конструкторы.

Для многих типов, определённых пользователем X, вы можете определить метод Base.broadcastable(x::X) = Ref(x), чтобы экземпляры этого типа действовали как 0-мерные «скаляры» для векторизации.

Изменяемые составные типы

Если составной тип объявлен с mutable struct вместо struct, то его экземпляры можно изменять:

julia> mutable struct Bar
           baz
           qux::Float64
       end

julia> bar = Bar("Hello", 1.5);

julia> bar.qux = 2.0
2.0

julia> bar.baz = 1//2
1//2

Дополнительный интерфейс между полями и пользователем может быть предоставлен через Свойства экземпляров. Это предоставляет больший контроль над тем, что можно получить и изменить, используя обозначение bar.baz.

Для поддержки изменения таких объектов они обычно выделяются в куче и имеют стабильные адреса памяти. Изменяемый объект похож на небольшой контейнер, который может содержать разные значения со временем, и поэтому его можно надёжно идентифицировать только по его адресу. В отличие от этого, экземпляр неизменяемого типа связан с конкретными значениями полей — сами значения полей полностью определяют объект. При решении вопроса о том, сделать ли тип изменяемым, спросите, будут ли два экземпляра с одинаковыми значениями полей считаться идентичными, или им может потребоваться изменяться независимо со временем. Если они будут считаться идентичными, тип, вероятно, должен быть неизменяемым.

Вкратце, две основные характеристики определяют неизменяемость в Julia:

  • Не разрешается изменять значение неизменяемого типа.
    • Для битовых типов это означает, что битовая структура значения, установленная однажды, никогда не изменится, и это значение является идентификатором битового типа.
    • Для составных типов это означает, что идентичность значений его полей никогда не изменится. Когда поля являются битовыми типами, это означает, что их биты никогда не изменятся, а для полей, значения которых являются изменяемыми типами, такими как массивы, это означает, что поля всегда будут ссылаться на одно и то же изменяемое значение, даже если содержимое этого изменяемого значения само может быть изменено.
  • Объект с неизменяемым типом может быть свободно скопирован компилятором, поскольку его неизменяемость делает невозможным программно отличить исходный объект от копии.
    • В частности, это означает, что достаточно маленькие неизменяемые значения, такие как целые числа и числа с плавающей запятой, обычно передаются функциям в регистрах (или выделены в стеке).
    • Изменяемые значения, с другой стороны, выделяются в куче и передаются функциям как указатели на значения, выделенные в куче, за исключением случаев, когда компилятор уверен, что нет способа понять, что это не так.

В тех случаях, когда одно или несколько полей в структуре, которая в противном случае является изменяемой, известно как неизменяемое, эти поля можно объявить как таковые, используя const как показано ниже. Это позволяет использовать некоторые, но не все оптимизации неизменяемых структур и может использоваться для принуждения инвариантов к конкретным полям, помеченным как const.

const аннотирование полей изменяемых структур требует как минимум Julia 1.8.

julia> mutable struct Baz
           a::Int
           const b::Float64
       end

julia> baz = Baz(1, 1.5);

julia> baz.a = 2
2

julia> baz.b = 2.0
ERROR: setfield!: const field .b of type Baz cannot be changed
[...]

Объявленные типы

Три вида типов (абстрактные, примитивные, составные), обсуждавшиеся в предыдущих разделах, на самом деле тесно связаны. Они имеют общие ключевые свойства:

  • Они объявлены явно.
  • Они имеют имена.
  • Они имеют явно объявленные супертипы.
  • Они могут иметь параметры.

Из-за этих общих свойств эти типы в интерпретаторе представлены как экземпляры одной и той же концепции, DataType, которая является типом любого из этих типов:

julia> typeof(Real)
DataType

julia> typeof(Int)
DataType

Тип DataType может быть абстрактным или конкретным. Если он конкретный, он имеет указанный размер, схему хранения и (по желанию) имена полей. Таким образом, примитивный тип является DataType с ненулевым размером, но без имён полей. Составной тип является DataType, имеющим имена полей или пустым (нулевого размера).

Каждое конкретное значение в системе является экземпляром некоторого DataType.

Объединения типов

Объединение типов — это специальный абстрактный тип, который включает в себя все объекты, являющиеся экземплярами любого из его аргументов типов, построенный с использованием специального ключевого слова Union:

julia> IntOrString = Union{Int,AbstractString}
Union{Int64, AbstractString}

julia> 1 :: IntOrString
1

julia> "Hello!" :: IntOrString
"Hello!"

julia> 1.0 :: IntOrString
ERROR: TypeError: in typeassert, expected Union{Int64, AbstractString}, got a value of type Float64

Компиляторы многих языков имеют внутренний конструктор объединений для работы с типами; Julia просто предоставляет его программисту. Компилятор Julia может генерировать эффективный код в присутствии типов Union с небольшим количеством типов [1], сгенерировав специализированный код в отдельных ветвях для каждого возможного типа.

Особенно полезным случаем типа Union является Union{T, Nothing}, где T может быть любым типом, а Nothing — это единичный тип, единственным экземпляром которого является объект nothing. Этот шаблон является эквивалентом Julia для Nullable, Option или Maybe типов в других языках. Объявление аргумента функции или поля как Union{T, Nothing} позволяет установить его либо в значение типа T, либо в nothing для обозначения отсутствия значения. Дополнительную информацию см. в этой записи FAQ.

Параметрические типы

Важной и мощной особенностью системы типов Julia является то, что она параметрическая: типы могут принимать параметры, так что объявления типов фактически вводят целую семью новых типов — по одному для каждой возможной комбинации значений параметров. Есть много языков, которые поддерживают какую-либо версию обобщённого программирования, где структуры данных и алгоритмы для их обработки могут быть определены без указания точных типов. Например, некоторая форма обобщённого программирования существует в ML, Haskell, Ada, Eiffel, C++, Java, C#, F# и Scala, чтобы назвать лишь несколько. Некоторые из этих языков поддерживают истинную параметрическую полиморфизм (например, ML, Haskell, Scala), в то время как другие поддерживают неформальные, основанные на шаблонах стили обобщённого программирования (например, C++, Java). С таким разнообразием видов обобщённого программирования и параметрических типов в различных языках мы даже не будем пытаться сравнить параметрические типы Julia с другими языками, а вместо этого сосредоточимся на объяснении системы Julia как таковой. Однако мы отметим, что поскольку Julia — динамически типизированный язык и не должен принимать все решения о типе во время компиляции, многие традиционные трудности, возникающие в статических системах параметрических типов, могут быть относительно легко решены.

Все объявленные типы (разновидности DataType ) могут быть параметризованными, с тем же синтаксисом в каждом случае. Мы обсудим их в следующем порядке: сначала параметрические составные типы, затем параметрические абстрактные типы и, наконец, параметрические примитивные типы.

Параметрические составные типы

Параметры типа вводятся сразу после имени типа, заключённые в фигурные скобки:

julia> struct Point{T}
           x::T
           y::T
       end

Это объявление определяет новый параметрический тип, Point{T}, содержащий две «координаты» типа T. Что же такое T? Ну, это именно суть параметрических типов: это может быть любой тип вообще (или значение любого битового типа, на самом деле, хотя здесь он явно используется как тип). Point{Float64} — это конкретный тип, эквивалентный типу, определённому путём замены T в определении Point на Float64. Таким образом, это единственное объявление фактически объявляет неограниченное количество типов: Point{Float64}, Point{AbstractString}, Point{Int64}, и т. д. Каждый из них теперь является пригодным для использования конкретным типом:

julia> Point{Float64}
Point{Float64}

julia> Point{AbstractString}
Point{AbstractString}

Тип Point{Float64} — это точка, координаты которой — 64-битные числа с плавающей запятой, а тип Point{AbstractString} — это «точка», «координаты» которой — строковые объекты (см. Строки).

Point сам по себе также является допустимым объектом типа, содержащим все экземпляры Point{Float64}, Point{AbstractString}, и т. д. в качестве подтипов:

julia> Point{Float64} <: Point
true

julia> Point{AbstractString} <: Point
true

Другие типы, конечно, не являются подтипами:

julia> Float64 <: Point
false

julia> AbstractString <: Point
false

Конкретные типы Point с различными значениями T никогда не являются подтипами друг друга:

julia> Point{Float64} <: Point{Int64}
false

julia> Point{Float64} <: Point{Real}
false

Этот последний момент очень важен: даже если Float64 <: Real у нас НЕТ Point{Float64} <: Point{Real}.

Другими словами, в терминологии теории типов, параметры типа Julia являются инвариантными, а не ковариантными (или даже контравариантными). Это по практическим причинам: хотя любой экземпляр Point{Float64} концептуально может быть похож на экземпляр Point{Real} также, два типа имеют разные представления в памяти:

  • Экземпляр Point{Float64} может быть компактно и эффективно представлен как пара непосредственных 64-битных значений;
  • Экземпляр Point{Real} должен иметь возможность содержать любую пару экземпляров Real. Поскольку объекты, являющиеся экземплярами Real, могут быть произвольного размера и структуры, на практике экземпляр Point{Real} должен быть представлен как пара указателей на индивидуально выделенные объекты Real.

Эффективность, получаемая от возможности хранения объектов Point{Float64} с непосредственными значениями, значительно возрастает в случае массивов: массив Array{Float64} может храниться как непрерывный блок памяти 64-битных чисел с плавающей запятой, тогда как массив Array{Real} должен быть массивом указателей на индивидуально выделенные объекты Real — которые могут быть упакованными 64-битными значениями с плавающей запятой, но также могут быть произвольно большими, сложными объектами, которые объявлены как реализации абстрактного типа Real.

Поскольку Point{Float64} не является подтипом Point{Real} , следующая функция не может применяться к аргументам типа Point{Float64}:

function norm(p::Point{Real})
    sqrt(p.x^2 + p.y^2)
end

Правильный способ определения функции, принимающей все аргументы типа Point{T} где T является подтипом Real:

function norm(p::Point{<:Real})
    sqrt(p.x^2 + p.y^2)
end

(В качестве альтернативы можно определить function norm(p::Point{T} where T<:Real) или function norm(p::Point{T}) where T<:Real; см. Объединения всех типов.)

Дополнительные примеры будут рассмотрены позже в Методах.

Как создать объект Point? Можно определить пользовательские конструкторы для составных типов, которые будут подробно рассмотрены в Конструкторах, но в отсутствие специальных объявлений конструкторов есть два стандартных способа создания новых составных объектов: один с явно указанными параметрами типа и другой, в котором они подразумеваются аргументами конструктора объекта.

Поскольку тип Point{Float64} — это конкретный тип, эквивалентный Point с Float64 вместо T, его можно использовать как конструктор соответственно:

julia> p = Point{Float64}(1.0, 2.0)
Point{Float64}(1.0, 2.0)

julia> typeof(p)
Point{Float64}

Для конструктора по умолчанию необходимо указать ровно один аргумент для каждого поля:

julia> Point{Float64}(1.0)
ERROR: MethodError: no method matching Point{Float64}(::Float64)
[...]

julia> Point{Float64}(1.0,2.0,3.0)
ERROR: MethodError: no method matching Point{Float64}(::Float64, ::Float64, ::Float64)
[...]

Для параметрических типов генерируется только один конструктор по умолчанию, так как его переопределение невозможно. Этот конструктор принимает любые аргументы и преобразует их в типы полей.

Во многих случаях излишне указывать тип объекта Point , который нужно создать, поскольку типы аргументов вызова конструктора уже неявно предоставляют информацию о типе. По этой причине вы также можете использовать Point в качестве конструктора, при условии, что подразумеваемое значение типа параметра T однозначно:

julia> p1 = Point(1.0,2.0)
Point{Float64}(1.0, 2.0)

julia> typeof(p1)
Point{Float64}

julia> p2 = Point(1,2)
Point{Int64}(1, 2)

julia> typeof(p2)
Point{Int64}

В случае Point, тип T однозначно подразумевается тогда и только тогда, когда два аргумента Point имеют одинаковый тип. Если это не так, конструктор завершится с ошибкой MethodError:

julia> Point(1,2.5)
ERROR: MethodError: no method matching Point(::Int64, ::Float64)

Closest candidates are:
  Point(::T, !Matched::T) where T
   @ Main none:2

Stacktrace:
[...]

Методы конструкторов для правильной обработки таких смешанных случаев можно определить, но это не будет рассматриваться до тех пор, пока мы не дойдем до Конструкторов далее.

Параметрические абстрактные типы

Объявления параметрических абстрактных типов объявляют набор абстрактных типов, в значительной степени аналогично:

julia> abstract type Pointy{T} end

С этим объявлением Pointy{T} представляет собой отдельный абстрактный тип для каждого типа или целого значения T. Как и в случае с параметрическими составными типами, каждая такая инстанция является подтипом Pointy:

julia> Pointy{Int64} <: Pointy
true

julia> Pointy{1} <: Pointy
true

Параметрические абстрактные типы являются инвариантными, так же как и параметрические составные типы:

julia> Pointy{Float64} <: Pointy{Real}
false

julia> Pointy{Real} <: Pointy{Float64}
false

Запись Pointy{<:Real} используется для выражения аналога типа ковариантности в Julia, в то время как Pointy{>:Int} — аналога контравариантности, но технически они представляют собой множества типов (см. Типы UnionAll).

julia> Pointy{Float64} <: Pointy{<:Real}
true

julia> Pointy{Real} <: Pointy{>:Int}
true

Так же, как обычные абстрактные типы служат для создания полезной иерархии типов над конкретными типами, параметрические абстрактные типы выполняют ту же функцию по отношению к параметрическим составным типам. Например, мы можем объявить Point{T} подтипом Pointy{T} следующим образом:

julia> struct Point{T} <: Pointy{T}
           x::T
           y::T
       end

Ввиду такого объявления для каждого выбора T Point{T} является подтипом Pointy{T}:

julia> Point{Float64} <: Pointy{Float64}
true

julia> Point{Real} <: Pointy{Real}
true

julia> Point{AbstractString} <: Pointy{AbstractString}
true

Это отношение также инвариантно:

julia> Point{Float64} <: Pointy{Real}
false

julia> Point{Float64} <: Pointy{<:Real}
true

Какую цель преследуют параметрические абстрактные типы, такие как Pointy? Представьте, что мы создаем реализацию точки, которая требует только одной координаты, поскольку точка находится на диагональной прямой x = y:

julia> struct DiagPoint{T} <: Pointy{T}
           x::T
       end

Теперь как Point{Float64}, так и DiagPoint{Float64} являются реализациями абстракции Pointy{Float64}, и аналогично для любого другого возможного выбора типа T. Это позволяет программировать на общем интерфейсе, который разделяют все объекты Pointy, реализованном как для Point, так и для DiagPoint. Однако это нельзя полностью продемонстрировать, пока мы не представим методы и диспетчеризацию в следующем разделе Методы.

Существуют ситуации, когда параметрам типа не следует свободно варьироваться по всем возможным типам. В таких ситуациях можно ограничить диапазон T следующим образом:

julia> abstract type Pointy{T<:Real} end

С таким объявлением можно использовать любой тип, который является подтипом Real вместо T, но не типы, которые не являются подтипами Real:

julia> Pointy{Float64}
Pointy{Float64}

julia> Pointy{Real}
Pointy{Real}

julia> Pointy{AbstractString}
ERROR: TypeError: in Pointy, in T, expected T<:Real, got Type{AbstractString}

julia> Pointy{1}
ERROR: TypeError: in Pointy, in T, expected T<:Real, got a value of type Int64

Параметры типа параметрических составных типов можно ограничить аналогичным образом:

struct Point{T<:Real} <: Pointy{T}
    x::T
    y::T
end

В качестве реального примера того, как вся эта параметрическая механизма типов может быть полезной, вот фактическое определение неизменяемого типа Julia Rational (за исключением того, что мы опускаем конструктор для простоты), представляющего точную дробь целых чисел:

struct Rational{T<:Integer} <: Real
    num::T
    den::T
end

Принимать отношения целых чисел имеет смысл, поэтому тип параметра T ограничен как подтип Integer, и отношение целых чисел представляет собой значение на числовой прямой, поэтому любой Rational является экземпляром абстракции Real.

Кортежи (Tuple)

Кортежи — это абстракция аргументов функции без самой функции. Существенными аспектами аргументов функции являются их порядок и типы. Поэтому тип кортежа похож на параметрический неизменяемый тип, где каждый параметр — тип одного поля. Например, тип кортежа из 2 элементов похож на следующий неизменяемый тип:

struct Tuple2{A,B}
    a::A
    b::B
end

Однако есть три ключевых различия:

  • Типы кортежей могут иметь любое количество параметров.
  • Типы кортежей ковариантны по своим параметрам: Tuple{Int} является подтипом Tuple{Any}. Следовательно Tuple{Any} считается абстрактным типом, а типы кортежей являются конкретными только если их параметры являются конкретными.
  • У кортежей нет имен полей; поля доступны только по индексу.

Значения кортежей записываются в скобках с запятыми. При создании кортежа соответствующий тип кортежа генерируется по требованию:

julia> typeof((1,"foo",2.5))
Tuple{Int64, String, Float64}

Обратите внимание на последствия ковариантности:

julia> Tuple{Int,AbstractString} <: Tuple{Real,Any}
true

julia> Tuple{Int,AbstractString} <: Tuple{Real,Real}
false

julia> Tuple{Int,AbstractString} <: Tuple{Real,}
false

Интуитивно это соответствует тому, что тип аргументов функции является подтипом подписи функции (когда подпись совпадает).

Типы кортежей с переменным числом аргументов (Vararg)

Последний параметр типа кортежа может быть специальным значением Vararg, которое обозначает любое количество последующих элементов:

julia> mytupletype = Tuple{AbstractString,Vararg{Int}}
Tuple{AbstractString, Vararg{Int64}}

julia> isa(("1",), mytupletype)
true

julia> isa(("1",1), mytupletype)
true

julia> isa(("1",1,2), mytupletype)
true

julia> isa(("1",1,2,3.0), mytupletype)
false

Кроме того Vararg{T} соответствует нулю или более элементам типа T. Типы кортежей с переменным числом аргументов используются для представления аргументов, принимаемых методами с переменным числом аргументов (см. Функции с переменным числом аргументов).

Специальное значение Vararg{T,N} (когда используется в качестве последнего параметра типа кортежа) соответствует ровно N элементам типа T. NTuple{N,T} — удобный псевдоним для Tuple{Vararg{T,N}}, т. е. типа кортежа, содержащего ровно N элементов типа T.

Именованные типы кортежей

Именованные кортежи являются экземплярами типа NamedTuple, у которого есть два параметра: кортеж символов, задающих имена полей, и тип кортежа, задающий типы полей.

julia> typeof((a=1,b="hello"))
NamedTuple{(:a, :b), Tuple{Int64, String}}

Макрос @NamedTuple обеспечивает более удобную синтаксическую конструкцию, похожую на struct, для объявления типов NamedTuple через объявления key::Type, где пропущенный ::Type соответствует ::Any.

julia> @NamedTuple{a::Int, b::String}
NamedTuple{(:a, :b), Tuple{Int64, String}}

julia> @NamedTuple begin
           a::Int
           b::String
       end
NamedTuple{(:a, :b), Tuple{Int64, String}}

Тип NamedTuple может использоваться в качестве конструктора, принимающего один аргумент-кортеж. Созданный тип NamedTuple может быть либо конкретным типом, с указанными обоими параметрами, либо типом, определяющим только имена полей:

julia> @NamedTuple{a::Float32,b::String}((1,""))
(a = 1.0f0, b = "")

julia> NamedTuple{(:a, :b)}((1,""))
(a = 1, b = "")

Если типы полей указаны, аргументы преобразуются. В противном случае используются типы аргументов.

Параметрические примитивные типы

Примитивные типы также могут быть объявлены параметрически. Например, указатели представлены как примитивные типы, которые объявляются в Julia так:

# 32-bit system:
primitive type Ptr{T} 32 end

# 64-bit system:
primitive type Ptr{T} 64 end

Несколько необычная особенность этих объявлений по сравнению с типичными параметрическими составными типами заключается в том, что параметр типа T не используется в определении самого типа — он просто является абстрактной меткой, по существу определяющей целое семейство типов с одинаковой структурой, отличающихся только параметром типа. Таким образом, Ptr{Float64} и Ptr{Int64} — это разные типы, несмотря на то, что они имеют одинаковое представление. И, конечно же, все конкретные типы указателей являются подтипами обобщающего типа Ptr:

julia> Ptr{Float64} <: Ptr
true

julia> Ptr{Int64} <: Ptr
true

Типы UnionAll

Мы сказали, что параметрический тип, такой как Ptr , действует как надтип всех его экземпляров (Ptr{Int64} и т. д.). Как это работает? Ptr сам по себе не может быть обычным типом данных, поскольку без знания типа ссылаемых данных тип явно не может использоваться для операций с памятью. Ответ заключается в том, что Ptr (или другие параметрические типы, такие как Array ) — это другой тип, называемый типом UnionAll. Такой тип выражает итерированное объединение типов для всех значений некоторого параметра.

UnionAll типы обычно записываются с использованием ключевого слова where. Например Ptr можно более точно записать как Ptr{T} where T, что означает все значения, тип которых Ptr{T} для некоторого значения T. В этом контексте параметр T часто также называется «переменной типа», поскольку он похож на переменную, которая принимает значения типов. Каждый where вводит одну переменную типа, поэтому эти выражения вложены для типов с несколькими параметрами, например Array{T,N} where N where T.

Синтаксис применения типа A{B,C} требует, чтобы A был типом UnionAll, и сначала заменяет B на внешнюю переменную типа в A. Результат должен быть другим типом UnionAll, в который затем подставляется C. Таким образом, A{B,C} эквивалентно A{B}{C}. Это объясняет, почему можно частично инстанцировать тип, как в Array{Float64}: первое значение параметра было зафиксировано, но второе всё ещё принимает все возможные значения. Используя явный синтаксис where, можно зафиксировать любой подмножество параметров. Например, тип всех одномерных массивов можно записать как Array{T,1} where T.

Переменные типа могут быть ограничены отношениями подтипов. Array{T} where T<:Integer относится ко всем массивам, тип элементов которых — какой-либо вид Integer. Синтаксис Array{<:Integer} — это удобное сокращение для Array{T} where T<:Integer. Переменные типа могут иметь как нижние, так и верхние границы. Array{T} where Int<:T<:Number относится ко всем массивам Number, которые могут содержать Int (поскольку T должен быть по крайней мере так же большим, как Int). Синтаксис where T>:Int также работает для указания только нижней границы переменной типа, и Array{>:Int} эквивалентно Array{T} where T>:Int.

Так как выражения where вложены, границы переменных типа могут ссылаться на внешние переменные типа. Например, Tuple{T,Array{S}} where S<:AbstractArray{T} where T<:Real относится к двум кортежам, первый элемент которого — какой-либо Real, а второй элемент — Array любого типа массива, тип элементов которого содержит тип первого элемента кортежа.

Ключевое слово where само по себе может быть вложено в более сложное объявление. Например, рассмотрим два типа, созданные следующими объявлениями:

julia> const T1 = Array{Array{T, 1} where T, 1}
Vector{Vector} (alias for Array{Array{T, 1} where T, 1})

julia> const T2 = Array{Array{T, 1}, 1} where T
Array{Vector{T}, 1} where T

Тип T1 определяет одномерный массив одномерных массивов; каждый из внутренних массивов состоит из объектов одного типа, но этот тип может меняться от одного внутреннего массива к другому. С другой стороны, тип T2 определяет одномерный массив одномерных массивов, все внутренние массивы которых должны иметь один и тот же тип. Обратите внимание, что T2 — это абстрактный тип, например Array{Array{Int,1},1} <: T2, тогда как T1 — это конкретный тип. Вследствие этого T1 можно создать с конструктором без аргументов a=T1(), но T2 нельзя.

Существует удобный синтаксис для именования таких типов, похожий на сокращённую форму синтаксиса определения функций:

Vector{T} = Array{T, 1}

Это эквивалентно const Vector = Array{T,1} where T. Запись Vector{Float64} эквивалентна записи Array{Float64,1}, и тип Vector содержит все объекты Array, где второй параметр — число измерений массива — равен 1, независимо от типа элемента. В языках, где параметрические типы всегда должны быть указаны полностью, это не особенно полезно, но в Julia это позволяет записать просто Vector для абстрактного типа, включающего все одномерные плотные массивы любого типа элемента.

Типы-синглетоны

Неизменяемые составные типы без полей называются синглетонами. Формально, если

  1. T — это неизменяемый составной тип (т. е. определён с помощью struct),
  2. a isa T && b isa T подразумевает a === b,

тогда T — это тип-синглетон.[2] Base.issingletontype можно использовать для проверки, является ли тип типом-синглетоном. Абстрактные типы по определению не могут быть типами-синглетонами.

Из определения следует, что может быть только один экземпляр таких типов:

julia> struct NoFields
       end

julia> NoFields() === NoFields()
true

julia> Base.issingletontype(NoFields)
true

Функция === подтверждает, что созданные экземпляры NoFields фактически представляют собой один и тот же объект.

Параметрические типы могут быть типами-синглетонами, когда выполняется указанное выше условие. Например,

julia> struct NoFieldsParam{T}
       end

julia> Base.issingletontype(NoFieldsParam) # Can't be a singleton type ...
false

julia> NoFieldsParam{Int}() isa NoFieldsParam # ... because it has ...
true

julia> NoFieldsParam{Bool}() isa NoFieldsParam # ... multiple instances.
true

julia> Base.issingletontype(NoFieldsParam{Int}) # Parametrized, it is a singleton.
true

julia> NoFieldsParam{Int}() === NoFieldsParam{Int}()
true

Типы функций

Каждая функция имеет свой собственный тип, который является подтипом Function.

julia> foo41(x) = x + 1
foo41 (generic function with 1 method)

julia> typeof(foo41)
typeof(foo41) (singleton type of function foo41, subtype of Function)

Обратите внимание, как typeof(foo41) печатается как само по себе. Это всего лишь соглашение для вывода на печать, так как это первый объект, который можно использовать как любое другое значение:

julia> T = typeof(foo41)
typeof(foo41) (singleton type of function foo41, subtype of Function)

julia> T <: Function
true

Типы функций, определённых на верхнем уровне, являются типами-синглетонами. При необходимости их можно сравнивать с помощью ===.

Замыкания также имеют свой собственный тип, который обычно печатается с именами, заканчивающимися на #<number>. Имена и типы для функций, определённых в разных местах, различны, но не гарантируется, что они будут выводиться одинаково в разных сессиях.

julia> typeof(x -> x + 1)
var"#9#10"

Типы замыканий необязательно являются типами-синглетонами.

julia> addy(y) = x -> x + y
addy (generic function with 1 method)

julia> typeof(addy(1)) === typeof(addy(2))
true

julia> addy(1) === addy(2)
false

julia> Base.issingletontype(typeof(addy(1)))
false

Type{T} селекторы типа

Для каждого типа T, Type{T} — это абстрактный параметрический тип, единственным экземпляром которого является объект T. Пока мы не обсудим Параметрические методы и преобразования, трудно объяснить полезность этого построения, но коротко — оно позволяет специализировать поведение функции на конкретных типах как значениях. Это полезно для написания методов (особенно параметрических), поведение которых зависит от типа, задаваемого в качестве явного аргумента, а не подразумеваемого типом одного из его аргументов.

Поскольку определение немного сложно для анализа, давайте рассмотрим некоторые примеры:

julia> isa(Float64, Type{Float64})
true

julia> isa(Real, Type{Float64})
false

julia> isa(Real, Type{Real})
true

julia> isa(Float64, Type{Real})
false

Другими словами, isa(A, Type{B}) истинно тогда и только тогда, когда A и B — один и тот же объект, и этот объект является типом.

В частности, поскольку параметрические типы являются инвариантными, у нас есть

julia> struct TypeParamExample{T}
           x::T
       end

julia> TypeParamExample isa Type{TypeParamExample}
true

julia> TypeParamExample{Int} isa Type{TypeParamExample}
false

julia> TypeParamExample{Int} isa Type{TypeParamExample{Int}}
true

Без параметра Type — это просто абстрактный тип, экземплярами которого являются все объекты типов:

julia> isa(Type{Float64}, Type)
true

julia> isa(Float64, Type)
true

julia> isa(Real, Type)
true

Любой объект, который не является типом, не является экземпляром Type:

julia> isa(1, Type)
false

julia> isa("foo", Type)
false

Хотя Type является частью иерархии типов Julia, как и любой другой абстрактный параметрический тип, он редко используется за пределами сигнатур методов, за исключением некоторых особых случаев. Другое важное применение Type — уточнение типов полей, которые в противном случае были бы описаны менее точно, например, как DataType в примере ниже, где конструктор по умолчанию может привести к проблемам производительности в коде, полагающемся на точный тип упаковки (аналогично параметрам абстрактного типа).

julia> struct WrapType{T}
       value::T
       end

julia> WrapType(Float64) # default constructor, note DataType
WrapType{DataType}(Float64)

julia> WrapType(::Type{T}) where T = WrapType{Type{T}}(T)
WrapType

julia> WrapType(Float64) # sharpened constructor, note more precise Type{Float64}
WrapType{Type{Float64}}(Float64)

Псевдонимы типов

Иногда удобно ввести новое имя для уже выразимого типа. Это можно сделать с помощью простого оператора присваивания. Например, UInt является псевдонимом либо UInt32, либо UInt64, в зависимости от размера указателей на данной системе:

# 32-bit system:
julia> UInt
UInt32

# 64-bit system:
julia> UInt
UInt64

Это достигается с помощью следующего кода в base/boot.jl:

if Int === Int64
    const UInt = UInt64
else
    const UInt = UInt32
end

Конечно, это зависит от того, к чему Int является псевдонимом — но это предопределённый правильный тип — либо Int32, либо Int64.

(Обратите внимание, что в отличие от Int, Float не существует как псевдоним типа для AbstractFloat определённого размера. В отличие от целочисленных регистров, где размер Int отражает размер системного указателя на этой машине, размеры регистров с плавающей точкой задаются стандартом IEEE-754.)

Операции с типами

Поскольку типы в Julia являются сами по себе объектами, обычные функции могут с ними работать. Некоторые функции, которые особенно полезны для работы с типами или исследования типов, уже были введены, например, оператор <:, который показывает, является ли левый операнд подтипом правого операнда.

Функция isa проверяет, является ли объект данного типа, и возвращает true или false:

julia> isa(1, Int)
true

julia> isa(1, AbstractFloat)
false

Функция typeof, уже используемая в примерах по всему руководству, возвращает тип своего аргумента. Поскольку, как отмечалось выше, типы являются объектами, они также имеют типы, и мы можем узнать, каковы их типы:

julia> typeof(Rational{Int})
DataType

julia> typeof(Union{Real,String})
Union

Что если мы повторим процесс? Какой тип у типа типа? Как оказывается, типы — это все составные значения, и поэтому все они имеют тип DataType:

julia> typeof(DataType)
DataType

julia> typeof(Union)
DataType

DataType — это собственный тип.

Ещё одна операция, которая применяется к некоторым типам, это supertype, которая раскрывает супертип типа. Только объявленные типы (DataType) имеют однозначные супертипы:

julia> supertype(Float64)
AbstractFloat

julia> supertype(Number)
Any

julia> supertype(AbstractString)
Any

julia> supertype(Any)
Any

Если вы примените supertype к другим объектам типов (или не-типам), возникнет ошибка MethodError:

julia> supertype(Union{Float64,Int64})
ERROR: MethodError: no method matching supertype(::Type{Union{Float64, Int64}})
Closest candidates are:
[...]

Настройка вывода в читаемом формате

Часто требуется настроить отображение экземпляров типа. Это достигается перегрузкой функции show. Например, предположим, что мы определили тип для представления комплексных чисел в полярной форме:

julia> struct Polar{T<:Real} <: Number
           r::T
           Θ::T
       end

julia> Polar(r::Real,Θ::Real) = Polar(promote(r,Θ)...)
Polar

Здесь мы добавили пользовательскую функцию-конструктор, чтобы она могла принимать аргументы разных Real типов и преобразовывать их к общему типу (см. Конструкторы и Преобразование и повышение). (Конечно, нам пришлось бы определить множество других методов, чтобы она работала как Number, например, +, *, one, zero, правила повышения и так далее.) По умолчанию экземпляры этого типа отображаются довольно просто, с информацией о имени типа и значениях полей, например, Polar{Float64}(3.0,4.0).

Если мы хотим, чтобы он отображался как 3.0 * exp(4.0im), мы бы определили следующий метод для вывода объекта в заданный объект вывода io (представляющий файл, терминал, буфер и т. д.; см. Сети и потоки):

julia> Base.show(io::IO, z::Polar) = print(io, z.r, " * exp(", z.Θ, "im)")

Более тонкий контроль над отображением объектов Polar возможен. В частности, иногда требуется как подробный многострочный формат вывода, используемый для отображения одного объекта в REPL и других интерактивных средах, так и более компактный однострочный формат, используемый для print или для отображения объекта как части другого объекта (например, в массиве). Хотя по умолчанию функция show(io, z) вызывается в обоих случаях, вы можете определить другой многострочный формат для отображения объекта, перегрузив трехаргументную форму show, которая принимает тип MIME text/plain в качестве второго аргумента (см. Мультимедийный ввод/вывод), например:

julia> Base.show(io::IO, ::MIME"text/plain", z::Polar{T}) where{T} =
           print(io, "Polar{$T} complex number:\n   ", z)

(Обратите внимание, что print(..., z) здесь вызовет метод show(io, z) с 2 аргументами.) Это приводит к:

julia> Polar(3, 4.0)
Polar{Float64} complex number:
   3.0 * exp(4.0im)

julia> [Polar(3, 4.0), Polar(4.0,5.3)]
2-element Vector{Polar{Float64}}:
 3.0 * exp(4.0im)
 4.0 * exp(5.3im)

где однострочный формат show(io, z) по-прежнему используется для массива значений Polar. Технически, REPL вызывает display(z) для отображения результата выполнения строки, который по умолчанию равен show(stdout, MIME("text/plain"), z), который, в свою очередь, по умолчанию равен show(stdout, z), но вы не должны определять новые методы display, если вы не определяете новый обработчик мультимедийного отображения (см. Мультимедийный ввод/вывод).

Кроме того, вы также можете определить методы show для других типов MIME, чтобы включить более богатое отображение (HTML, изображения и т. д.) объектов в средах, которые поддерживают это (например, IJulia). Например, мы можем определить форматированное отображение HTML объектов Polar с надстрочными и курсивными символами следующим образом:

julia> Base.show(io::IO, ::MIME"text/html", z::Polar{T}) where {T} =
           println(io, "<code>Polar{$T}</code> complex number: ",
                   z.r, " <i>e</i><sup>", z.Θ, " <i>i</i></sup>")

Объект Polar затем будет отображаться автоматически с помощью HTML в среде, которая поддерживает отображение HTML, но вы можете вызвать show вручную, чтобы получить вывод HTML, если хотите:

julia> show(stdout, "text/html", Polar(3.0,4.0))
<code>Polar{Float64}</code> complex number: 3.0 <i>e</i><sup>4.0 <i>i</i></sup>

Рендерер HTML отобразит это как: Polar{Float64} комплексное число: 3.0 e4.0 i

Как правило, метод show в одну строку должен выводить допустимое выражение Julia для создания отображаемого объекта. Когда этот метод show содержит инфиксные операторы, такие как оператор умножения (*) в нашем однострочном методе show для Polar выше, он может не правильно анализироваться при печати как часть другого объекта. Чтобы увидеть это, рассмотрите объект выражения (см. Представление программы), который принимает квадрат определенного экземпляра нашего типа Polar:

julia> a = Polar(3, 4.0)
Polar{Float64} complex number:
   3.0 * exp(4.0im)

julia> print(:($a^2))
3.0 * exp(4.0im) ^ 2

Поскольку оператор ^ имеет более высокий приоритет, чем * (см. Приоритет операторов и ассоциативность), этот вывод не соответствует выражению a ^ 2, которое должно быть равно (3.0 * exp(4.0im)) ^ 2. Чтобы решить эту проблему, мы должны создать пользовательский метод для Base.show_unquoted(io::IO, z::Polar, indent::Int, precedence::Int), который вызывается внутри объекта выражения при печати:

julia> function Base.show_unquoted(io::IO, z::Polar, ::Int, precedence::Int)
           if Base.operator_precedence(:*) <= precedence
               print(io, "(")
               show(io, z)
               print(io, ")")
           else
               show(io, z)
           end
       end

julia> :($a^2)
:((3.0 * exp(4.0im)) ^ 2)

Определенный выше метод добавляет круглые скобки вокруг вызова show, когда приоритет вызывающего оператора не ниже приоритета умножения. Этот контроль позволяет выражениям, которые анализируются правильно без скобок (таким как :($a + 2) и :($a == 2)), пропускать их при печати:

julia> :($a + 2)
:(3.0 * exp(4.0im) + 2)

julia> :($a == 2)
:(3.0 * exp(4.0im) == 2)

В некоторых случаях полезно настраивать поведение методов show в зависимости от контекста. Этого можно добиться с помощью типа IOContext, который позволяет передавать контекстные свойства вместе с обернутым потоком ввода/вывода. Например, мы можем построить более короткое представление в нашем методе show , когда свойство :compact установлено в true, возвращаясь к длинному представлению, если свойство false установлено или отсутствует:

julia> function Base.show(io::IO, z::Polar)
           if get(io, :compact, false)::Bool
               print(io, z.r, "ℯ", z.Θ, "im")
           else
               print(io, z.r, " * exp(", z.Θ, "im)")
           end
       end

Это новое компактное представление будет использоваться, когда переданный поток ввода/вывода является объектом IOContext с установленным свойством :compact. В частности, это имеет место при выводе массивов с несколькими столбцами (где горизонтальное пространство ограничено):

julia> show(IOContext(stdout, :compact=>true), Polar(3, 4.0))
3.0ℯ4.0im

julia> [Polar(3, 4.0) Polar(4.0,5.3)]
1×2 Matrix{Polar{Float64}}:
 3.0ℯ4.0im  4.0ℯ5.3im

См. документацию по IOContext для списка общих свойств, которые могут быть использованы для настройки вывода.

"Типы значений"

В Julia нельзя выполнять диспетчеризацию по значению, например, true или false. Однако можно выполнять диспетчеризацию по параметрическим типам, и Julia позволяет включать значения «чистых битов» (Типы, Символы, Целые числа, числа с плавающей запятой, кортежи и т. д.) в качестве параметров типа. Типичный пример — параметр размерности в Array{T,N}, где T — тип (например, Float64), но N — просто Int.

Вы можете создать свои собственные пользовательские типы, которые принимают значения в качестве параметров, и использовать их для управления диспетчеризацией пользовательских типов. В качестве иллюстрации этой идеи давайте представим параметрический тип Val{x}, и его конструктор Val(x) = Val{x}(), который служит обычным способом использования этой техники в случаях, когда вам не нужна более сложная иерархия.

Val определен как:

julia> struct Val{x}
       end

julia> Val(x) = Val{x}()
Val

В реализации Val нет ничего больше. Некоторые функции стандартной библиотеки Julia принимают экземпляры Val в качестве аргументов, и вы также можете использовать их для написания собственных функций. Например:

julia> firstlast(::Val{true}) = "First"
firstlast (generic function with 1 method)

julia> firstlast(::Val{false}) = "Last"
firstlast (generic function with 2 methods)

julia> firstlast(Val(true))
"First"

julia> firstlast(Val(false))
"Last"

Для согласованности в Julia в месте вызова всегда следует передавать экземпляр Val , а не использовать тип, то есть использовать foo(Val(:bar)), а не foo(Val{:bar}).

Стоит отметить, что очень легко неправильно использовать параметрические типы «значений», включая Val; в неблагоприятных случаях вы легко можете значительно ухудшить производительность своего кода. В частности, вам никогда не следует писать фактический код, как показано выше. Для получения дополнительной информации о правильном (и неправильном) использовании Val, пожалуйста, прочтите более подробное обсуждение в советах по производительности.

  • 1«Малый» определяется константой MAX_UNION_SPLITTING, которая в настоящее время установлена в 4.
  • 2Некоторые популярные языки имеют типы-синглтоны, включая Haskell, Scala и Ruby.

© 2009–2023 Jeff Bezanson, Stefan Karpinski, Viral B. Shah, and other contributors
Licensed under the MIT License.
https://docs.julialang.org/en/v1.9/manual/types/

Spec-Zone.ru

Настройки Оффлайн Что нового Помощь О нас
Spec-Zone .ru
спецификации, руководства, описания, API