Spec-Zone.ru › Perl 5.28

perlreref

СОДЕРЖАНИЕ

  • ИМЯ
  • ОПИСАНИЕ
    • ОПЕРАТОРЫ
    • СИНТАКСИС
    • ПОСЛЕДОВАТЕЛЬНОСТИ ЭСКАПИРОВАНИЯ
    • КОМБИНАЦИИ СИМВОЛОВ
    • ЯКОРЯ
    • КВАНТИФИКАТОРЫ
    • РАЗШИРЕННЫЕ КОНСТРУКЦИИ
    • ПЕРЕМЕННЫЕ
    • ФУНКЦИИ
    • ТЕРМИНОЛОГИЯ
      • Заглавные буквы
      • Сворачивание регистра
  • АВТОР
  • СМОТРИТЕ ТАКЖЕ
  • БЛАГОДАРНОСТИ

ИМЯ

perlreref - Справочник по регулярным выражениям Perl

ОПИСАНИЕ

Это краткое руководство по регулярным выражениям Perl. Для получения полной информации см. perlre и perlop, а также раздел "СМОТРИТЕ ТАКЖЕ" в данном документе.

ОПЕРАТОРЫ

=~ определяет, к какой переменной применяется регулярное выражение. При его отсутствии используется $_.

$var =~ /foo/;

!~ определяет, к какой переменной применяется регулярное выражение, и инвертирует результат совпадения; возвращает false, если совпадение успешно, и true, если оно не удалось.

$var !~ /foo/;

m/pattern/msixpogcdualn ищет в строке соответствие шаблону, применяя заданные опции.

m  Multiline mode - ^ and $ match internal lines
s  match as a Single line - . matches \n
i  case-Insensitive
x  eXtended legibility - free whitespace and comments
p  Preserve a copy of the matched string -
   ${^PREMATCH}, ${^MATCH}, ${^POSTMATCH} will be defined.
o  compile pattern Once
g  Global - all occurrences
c  don't reset pos on failed matches when using /g
a  restrict \d, \s, \w and [:posix:] to match ASCII only
aa (two a's) also /i matches exclude ASCII/non-ASCII
l  match according to current locale
u  match according to Unicode rules
d  match according to native rules unless something indicates
   Unicode
n  Non-capture mode. Don't let () fill in $1, $2, etc...

Если 'pattern' является пустой строкой, используется последнее успешно сопоставленное регулярное выражение. Разделители, отличные от '/', могут быть использованы как для данного оператора, так и для следующих. Ведущий m можно опустить, если разделитель — '/'.

qr/pattern/msixpodualn позволяет хранить регулярное выражение в переменной или передавать его. Модификаторы, как и для m//, и хранятся внутри регулярного выражения.

s/pattern/replacement/msixpogcedual заменяет совпадения 'pattern' на 'replacement'. Модификаторы, как и для m//, с двумя дополнениями:

e  Evaluate 'replacement' as an expression
r  Return substitution and leave the original string untouched.

'e' может быть указан несколько раз. 'replacement' интерпретируется как строка в двойных кавычках, если разделитель — одинарная кавычка (').

m?pattern? подобно m/pattern/, но соответствует только один раз. Иные разделители использовать нельзя. Требуется сброс с помощью reset().

СИНТАКСИС

\       Escapes the character immediately following it
.       Matches any single character except a newline (unless /s is
          used)
^       Matches at the beginning of the string (or line, if /m is used)
$       Matches at the end of the string (or line, if /m is used)
*       Matches the preceding element 0 or more times
+       Matches the preceding element 1 or more times
?       Matches the preceding element 0 or 1 times
{...}   Specifies a range of occurrences for the element preceding it
[...]   Matches any one of the characters contained within the brackets
(...)   Groups subexpressions for capturing to $1, $2...
(?:...) Groups subexpressions without capturing (cluster)
|       Matches either the subexpression preceding or following it
\g1 or \g{1}, \g2 ...    Matches the text from the Nth group
\1, \2, \3 ...           Matches the text from the Nth group
\g-1 or \g{-1}, \g-2 ... Matches the text from the Nth previous group
\g{name}     Named backreference
\k<name>     Named backreference
\k'name'     Named backreference
(?P=name)    Named backreference (python syntax)

ПОСЛЕДОВАТЕЛЬНОСТИ ЭСКАПИРОВАНИЯ

Они работают так же, как и в обычных строках.

\a       Alarm (beep)
\e       Escape
\f       Formfeed
\n       Newline
\r       Carriage return
\t       Tab
\037     Char whose ordinal is the 3 octal digits, max \777
\o{2307} Char whose ordinal is the octal number, unrestricted
\x7f     Char whose ordinal is the 2 hex digits, max \xFF
\x{263a} Char whose ordinal is the hex number, unrestricted
\cx      Control-x
\N{name} A named Unicode character or character sequence
\N{U+263D} A Unicode character by hex ordinal

\l  Lowercase next character
\u  Titlecase next character
\L  Lowercase until \E
\U  Uppercase until \E
\F  Foldcase until \E
\Q  Disable pattern metacharacters until \E
\E  End modification

Для Заглавных букв, см. "Заглавные буквы".

Этот работает иначе, чем обычные строки:

\b  An assertion, not backspace, except in a character class

КОМБИНАЦИИ СИМВОЛОВ

[amy]    Match 'a', 'm' or 'y'
[f-j]    Dash specifies "range"
[f-j-]   Dash escaped or at start or end means 'dash'
[^f-j]   Caret indicates "match any character _except_ these"

Следующие последовательности (кроме \N ) работают внутри или вне комбинации символов. Первые шесть учитывают локаль, все учитывают Unicode. Подробности см. в perllocale и perlunicode.

\d      A digit
\D      A nondigit
\w      A word character
\W      A non-word character
\s      A whitespace character
\S      A non-whitespace character
\h      A horizontal whitespace
\H      A non horizontal whitespace
\N      A non newline (when not followed by '{NAME}';;
        not valid in a character class; equivalent to [^\n]; it's
        like '.' without /s modifier)
\v      A vertical whitespace
\V      A non vertical whitespace
\R      A generic newline           (?>\v|\x0D\x0A)

\pP     Match P-named (Unicode) property
\p{...} Match Unicode property with name longer than 1 character
\PP     Match non-P
\P{...} Match lack of Unicode property with name longer than 1 char
\X      Match Unicode extended grapheme cluster

Классы символов POSIX и их эквиваленты Unicode и Perl:

           ASCII-         Full-
  POSIX    range          range    backslash
[[:...:]]  \p{...}        \p{...}   sequence    Description

-----------------------------------------------------------------------
alnum   PosixAlnum       XPosixAlnum            'alpha' plus 'digit'
alpha   PosixAlpha       XPosixAlpha            Alphabetic characters
ascii   ASCII                                   Any ASCII character
blank   PosixBlank       XPosixBlank   \h       Horizontal whitespace;
                                                  full-range also
                                                  written as
                                                  \p{HorizSpace} (GNU
                                                  extension)
cntrl   PosixCntrl       XPosixCntrl            Control characters
digit   PosixDigit       XPosixDigit   \d       Decimal digits
graph   PosixGraph       XPosixGraph            'alnum' plus 'punct'
lower   PosixLower       XPosixLower            Lowercase characters
print   PosixPrint       XPosixPrint            'graph' plus 'space',
                                                  but not any Controls
punct   PosixPunct       XPosixPunct            Punctuation and Symbols
                                                  in ASCII-range; just
                                                  punct outside it
space   PosixSpace       XPosixSpace   \s       Whitespace
upper   PosixUpper       XPosixUpper            Uppercase characters
word    PosixWord        XPosixWord    \w       'alnum' + Unicode marks
                                                   + connectors, like
                                                   '_' (Perl extension)
xdigit  ASCII_Hex_Digit  XPosixDigit            Hexadecimal digit,
                                                   ASCII-range is
                                                   [0-9A-Fa-f]

Также существуют различные синонимы, например, \p{Alpha} для \p{XPosixAlpha}; все они перечислены в "Свойства, доступные через \p{} и \P{}" в perluniprops

Внутри комбинации символов:

  POSIX      traditional   Unicode
[:digit:]       \d        \p{Digit}
[:^digit:]      \D        \P{Digit}

ЯКОРЯ

Все — утверждения нулевой ширины.

^  Match string start (or line, if /m is used)
$  Match string end (or line, if /m is used) or before newline
\b{} Match boundary of type specified within the braces
\B{} Match wherever \b{} doesn't match
\b Match word boundary (between \w and \W)
\B Match except at word boundary (between \w and \w or \W and \W)
\A Match string start (regardless of /m)
\Z Match string end (before optional newline)
\z Match absolute string end
\G Match where previous m//g left off
\K Keep the stuff left of the \K, don't include it in $&

КВАНТИФИКАТОРЫ

Квантификаторы по умолчанию жадные и соответствуют самой длинной левой части.

Maximal Minimal Possessive Allowed range
------- ------- ---------- -------------
{n,m}   {n,m}?  {n,m}+     Must occur at least n times
                           but no more than m times
{n,}    {n,}?   {n,}+      Must occur at least n times
{n}     {n}?    {n}+       Must occur exactly n times
*       *?      *+         0 or more times (same as {0,})
+       +?      ++         1 or more times (same as {1,})
?       ??      ?+         0 or 1 time (same as {0,1})

Позиционные формы (новые в Perl 5.10) предотвращают обратную отмотку: то, что соответствует шаблону с позиционным квантификатором, не будет отмотано назад, даже если это приводит к отказу всего совпадения.

Квантификатора {,n} нет. Это интерпретируется как строка.

РАЗШИРЕННЫЕ КОНСТРУКЦИИ

(?#text)          A comment
(?:...)           Groups subexpressions without capturing (cluster)
(?pimsx-imsx:...) Enable/disable option (as per m// modifiers)
(?=...)           Zero-width positive lookahead assertion
(?*pla:...)       Same; avail experimentally starting in 5.28
(?!...)           Zero-width negative lookahead assertion
(?*nla:...)       Same; avail experimentally starting in 5.28
(?<=...)          Zero-width positive lookbehind assertion
(?*plb:...)       Same; avail experimentally starting in 5.28
(?<!...)          Zero-width negative lookbehind assertion
(?*nlb:...)       Same; avail experimentally starting in 5.28
(?>...)           Grab what we can, prohibit backtracking
(?*atomic:...)    Same; avail experimentally starting in 5.28
(?|...)           Branch reset
(?<name>...)      Named capture
(?'name'...)      Named capture
(?P<name>...)     Named capture (python syntax)
(?[...])          Extended bracketed character class
(?{ code })       Embedded code, return value becomes $^R
(??{ code })      Dynamic regex, return value used as regex
(?N)              Recurse into subpattern number N
(?-N), (?+N)      Recurse into Nth previous/next subpattern
(?R), (?0)        Recurse at the beginning of the whole pattern
(?&name)          Recurse into a named subpattern
(?P>name)         Recurse into a named subpattern (python syntax)
(?(cond)yes|no)
(?(cond)yes)      Conditional expression, where "cond" can be:
                  (?=pat)   lookahead
                  (?!pat)   negative lookahead
                  (?<=pat)  lookbehind
                  (?<!pat)  negative lookbehind
                  (N)       subpattern N has matched something
                  (<name>)  named subpattern has matched something
                  ('name')  named subpattern has matched something
                  (?{code}) code condition
                  (R)       true if recursing
                  (RN)      true if recursing into Nth subpattern
                  (R&name)  true if recursing into named subpattern
                  (DEFINE)  always false, no no-pattern allowed

ПЕРЕМЕННЫЕ

$_    Default variable for operators to use

$`    Everything prior to matched string
$&    Entire matched string
$'    Everything after to matched string

${^PREMATCH}   Everything prior to matched string
${^MATCH}      Entire matched string
${^POSTMATCH}  Everything after to matched string

Примечание для тех, кто всё ещё использует Perl 5.18 или более раннюю версию: Использование $`, $& или $' замедлит все операции с регулярными выражениями в вашей программе. Обратитесь к perlvar для @- , чтобы увидеть эквивалентные выражения, которые не приведут к замедлению. См. также Devel::SawAmpersand. Начиная с Perl 5.10, вы также можете использовать эквивалентные переменные ${^PREMATCH}, ${^MATCH} и ${^POSTMATCH}, но для их определения необходимо указать модификатор /p (preserve) для вашего регулярного выражения. В Perl 5.20 использование $`, $& и $' не влияет на скорость.

$1, $2 ...  hold the Xth captured expr
$+    Last parenthesized pattern match
$^N   Holds the most recently closed capture
$^R   Holds the result of the last (?{...}) expr
@-    Offsets of starts of groups. $-[0] holds start of whole match
@+    Offsets of ends of groups. $+[0] holds end of whole match
%+    Named capture groups
%-    Named capture groups, as array refs

Захваченные группы нумеруются по их открывающей скобке.

ФУНКЦИИ

lc          Lowercase a string
lcfirst     Lowercase first char of a string
uc          Uppercase a string
ucfirst     Titlecase first char of a string
fc          Foldcase a string

pos         Return or set current match position
quotemeta   Quote metacharacters
reset       Reset m?pattern? status
study       Analyze string for optimizing matching

split       Use a regex to split a string into parts

Первые пять из них похожи на последовательности эскапирования \L, \l, \U, \u и \F. Для Заглавных букв см. "Заглавные буквы"; для Сворачивания регистра см. "Сворачивание регистра".

ТЕРМИНОЛОГИЯ

Заглавные буквы

Концепция Unicode, которая чаще всего равна верхнему регистру, но для некоторых символов, таких как немецкая "острая s", есть разница.

Сворачивание регистра

Форма Unicode, которая полезна при сравнении строк независимо от регистра, поскольку некоторые символы имеют сложные отображения регистра. В основном является вариантом строчных букв.

АВТОР

Iain Truskett. Обновлено Perl 5 Porters.

Этот документ можно распространять на тех же условиях, что и сам Perl.

СМОТРИТЕ ТАКЖЕ

  • perlretut для получения руководства по регулярным выражениям.

  • perlrequick для быстрого руководства.

  • perlre для более подробной информации.

  • perlvar для получения подробной информации о переменных.

  • perlop для получения подробной информации об операторах.

  • perlfunc для получения подробной информации о функциях.

  • perlfaq6 для часто задаваемых вопросов по регулярным выражениям.

  • perlrebackslash для справки по последовательностям обратной косой черты.

  • perlrecharclass для справки по комбинациям символов.

  • Модуль re для изменения поведения и отладки.

  • "Отладка регулярных выражений" в perldebug

  • perluniintro, perlunicode, charnames и perllocale для получения подробной информации о регулярных выражениях и интернационализации.

  • Mastering Regular Expressions Джеффри Фридл (http://oreilly.com/catalog/9780596528126/) для углубленного изучения и справки по данной теме.

БЛАГОДАРНОСТИ

David P.C. Wollmann, Richard Soderberg, Sean M. Burke, Tom Christiansen, Jim Cromie и Jeffrey Goff за полезные советы.

© 1993–2020 Larry Wall and others
Licensed under the GNU General Public License version 1 or later, or the Artistic License.
The Perl logo is a trademark of the Perl Foundation.
https://perldoc.perl.org/5.28.3/perlreref

Spec-Zone.ru

Настройки Оффлайн Что нового Помощь О нас
Spec-Zone .ru
спецификации, руководства, описания, API