CORE

СОДЕРЖАНИЕ

• НАЗВАНИЕ
• СИНОПСИС
• ОПИСАНИЕ
• ПЕРЕОПРЕДЕЛЕНИЕ ФУНКЦИЙ ЯДРА
• АВТОР
• СМОТРИТЕ ТАКЖЕ

НАЗВАНИЕ

CORE — Имя пространства имён для встроенных процедур Perl

СИНОПСИС

BEGIN {
    *CORE::GLOBAL::hex = sub { 1; };
}

print hex("0x50"),"\n";                     # prints 1
print CORE::hex("0x50"),"\n";               # prints 80
CORE::say "yes";                            # prints yes

BEGIN { *shove = \&CORE::push; }
shove @array, 1,2,3;                        # pushes on to @array

ОПИСАНИЕ

Пространство имён CORE предоставляет доступ к исходным встроенным функциям Perl. Пакет CORE встроен в Perl, и поэтому вам не нужно использовать или подключать гипотетический модуль «CORE» перед доступом к процедурам в этом пространстве имён.

Список встроенных функций Perl можно найти в perlfunc.

Для всех ключевых слов Perl префикс CORE:: заставит использовать встроенную функцию, даже если она была переопределена или обычно требует прагмы feature. Несмотря на внешнее впечатление, это никак не связано с пакетом CORE, а является частью синтаксиса Perl.

Для многих функций Perl пакет CORE содержит реальные подпрограммы. Эта функция нова в Perl 5.16. Вы можете создавать ссылки на них и создавать псевдонимы. Однако некоторые можно вызывать только как слова без префиксов; то есть вы не можете использовать синтаксис с амперсандом (&foo) или вызывать их через ссылки. Смотрите пример shove выше. Эти подпрограммы существуют для всех ключевых слов, кроме следующих:

__DATA__, __END__, and, cmp, default, do, dump, else, elsif, eq, eval, for, foreach, format, ge, given, goto, grep, gt, if, last, le, local, lt, m, map, my, ne, next, no, or, our, package, print, printf, q, qq, qr, qw, qx, redo, require, return, s, say, sort, state, sub, tr, unless, until, use, when, while, x, xor, y

Вызов с синтаксисом амперсанда и через ссылки не работает для следующих функций, поскольку у них есть специальный синтаксис, который не всегда можно преобразовать в простой список (например, eof по сравнению с eof()):

chdir, chomp, chop, defined, delete, eof, exec, exists, lstat, split, stat, system, truncate, unlink

ПЕРЕОПРЕДЕЛЕНИЕ ФУНКЦИЙ ЯДРА

Чтобы переопределить встроенную процедуру Perl собственной версией, необходимо импортировать её во время компиляции. Это удобно сделать с помощью прагмы subs. Это повлияет только на пакет, в который вы импортировали указанную подпрограмму:

use subs 'chdir';
sub chdir { ... }
chdir $somewhere;

Чтобы переопределить встроенную функцию глобально (то есть во всех пространствах имён), необходимо импортировать свою функцию в псевдопространство имён CORE::GLOBAL во время компиляции:

BEGIN {
    *CORE::GLOBAL::hex = sub {
        # ... your code here
    };
}

Новая процедура будет вызываться всякий раз, когда вызывается встроенная функция без квалифицирующего пакета:

print hex("0x50"),"\n";                     # prints 1

В обоих случаях, если вы хотите получить доступ к исходной, не изменённой процедуре, используйте префикс CORE:::

print CORE::hex("0x50"),"\n";               # prints 80

АВТОР

Данная документация предоставлена Tels <nospam-abuse@bloodgate.com> 2007 г.

СМОТРИТЕ ТАКЖЕ

perlsub, perlfunc.