Справочник CMake

CMake — это инструмент, который помогает упростить процесс сборки проектов разработки на различных платформах. CMake автоматизирует генерацию систем сборки, таких как Makefiles и файлы проектов Visual Studio.

CMake — это инструмент сторонних разработчиков со своей документацией. Остальная часть этого руководства подробно описывает особенности использования Qt 5 с CMake. Минимальная версия, необходимая для использования Qt5, — CMake 3.1.0.

Начало работы

Первое требование при использовании CMake — использовать find_package для поиска библиотек и заголовочных файлов, поставляемых с Qt. Эти библиотеки и заголовочные файлы затем могут быть использованы для построения библиотек и приложений на основе Qt.

Рекомендуемый способ использования библиотек и заголовочных файлов Qt с CMake — использовать команду target_link_libraries. Эта команда автоматически добавляет соответствующие каталоги включения, определения компиляции, флаг независимости от позиции кода и ссылки на библиотеку qtmain.lib в Windows.

Для построения исполняемого файла GUI helloworld типичное использование будет следующим:

cmake_minimum_required(VERSION 3.1.0)

project(testproject)

# Find includes in corresponding build directories
set(CMAKE_INCLUDE_CURRENT_DIR ON)
# Instruct CMake to run moc automatically when needed
set(CMAKE_AUTOMOC ON)
# Create code from a list of Qt designer ui files
set(CMAKE_AUTOUIC ON)

# Find the QtWidgets library
find_package(Qt5Widgets CONFIG REQUIRED)

# Populate a CMake variable with the sources
set(helloworld_SRCS
    mainwindow.ui
    mainwindow.cpp
    main.cpp
)
# Tell CMake to create the helloworld executable
add_executable(helloworld WIN32 ${helloworld_SRCS})
# Use the Widgets module from Qt 5
target_link_libraries(helloworld Qt5::Widgets)

Для успешного выполнения find_package, Qt 5 должен быть найден в каталоге CMAKE_PREFIX_PATH или переменная Qt5<Модуль>_DIR в кэше CMake должна быть установлена в расположение файла Qt5WidgetsConfig.cmake. Самый простой способ использовать CMake — установить переменную среды CMAKE_PREFIX_PATH на префикс установки Qt 5.

Настройка CMAKE_AUTOMOC автоматически запускает moc при необходимости. Более подробную информацию об этой функции см. в документации CMake AUTOMOC

Импортированные цели

Для каждого модуля Qt создаются импортированные цели. В командах CMake, таких как target_link_libraries, следует отдавать предпочтение именам импортированных целей вместо использования переменной, например, Qt5<Модуль>_LIBRARIES. Фактический путь к библиотеке можно получить, используя свойство LOCATION:

find_package(Qt5Core)

get_target_property(QtCore_location Qt5::Core LOCATION)

Однако, в коде CMake редко требуется полный путь к библиотеке. Большинство API CMake знают об импортированных целях и могут автоматически использовать их вместо полного пути.

Каждый модуль в Qt 5 имеет целевую библиотеку с именем Qt5::<Модуль>, которое можно использовать для этой цели.

Импортированные цели создаются с теми конфигурациями, с которыми был настроен Qt. То есть, если Qt был настроен с переключателем -debug, будет создана импортированная цель с конфигурацией DEBUG. Если Qt был настроен с переключателем -release, будет создана импортированная цель с конфигурацией RELEASE. Если Qt был настроен с переключателем -debug-and-release (по умолчанию в Windows), тогда импортированные цели будут созданы с конфигурациями RELEASE и DEBUG.

Если в вашем проекте есть пользовательские конфигурации сборки CMake, может потребоваться установить отображение от вашей пользовательской конфигурации к конфигурации Qt debug или release.

find_package(Qt5Core)

set(CMAKE_CXX_FLAGS_COVERAGE "${CMAKE_CXX_FLAGS_RELEASE} -fprofile-arcs -ftest-coverage")

# set up a mapping so that the Release configuration for the Qt imported target is
# used in the COVERAGE CMake configuration.
set_target_properties(Qt5::Core PROPERTIES MAP_IMPORTED_CONFIG_COVERAGE "RELEASE")

Плагины также доступны как цели IMPORTED в CMake. Модули Qt Network, Qt SQL, Qt GUI и Qt Widgets имеют связанные плагины. Они предоставляют список плагинов в переменной Qt5<Модуль>_PLUGINS.

foreach(plugin ${Qt5Network_PLUGINS})
  get_target_property(_loc ${plugin} LOCATION)
  message("Plugin ${plugin} is at location ${_loc}")
endforeach()

Справочник по переменным

Переменные модуля

Результат вызова find_package — создание импортированных целей для использования с target_link_libraries, заполнение некоторых переменных информацией, необходимой для настройки сборки, и доступ к макросам для использования. Имя импортированной цели для каждого модуля соответствует имени модуля с префиксом 'Qt5::', например Qt5::Widgets. Все переменные, специфичные для пакета, имеют согласованное имя с префиксом имени пакета. Например, find_package(Qt5Widgets) при успешном поиске сделает доступными следующие переменные:

• Qt5Widgets_VERSION Строковое описание версии модуля.
• Qt5Widgets_LIBRARIES Список библиотек для использования с командой target_link_libraries.
• Qt5Widgets_INCLUDE_DIRS Список каталогов для использования с командой include_directories.
• Qt5Widgets_DEFINITIONS Список определений для использования с add_definitions.
• Qt5Widgets_COMPILE_DEFINITIONS Список определений для использования со свойством target COMPILE_DEFINITIONS.
• Qt5Widgets_FOUND Булево значение, описывающее, был ли модуль успешно найден.
• Qt5Widgets_EXECUTABLE_COMPILE_FLAGS Строка флагов, используемых при построении исполняемых файлов.

Аналогичные переменные будут доступны для всех пакетов, найденных с помощью вызова find_package. Обратите внимание, что переменные чувствительны к регистру.

Переменные установки

Кроме того, доступны несколько других переменных, которые не относятся к какому-либо конкретному пакету, а к самой установке Qt.

• QT_VISIBILITY_AVAILABLE Булево значение, описывающее, был ли Qt построен со скрытой видимостью.
• QT_LIBINFIX Строка, содержащая инфикс, используемый в именах библиотек.

Справочник по макросам

Макросы Qt5Core

Макросы, доступные при поиске Qt5Core.

Макросы Qt5Widgets

Макросы, доступные при поиске Qt5Widgets.

Макросы Qt5DBus

Макросы, доступные при поиске Qt5DBus.

Макросы Qt5LinguistTools

Макросы, доступные при поиске Qt5LinguistTools.