Три способа обертки — начало работы

Быстрый способ

Самый быстрый способ обернуть подпрограмму Fortran FIB для использования в Python — это выполнить

python -m numpy.f2py -c fib1.f -m fib1

или, в качестве альтернативы, если доступен инструмент командной строки f2py,

f2py -c fib1.f -m fib1

Эта команда компилирует и оборачивает fib1.f (-c) для создания модуля расширения fib1.so (-m) в текущем каталоге. Список параметров командной строки можно увидеть, выполнив python -m numpy.f2py. Теперь в Python подпрограмма Fortran FIB доступна через fib1.fib:

>>> import numpy as np
>>> import fib1
>>> print(fib1.fib.__doc__)
fib(a,[n])

Wrapper for ``fib``.

Parameters
----------
a : input rank-1 array('d') with bounds (n)

Other parameters
----------------
n : input int, optional
    Default: len(a)

>>> a = np.zeros(8, 'd')
>>> fib1.fib(a)
>>> print(a)
[  0.   1.   1.   2.   3.   5.   8.  13.]

Умный способ

Если мы хотим иметь больший контроль над тем, как F2PY будет обрабатывать интерфейс с нашим кодом Fortran, мы можем применить шаги обертывания по одному.

• Сначала мы создадим файл сигнатур из fib1.f, выполнив:

  python -m numpy.f2py fib1.f -m fib2 -h fib1.pyf
  

  Файл сигнатур сохраняется в fib1.pyf (см. флаг -h) и его содержимое показано ниже.

  !    -*- f90 -*-
  python module fib2 ! in 
      interface  ! in :fib2
          subroutine fib(a,n) ! in :fib2:fib1.f
              real*8 dimension(n) :: a
              integer optional,check(len(a)>=n),depend(a) :: n=len(a)
          end subroutine fib
      end interface 
  end python module fib2
  
  ! This file was auto-generated with f2py (version:2.28.198-1366).
  ! See http://cens.ioc.ee/projects/f2py2e/
  

• Далее мы сообщим F2PY, что аргумент n является входным аргументом (используя атрибут intent(in)) и что результат, т. е. содержимое a после вызова функции Fortran FIB, должен возвращаться в Python (используя атрибут intent(out)). Кроме того, массив a должен быть создан динамически с размером, определяемым входным аргументом n (используя атрибут depend(n) для указания этой зависимости).

  Содержимое соответствующим образом изменённой версии fib1.pyf (сохранённой как fib2.pyf) таково:

  !    -*- f90 -*-
  python module fib2 
      interface
          subroutine fib(a,n)
              real*8 dimension(n),intent(out),depend(n) :: a
              integer intent(in) :: n
          end subroutine fib
      end interface 
  end python module fib2
  

• Наконец, мы создаём модуль расширения с numpy.distutils, выполнив:

  python -m numpy.f2py -c fib2.pyf fib1.f
  

В Python:

>>> import fib2
>>> print(fib2.fib.__doc__)
a = fib(n)

Wrapper for ``fib``.

Parameters
----------
n : input int

Returns
-------
a : rank-1 array('d') with bounds (n)

>>> print(fib2.fib(8))
[  0.   1.   1.   2.   3.   5.   8.  13.]

Быстрый и умный способ

«Умный» способ обертывания функций Fortran, описанный выше, подходит для обертывания (например, сторонних) кодов Fortran, для которых изменения исходных кодов нежелательны или даже невозможны.

Однако, если редактирование кода Fortran приемлемо, то в большинстве случаев можно пропустить генерацию промежуточного файла сигнатур. Специфические атрибуты F2PY можно вставить непосредственно в исходные коды Fortran с помощью директив F2PY. Директива F2PY состоит из специальных строк комментариев (начинающихся с Cf2py или !f2py, например), которые игнорируются компиляторами Fortran, но интерпретируются F2PY как обычные строки.

Рассмотрим изменённую версию предыдущего кода Fortran с директивами F2PY, сохранённую как fib3.f:

C FILE: FIB3.F
      SUBROUTINE FIB(A,N)
C
C     CALCULATE FIRST N FIBONACCI NUMBERS
C
      INTEGER N
      REAL*8 A(N)
Cf2py intent(in) n
Cf2py intent(out) a
Cf2py depend(n) a
      DO I=1,N
         IF (I.EQ.1) THEN
            A(I) = 0.0D0
         ELSEIF (I.EQ.2) THEN
            A(I) = 1.0D0
         ELSE 
            A(I) = A(I-1) + A(I-2)
         ENDIF
      ENDDO
      END
C END FILE FIB3.F

Модуль расширения можно теперь создать одной командой:

python -m numpy.f2py -c -m fib3 fib3.f

Обратите внимание, что полученная обертка для FIB так же «умна» (однозначна), как и в предыдущем случае:

>>> import fib3
>>> print(fib3.fib.__doc__)
a = fib(n)

Wrapper for ``fib``.

Parameters
----------
n : input int

Returns
-------
a : rank-1 array('d') with bounds (n)

>>> print(fib3.fib(8))
[  0.   1.   1.   2.   3.   5.   8.  13.]