Три способа обертки — начало работы

Обертка функций Fortran или C в Python с помощью F2PY состоит из следующих шагов:

• Создание так называемого файла сигнатур, содержащего описания обёрток для функций Fortran или C, также называемых сигнатурами функций. В случае процедур Fortran, F2PY может создать начальный файл сигнатур, просканировав исходный код Fortran и вычленив всю необходимую информацию для создания обёртки функций.
• По желанию, созданные F2PY файлы сигнатур могут быть отредактированы для оптимизации обёртки функций, чтобы сделать их «умнее» и более «pythonic».
• F2PY считывает файл сигнатур и записывает модуль Python C/API, содержащий привязки Fortran/C/Python.
• F2PY компилирует все исходные коды и создаёт модуль расширения, содержащий обёртки. При создании модулей расширения F2PY использует numpy_distutils, который поддерживает ряд компиляторов Fortran 77/90/95, включая Gnu, Intel, Sun Fortre, SGI MIPSpro, Absoft, NAG, Compaq и т. д.

В зависимости от конкретной ситуации, эти шаги могут быть выполнены либо одной командой, либо пошагово, некоторые шаги могут быть пропущены или объединены с другими.

Ниже я опишу три типичных подхода использования F2PY. Следующий пример кода Fortran 77 будет использован для иллюстрации, сохраните его как fib1.f:

C FILE: FIB1.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB1.F

Быстрый способ

Самый быстрый способ обернуть подпрограмму Fortran FIB в Python — это запустить

python -m numpy.f2py -c fib1.f -m fib1

Эта команда создаёт (см. -c флаг, выполните python -m numpy.f2py без аргументов, чтобы увидеть объяснение опций командной строки) модуль расширения fib1.so (см. -m флаг) в текущий каталог. Теперь в Python подпрограмма Fortran FIB доступна через fib1.fib:

>>> import numpy
>>> import fib1
>>> print(fib1.fib.__doc__)
fib(a,[n])

Wrapper for ``fib``.

Parameters
----------
a : input rank-1 array('d') with bounds (n)

Other Parameters
----------------
n : input int, optional
    Default: len(a)

>>> a = numpy.zeros(8, 'd')
>>> fib1.fib(a)
>>> print(a)
[  0.   1.   1.   2.   3.   5.   8.  13.]

Умный способ

Давайте применим шаги обертывания функций Fortran в Python поочерёдно.

• Сначала мы создадим файл сигнатур из fib1.f запуском

  python -m numpy.f2py fib1.f -m fib2 -h fib1.pyf
  

  Файл сигнатур будет сохранён в fib1.pyf (см. -h флаг), а его содержимое показано ниже.

  !    -*- f90 -*-
  python module fib2 ! in 
      interface  ! in :fib2
          subroutine fib(a,n) ! in :fib2:fib1.f
              real*8 dimension(n) :: a
              integer optional,check(len(a)>=n),depend(a) :: n=len(a)
          end subroutine fib
      end interface 
  end python module fib2
  
  ! This file was auto-generated with f2py (version:2.28.198-1366).
  ! See http://cens.ioc.ee/projects/f2py2e/
  

• Далее, мы «научим» F2PY, что аргумент n является входным аргументом (используйте атрибут intent(in)) и что результат, т. е. содержимое a после вызова функции Fortran FIB, должен быть возвращён в Python (используйте атрибут intent(out)). Кроме того, массив a должен быть создан динамически с использованием размера, заданного входным аргументом n (используйте атрибут depend(n) для указания зависимости).

  Содержимое изменённой версии fib1.pyf (сохранённой как fib2.pyf) таково:

  !    -*- f90 -*-
  python module fib2 
      interface
          subroutine fib(a,n)
              real*8 dimension(n),intent(out),depend(n) :: a
              integer intent(in) :: n
          end subroutine fib
      end interface 
  end python module fib2
  

• И, наконец, мы создаём модуль расширения выполнением

  python -m numpy.f2py -c fib2.pyf fib1.f
  

В Python:

>>> import fib2
>>> print(fib2.fib.__doc__)
a = fib(n)

Wrapper for ``fib``.

Parameters
----------
n : input int

Returns
-------
a : rank-1 array('d') with bounds (n)

>>> print(fib2.fib(8))
[  0.   1.   1.   2.   3.   5.   8.  13.]

Быстрый и умный способ

«Умный способ» обертывания функций Fortran, описанный выше, подходит для обертывания (например, сторонних) кодов Fortran, для которых изменения в исходном коде нежелательны или даже невозможны.

Однако, если редактирование кода Fortran приемлемо, то в большинстве случаев можно пропустить генерацию промежуточного файла сигнатур. А именно, специфичные для F2PY атрибуты можно вставить непосредственно в исходный код Fortran с помощью так называемой директивы F2PY. Директива F2PY определяет специальные строки комментариев (например, начинающиеся с Cf2py), которые игнорируются компиляторами Fortran, но F2PY интерпретирует их как обычные строки.

Вот изменённая версия предыдущего кода Fortran, сохраните её как fib3.f:

C FILE: FIB3.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
Cf2py intent(in) n
Cf2py intent(out) a
Cf2py depend(n) a
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB3.F

Модуль расширения можно теперь создать одной командой:

python -m numpy.f2py -c -m fib3 fib3.f

Обратите внимание, что получившаяся обёртка для FIB так же «умна», как и в предыдущем случае:

>>> import fib3
>>> print(fib3.fib.__doc__)
a = fib(n)

Wrapper for ``fib``.

Parameters
----------
n : input int

Returns
-------
a : rank-1 array('d') with bounds (n)

>>> print(fib3.fib(8))
[  0.   1.   1.   2.   3.   5.   8.  13.]