Импорт

Используйте блок import, чтобы импортировать существующие ресурсы инфраструктуры в OpenTofu и передать их под управление OpenTofu. В отличие от команды tofu import, управляемый конфигурацией импорт с помощью блоков import предсказуем, работает с конвейерами CI/CD и позволяет предварительно просмотреть операцию импорта до изменения состояния.

После импорта OpenTofu отслеживает ресурс в файле состояния. Затем вы можете управлять импортированным ресурсом так же, как любым другим: обновлять его атрибуты и удалять в рамках стандартного жизненного цикла ресурса.

Блок import указывает, что OpenTofu импортировал ресурс, а не создал его. После импорта вы можете удалить блоки импорта из конфигурации или оставить их в качестве записи об источнике ресурса.

Синтаксис​

Блок import можно добавить в любой файл конфигурации OpenTofu. Обычно для этого создают файл imports.tf или размещают каждый блок import рядом с блоком resource, в который он импортирует ресурс.

import {
  to = aws_instance.example
  id = "i-abcd1234"
}

resource "aws_instance" "example" {
  name = "hashi"
  # (other resource arguments...)
}

Приведенный выше блок import задает импорт экземпляра AWS с идентификатором "i-abcd1234" в ресурс aws_instance.example корневого модуля.

Блок import содержит следующие аргументы:

• to — адрес экземпляра, который этот ресурс будет иметь в файле состояния.
• id — строка с идентификатором импорта ресурса.
• provider (необязательно) — пользовательский поставщик ресурсов. Подробности см. в разделе «Метааргумент поставщика ресурсов».
• for_each (необязательно) — импорт нескольких ресурсов путем перебора карты или набора. См. раздел «Импорт нескольких ресурсов» ниже.

Если аргумент provider не задан, OpenTofu пытается выполнить импорт с помощью поставщика по умолчанию.

Идентификатор импорта​

В блоке импорта необходимо указать аргумент id, содержащий строковый литерал с идентификатором импорта ресурса. OpenTofu использует этот идентификатор, чтобы найти ресурс, который вы хотите импортировать.

Идентификатор импорта зависит от типа ресурса. Необходимый идентификатор можно найти в документации поставщика для ресурса, который вы хотите импортировать.

Планирование и применение импорта​

OpenTofu обрабатывает блок import на этапе планирования. После утверждения плана OpenTofu импортирует ресурс в состояние на последующем этапе применения.

Чтобы импортировать ресурс с помощью блоков import, необходимо:

1. Определить блок import для ресурса или ресурсов.
2. Добавить в конфигурацию соответствующий блок resource или создать конфигурацию для этого ресурса.
3. Выполнить tofu plan, чтобы проверить, как OpenTofu импортирует ресурс или ресурсы.
4. Применить конфигурацию, чтобы импортировать ресурсы и обновить состояние OpenTofu.

Блок import является идемпотентным: применение действия импорта и запуск следующего плана не приведут к созданию нового действия импорта, если ресурс остается в состоянии.

OpenTofu необходимо импортировать каждый ресурс только один раз. Повторная попытка импортировать ресурс по тому же адресу безопасна и ничего не меняет. После завершения импорта блоки import можно удалить или оставить в конфигурации в качестве записи об источнике ресурса для будущих сопровождающих модуля. Дополнительную информацию о сопровождении конфигураций см. в разделе «Рефакторинг».

Конфигурация ресурса​

Перед импортом необходимо добавить конфигурацию для каждого ресурса, который OpenTofu должен импортировать. В противном случае OpenTofu выдаст ошибку при планировании и потребует добавить конфигурацию ресурса, прежде чем импорт сможет завершиться успешно. Конфигурацию ресурса можно создать вручную или сгенерировать с помощью OpenTofu.

Если вы знаете большинство аргументов ресурса, рекомендуем написать блок resource. Например, в конфигурации может уже быть похожий ресурс, настройки которого можно скопировать и изменить.

Если вы импортируете несколько ресурсов или один сложный ресурс, конфигурации которого у вас еще нет, рекомендуем сгенерировать конфигурацию.

Добавление блока resource​

Добавьте блок resource для импортируемого ресурса. Адрес ресурса должен совпадать с аргументом to блока импорта.

import {
  to = aws_instance.example
  id = "i-abcd1234"
}

resource "aws_instance" "example" {
  name = "renderer"
}

Создание конфигурации​

OpenTofu может генерировать код HCL для ресурсов, которых еще нет в конфигурации. Подробнее см. в разделе «Создание конфигурации».

Примеры​

В следующем примере показано, как импортировать ресурс в модуль.

import {
  to = module.instances.aws_instance.example
  id = "i-abcd1234"
}

В примере ниже показано, как импортировать ресурс с count.

import {
  to = aws_instance.example[0]
  id = "i-abcd1234"
}

В примере ниже показано, как импортировать ресурс с for_each.

import {
  to = aws_instance.example["foo"]
  id = "i-abcd1234"
}

Наконец, в примере ниже показано, как импортировать ресурс с помощью пользовательского поставщика ресурсов.

provider "aws" {
  alias = "europe"
  region = "eu-west-1"
}

import {
  provider = aws.europe
  to = aws_instance.example["foo"]
  id = "i-abcd1234"
}

Импорт нескольких ресурсов​

С помощью выражения for_each можно импортировать несколько ресурсов одним блоком импорта. Это выражение принимает набор, кортеж или карту и предоставляет переменные each.key и each.value для доступа к отдельным элементам.

В примере ниже можно указать список идентификаторов серверов для импорта. Если указать пустой список, ресурс random_id сгенерирует все идентификаторы случайным образом. Если указать некоторые идентификаторы, блок импорта импортирует их, а ресурс случайным образом сгенерирует остальные. Обратите внимание: ресурс random_id требует, чтобы идентификаторы были в формате base64.

variable "server_ids" {
  type = list(string)
}

resource "random_id" "test_id" {
  byte_length = 8
  count = 2
}

import {
  to = random_id.test_id[tonumber(each.key)]
  id = each.value
  for_each = {
    for idx, item in var.server_ids: idx => item
  }
}

output "id" {
  value = random_id.test_id.*.b64_url
}