12.22 Обобщенные открытые объявления

(Введено в 4.08)

Это расширение позволяет открывать любые выражения модулей в структурах и выражениях модулей. Аналогичный механизм также доступен внутри типов модулей, но только для расширенных путей модулей (например, F(X).G(Y)).

Например, модуль может быть ограничен при открытии:

module M = struct let x = 0 let hidden = 1 end
open (M:sig val x: int end)
let y = hidden

Error: Unbound value hidden

Другая возможность — немедленно открыть результат применения функтора:

  let sort (type x) (x:x list) =
    let open Set.Make(struct type t = x let compare=compare end) in
    elements (of_list x)

val sort : 'x list -> 'x list = 

Далее, эта конструкция может вводить локальные компоненты внутри структуры:

module M = struct
  let x = 0
  open! struct
    let x = 0
    let y = 1
  end
  let w = x + y
end

module M : sig val x : int val w : int end

Важное ограничение состоит в том, что типы, введённые с помощью open struct ... end, не могут появляться в сигнатуре окружающей структуры, если они не определены равными некоторым нелокальным типам. Так:

module M = struct
  open struct type 'a t = 'a option = None | Some of 'a end
  let x : int t = Some 1
end

module M : sig val x : int option end

это правильно, но:

module M = struct
  open struct type t = A end
  let x = A
end

Error: The type t/568 introduced by this open appears in the signature
       File "extensions/generalizedopens.etex", line 3, characters 6-7:
         The value x has no valid type if t/568 is hidden

неправильно, потому что x не может быть задан никаким типом, кроме t, который существует только локально. Хотя вышеуказанное было бы правильно, если бы x также было локальным:

module M: sig end = struct
  open struct
  type t = A
  end
  …
  open struct let x = A end
  …
end

module M : sig end

Внутри сигнатур расширенные открытие ограничены расширенными путями модулей:

module type S = sig
  module F: sig end -> sig type t end
  module X: sig end
  open F(X)
  val f: t
end

module type S =
  sig
    module F : sig end -> sig type t end
    module X : sig end
    val f : F(X).t
  end

и не

  open struct type t = int end

В таких ситуациях вместо этого можно использовать локальные подстановки (см. 12.7.2).

Обратите внимание, что это расширение недоступно внутри определений классов:

class c =
  let open Set.Make(Int) in
  ...