10.17 Встроенные записи

(Введено в OCaml 4.03)

Аргументы конструкторов типов-сумм теперь можно определять, используя ту же синтаксическую конструкцию, что и для записей. Разрешается использование изменяемых и полиморфных полей. Поддерживается синтаксис GADT. Атрибуты могут быть заданы для отдельных полей.

Синтаксически, построение или сопоставление конструкторов с таким аргументом-встроенной записью аналогично работе с унарным конструктором, единственным аргументом которого является объявленный тип записи. Шаблон может связывать встроенную запись как псевдопеременную, но запись не может выйти за пределы области действия привязки и может быть использована только с обозначением точки для извлечения или модификации полей или для построения новых значений конструкторов.

type t =
  | Point of {width: int; mutable x: float; mutable y: float}
  | Other

let v = Point {width = 10; x = 0.; y = 0.}

let scale l = function
  | Point p -> Point {p with x = l *. p.x; y = l *. p.y}
  | Other -> Other

let print = function
  | Point {x; y; _} -> Printf.printf "%f/%f" x y
  | Other -> ()

let reset = function
  | Point p -> p.x <- 0.; p.y <- 0.
  | Other -> ()

let invalid = function
  | Point p -> p

Error: This form is not allowed as the type of the inlined record could escape.