11.3 Collection CRUD Functions — MySQL Connectors 1.0

11.3 Функции CRUD для коллекций

CollectionFindFunction

Синтаксис этой функции в EBNF:

CollectionFindFunction
  ::= '.find(' SearchConditionStr? ')' ( '.fields(' ProjectedDocumentExprStr ')' )?
      ( '.groupBy(' SearchExprStrList ')' )? ( '.having(' SearchConditionStr ')' )?
      ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' ( '.offset(' NumberOfRows ')' )? )?
      ( '.lockExclusive(' LockContention ')' | '.lockShared(' LockContention ')' )?
      ( '.bind(' PlaceholderValues ')' )*
      ( '.execute()' )?

Рисунок 11.9 CollectionFindFunction

Image shows the syntax in EBNF form as described in the preceding text.

CollectionModifyFunction

Синтаксис этой функции, представленный в EBNF:

CollectionModifyFunction
  ::= '.modify(' SearchConditionStr ')'
      ( '.set(' DocPath ',' ExprOrLiteral ')' |
        '.unset(' DocPath ( ',' DocPath )* ')' |
        '.arrayInsert(' DocPath ',' ExprOrLiteral ')' |
        '.arrayAppend(' DocPath ',' ExprOrLiteral ')' |
        '.patch(' DocumentOrJSON ')'
      )+
      ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' )?
      ( '.bind(' PlaceholderValues ')' )*
      ( '.execute()' )?

Рисунок 11.10 CollectionModifyFunction

CollectionAddFunction

Синтаксис этой функции, показанный в EBNF:

CollectionAddFunction
    ::= ( '.add(' ( DocumentOrJSON | '[' DocumentOrJSON ( ',' DocumentOrJSON )* ']' )? ')' )+
        ( '.execute()' )?

Рисунок 11.11 CollectionAddFunction

CollectionRemoveFunction

Синтаксис этой функции, показанный в EBNF:

CollectionRemoveFunction
    ::= '.remove(' SearchConditionStr ')'
        ( '.sort(' SortExprStrList ')' )? ( '.limit(' NumberOfRows ')' )?
        ( '.bind(' PlaceholderValues ')' )*
        ( '.execute()' )?

Рисунок 11.12 CollectionRemoveFunction