Глава 12. Расширения языка

22 Обобщённые операторы open

(Добавлено в версии 4.08)

Это расширение позволяет открывать любые выражения модулей в структурах и выражениях модулей. Подобный механизм доступен и внутри типов модулей, но только для расширенных путей к модулям (например, F(X).G(Y)).

Например, модуль можно ограничить при открытии следующим образом:

module M = struct let x = 0 let hidden = 1 end
open (M:sig val x: int end)
let y = hidden

Error: Unbound value hidden

Другая возможность — сразу открыть результат применения функтора:

  let sort (type x) (x:x list) =
    let open Set.Make(struct type t = x let compare=compare end) in
    elements (of_list x)

val sort : 'x list -> 'x list = 

Кроме того, эта конструкция позволяет вводить локальные компоненты внутри структуры:

module M = struct
  let x = 0
  open! struct
    let x = 0
    let y = 1
  end
  let w = x + y
end

module M : sig val x : int val w : int end

Важно помнить, что типы, введённые с помощью open struct ... end, не могут появляться в сигнатуре охватывающей структуры, если только они не определены как равные некоторому нелокальному типу. Поэтому:

module M = struct
  open struct type 'a t = 'a option = None | Some of 'a end
  let x : int t = Some 1
end

module M : sig val x : int option end

допустимо, но:

module M = struct
  open struct type t = A end
  let x = A
end

Error: The type t introduced by this open appears in the signature.
  The value x has no valid type if t is hidden.

недопустимо, поскольку для x нельзя задать тип, отличный от t, который существует только локально. Однако приведённый выше пример был бы допустим, если бы x тоже был локальным:

module M: sig end = struct
  open struct
  type t = A
  end
  …
  open struct let x = A end
  …
end

module M : sig end

В сигнатурах расширенные конструкции open ограничены расширенными путями к модулям:

module type S = sig
  module F: sig end -> sig type t end
  module X: sig end
  open F(X)
  val f: t
end

module type S =
  sig
    module F : sig end -> sig type t end
    module X : sig end
    val f : F(X).t
  end

но не

  open struct type t = int end

В таких случаях вместо этого можно использовать локальные подстановки (см. 12.7.2).

Обратите внимание, что это расширение недоступно внутри определений классов:

class c =
  let open Set.Make(Int) in
  ...