open

СОДЕРЖАНИЕ

• ИМЯ
• СИНТАКСИС
• ОПИСАНИЕ
• ДЕТАЛИ РЕАЛИЗАЦИИ
• СМОТРИТЕ ТАКЖЕ

ИМЯ

open - pragma Perl для установки по умолчанию слоёв PerlIO для входных и выходных данных

СИНТАКСИС

use open IN  => ':crlf', OUT => ':raw';
open my $in, '<', 'foo.txt' or die "open failed: $!";
my $line = <$in>; # CRLF translated
close $in;
open my $out, '>', 'bar.txt' or die "open failed: $!";
print $out $line; # no translation of bytes
close $out;

use open OUT => ':encoding(UTF-8)';
use open IN  => ':encoding(iso-8859-7)';

use open IO  => ':locale';

# IO implicit only for :utf8, :encoding, :locale
use open ':encoding(UTF-8)';
use open ':encoding(iso-8859-7)';
use open ':locale';

# with :std, also affect global standard handles
use open ':std', ':encoding(UTF-8)';
use open ':std', OUT => ':encoding(cp1252)';
use open ':std', IO => ':raw :encoding(UTF-16LE)';

ОПИСАНИЕ

Полная поддержка слоёв ввода-вывода теперь реализована, при условии, что Perl настроен на использование PerlIO в качестве своей системы ввода-вывода (что является значением по умолчанию с версии 5.8 и единственной поддерживаемой конфигурацией с версии 5.16).

Pragma open служит одним из интерфейсов для объявления по умолчанию «слоёв» (ранее известные как «дисциплины») для всех операций ввода-вывода. Любые операторы open(), readpipe() (также известные как qx//) и аналогичные операторы, находящиеся в лексическом объёме действия данного pragma, будут использовать объявленные значения по умолчанию через переменную ${^OPEN}.

Слои указываются с ведущим двоеточием по соглашению. Вы можете указать стек из нескольких слоёв как строку, разделённую пробелами. См. PerlIO для получения дополнительной информации о доступных слоях.

С помощью подpragma IN вы можете объявить значения по умолчанию для входных потоков, а с помощью подpragma OUT вы можете объявить значения по умолчанию для выходных потоков. С помощью подpragma IO (которое можно опустить для :utf8, :locale, или :encoding), вы можете одновременно управлять входными и выходными потоками.

Когда open() получает явный список слоёв (с синтаксисом с тремя аргументами), они переопределяют список, объявленный с помощью данного pragma. open() также может получить одиночное двоеточие (:) для имени слоя, чтобы переопределить данный pragma и использовать значение по умолчанию, как подробно описано в "Значения по умолчанию и как их переопределить" в PerlIO.

Для преобразования из произвольного текстового кодирования используйте слой :encoding. Сопоставление имён кодировок в :encoding является нестрогим: регистр не имеет значения, и многие кодировки имеют несколько псевдонимов. См. Encode::Supported для получения подробностей и списка поддерживаемых языковых окружений.

Если вы хотите установить слои кодирования на основе переменных окружения locale, вы можете использовать псевдослой :locale. Например:

$ENV{LANG} = 'ru_RU.KOI8-R';
# the :locale will probe the locale environment variables like LANG
use open OUT => ':locale';
open(my $out, '>', 'koi8') or die "open failed: $!";
print $out chr(0x430); # CYRILLIC SMALL LETTER A = KOI8-R 0xc1
close $out;
open(my $in, '<', 'koi8') or die "open failed: $!";
printf "%#x\n", ord(<$in>); # this should print 0xc1
close $in;

Логика :locale подробно описана в "Под-pragma :locale" в encoding, но коротко: сначала происходит попытка получить nl_langinfo(CODESET), а затем угадывание по переменным окружения LC_ALL и LANG.

:locale также неявно включает :std.

:std не является слоем, а дополнительным под-pragma. При указании в списке импорта, он активирует дополнительную функциональность по передаче слоёв, выбранных для входных/выходных дескрипторов, в стандартные дескрипторы файлов (STDIN, STDOUT, STDERR). Если новые слои и существующий стек слоёв оба заканчиваются слоем :encoding, существующий слой :encoding также будет удалён.

Например, если для ввода и вывода выбрано :encoding(UTF-8), :std означает, что STDIN, STDOUT и STDERR также будут иметь :encoding(UTF-8). С другой стороны, если только вывод выбран в :encoding(koi8r), :std вызовет только STDOUT и STDERR в koi8r.

Эффект :std не является лексическим, поскольку он изменяет стек слоёв глобальных дескрипторов. Если вы хотите применить только этот глобальный эффект, а не эффект на дескрипторы, открытые в этом области, вы можете изолировать вызов этого pragma в собственном лексическом объёме.

{ use open ':std', IO => ':encoding(UTF-8)' }

ДЕТАЛИ РЕАЛИЗАЦИИ

В PerlIO::Layer find существует метод класса, который реализован как XS-код. Он вызывается import для проверки слоёв:

PerlIO::Layer::->find("perlio")

Возвращаемое значение (если определено) — это объект Perl класса PerlIO::Layer, созданный кодом C в perlio.c. Пока на уровне Perl с этим объектом нельзя ничего полезного сделать.

СМОТРИТЕ ТАКЖЕ

"binmode" в perlfunc, "open" в perlfunc, perlunicode, PerlIO, encoding