std/marshal

Этот модуль содержит процедуры для сериализации и десериализации произвольных структур данных Nim. Формат сериализации использует JSON.

Ограничение: Для объектов их тип не сериализуется. Это означает, что он не будет работать, если у объекта есть тип во время выполнения, отличный от типа во время компиляции.

Основные примеры использования

Пример:

import std/marshal
type
  A = object of RootObj
  B = object of A
    f: int

let a: ref A = new(B)
assert $$a[] == "{}" # not "{f: 0}"

# unmarshal
let c = to[B]("""{"f": 2}""")
assert typeof(c) is B
assert c.f == 2

# marshal
assert $$c == """{"f": 2}"""

См. также

• модуль streams
• модуль json

Импорты

streams, typeinfo, json, intsets, tables, unicode

Процедуры

proc `$$`[T](x: sink T): string

Возвращает строковое представление x (сериализация, маппинг).

Примечание: для сериализации x в JSON используйте %x из модуля json или jsonutils.toJson(x).

Пример:

type
  Foo = object
    id: int
    bar: string
let x = Foo(id: 1, bar: "baz")
## serialize:
let y = $$x
assert y == """{"id": 1, "bar": "baz"}"""

Источник Изменить

proc load[T](s: Stream; data: var T)

Загружает data из потока s. Вызывает IOError в случае ошибки.

Пример:

import std/streams

var s = newStringStream("[1, 3, 5]")
var a: array[3, int]
load(s, a)
assert a == [1, 3, 5]

Источник Изменить

proc store[T](s: Stream; data: sink T)

Сохраняет data в поток s. Вызывает IOError в случае ошибки.

Пример:

import std/streams

var s = newStringStream("")
var a = [1, 3, 5]
store(s, a)
s.setPosition(0)
assert s.readAll() == "[1, 3, 5]"

Источник Изменить

proc to[T](data: string): T

Читает данные и преобразует их в тип T (десериализация, размаппинг).

Пример:

type
  Foo = object
    id: int
    bar: string
let y = """{"id": 1, "bar": "baz"}"""
assert typeof(y) is string
## deserialize to type 'Foo':
let z = y.to[:Foo]
assert typeof(z) is Foo
assert z.id == 1
assert z.bar == "baz"

Источник Изменить