Динамическое создание QML-объектов из JavaScript

QML поддерживает динамическое создание объектов внутри JavaScript. Это полезно для отсрочки инициализации объектов до необходимости, тем самым улучшая время запуска приложения. Это также позволяет динамически создавать визуальные объекты и добавлять их в сцену в ответ на пользовательский ввод или другие события.

См. пример Динамической сцены для демонстрации концепций, обсуждаемых на этой странице.

Динамическое создание объектов

Существует два способа динамического создания объектов из JavaScript. Вы можете вызвать Qt.createComponent() для динамического создания объекта Component или использовать Qt.createQmlObject() для создания объекта из строки QML. Создание компонента предпочтительнее, если у вас уже определен компонент в документе QML и вы хотите динамически создавать экземпляры этого компонента. В противном случае создание объекта из строки QML полезно, когда сам QML-объект генерируется во время выполнения.

Динамическое создание компонента

Для динамической загрузки компонента, определенного в файле QML, вызовите функцию Qt.createComponent() в объекте Qt. Эта функция принимает в качестве единственного аргумента URL файла QML и создает объект Component из этого URL.

После получения объекта Component вы можете вызвать его метод createObject() для создания экземпляра компонента. Эта функция может принимать один или два аргумента:

• Первый - родительский объект для нового объекта. Родитель может быть графическим объектом (например, типа Item) или неграфическим объектом (например, типа QtObject или C++ QObject). Только графические объекты с графическими родительскими объектами будут отображаться на визуальном холсте Qt Quick. Если вы хотите установить родителя позже, вы можете безопасно передать null в эту функцию.
• Второй - необязательный и представляет собой карту пар свойство-значение, определяющих начальные значения свойств объекта. Значения свойств, указанные в этом аргументе, применяются к объекту до завершения его создания, что позволяет избежать ошибок связывания, которые могут возникнуть, если определенные свойства должны быть инициализированы для включения других связей свойств. Кроме того, есть небольшая выгода в производительности по сравнению с определением значений свойств и связей после создания объекта.

Вот пример. Сначала есть Sprite.qml, который определяет простой QML-компонент:

import QtQuick 2.0

Rectangle { width: 80; height: 50; color: "red" }

Наш основной файл приложения, main.qml, импортирует файл JavaScript, componentCreation.js, который будет создавать объекты Sprite:

import QtQuick 2.0
import "componentCreation.js" as MyScript

Rectangle {
    id: appWindow
    width: 300; height: 300

    Component.onCompleted: MyScript.createSpriteObjects();
}

Вот componentCreation.js. Обратите внимание, что он проверяет, является ли статус компонента status Component.Ready, прежде чем вызывать createObject() в случае, если QML-файл загружается по сети и, следовательно, не готов сразу.

var component;
var sprite;

function createSpriteObjects() {
    component = Qt.createComponent("Sprite.qml");
    if (component.status == Component.Ready)
        finishCreation();
    else
        component.statusChanged.connect(finishCreation);
}

function finishCreation() {
    if (component.status == Component.Ready) {
        sprite = component.createObject(appWindow, {"x": 100, "y": 100});
        if (sprite == null) {
            // Error Handling
            console.log("Error creating object");
        }
    } else if (component.status == Component.Error) {
        // Error Handling
        console.log("Error loading component:", component.errorString());
    }
}

Если вы уверены, что загружаемый QML-файл — это локальный файл, вы можете опустить функцию finishCreation() и вызвать createObject() сразу:

function createSpriteObjects() {
    component = Qt.createComponent("Sprite.qml");
    sprite = component.createObject(appWindow, {"x": 100, "y": 100});

    if (sprite == null) {
        // Error Handling
        console.log("Error creating object");
    }
}

Обратите внимание, что в обоих случаях createObject() вызывается с appWindow в качестве аргумента родителя, поскольку динамически создаваемый объект является визуальным (Qt Quick) объектом. Созданный объект станет дочерним объектом объекта appWindow в main.qml, и появится в сцене.

При использовании файлов с относительными путями путь должен быть относительным к файлу, в котором выполняется Qt.createComponent().

Для подключения сигналов к (или получения сигналов от) динамически созданных объектов используйте метод сигнала connect(). Подробнее см. Подключение сигналов к методам и сигналам.

Также возможно создание экземпляров компонентов без блокирования с помощью функции incubateObject().

Создание объекта из строки QML

Если QML не определен до момента выполнения, вы можете создать QML-объект из строки QML, используя функцию Qt.createQmlObject(), как в следующем примере:

var newObject = Qt.createQmlObject('import QtQuick 2.0; Rectangle {color: "red"; width: 20; height: 20}',
                                   parentItem,
                                   "dynamicSnippet1");

Первый аргумент — строка QML для создания. Как и в новом файле, вам нужно импортировать любые типы, которые вы хотите использовать. Второй аргумент — родительский объект для нового объекта, а семантика аргумента родителя, которая применяется к компонентам, аналогично применяется к createQmlObject(). Третий аргумент — путь к файлу, ассоциируемому с новым объектом; он используется для отладки ошибок.

Если строка QML импортирует файлы с помощью относительных путей, путь должен быть относительным к файлу, в котором определен родительский объект (второй аргумент метода).

Важно: При построении статических QML-приложений QML-файлы сканируются для обнаружения зависимостей импорта. Таким образом, все необходимые плагины и ресурсы разрешаются на этапе компиляции. Однако учитываются только явные операторы импорта (те, которые находятся в начале QML-файла), а не операторы импорта, заключённые в строковые литералы. Чтобы поддерживать статическую сборку, необходимо убедиться, что QML-файлы, использующие Qt.createQmlObject(), явно содержат все необходимые импорты в начале файла в дополнение к тем, что находятся внутри строковых литералов.

Поддержание динамически созданных объектов

При управлении динамически созданными объектами необходимо гарантировать, что контекст создания пережить созданный объект. В противном случае, если контекст создания будет уничтожен первым, привязки и обработчики сигналов в динамическом объекте больше не будут работать.

Фактический контекст создания зависит от того, как создаётся объект:

• Если используется Qt.createComponent(), контекст создания — это QQmlContext, в котором вызывается этот метод.
• Если вызван Qt.createQmlObject(), контекст создания — это контекст родительского объекта, переданного в этот метод.
• Если определен объект Component{} и вызваны createObject() или incubateObject(), контекст создания — это контекст, в котором определен объект Component

Также обратите внимание, что, хотя динамически созданные объекты могут использоваться так же, как и другие объекты, у них нет id в QML.

Удаление объектов динамически

Во многих пользовательских интерфейсах достаточно установить непрозрачность визуального объекта в 0 или переместить визуальный объект за пределы экрана вместо его удаления. Однако, если у вас много динамически созданных объектов, вы можете получить заметную выгоду в производительности, если удалять неиспользуемые объекты.

Обратите внимание, что вы никогда не должны вручную удалять объекты, которые были динамически созданы удобными фабриками QML-объектов (такими как Loader и Repeater). Также следует избегать удаления объектов, которые вы сами не создавали динамически.

Объекты можно удалить, используя метод destroy(). Этот метод имеет необязательный аргумент (по умолчанию 0), который указывает приблизительную задержку в миллисекундах перед уничтожением объекта.

Вот пример. application.qml создает пять экземпляров компонента SelfDestroyingRect.qml. Каждый экземпляр выполняет NumberAnimation, и когда анимация завершается, вызывает destroy() на своём корневом объекте для уничтожения самого себя:

import QtQuick 2.0

Item {
    id: container
    width: 500; height: 100

    Component.onCompleted: {
        var component = Qt.createComponent("SelfDestroyingRect.qml");
        for (var i=0; i<5; i++) {
            var object = component.createObject(container);
            object.x = (object.width + 10) * i;
        }
    }
}

import QtQuick 2.0

Rectangle {
    id: rect
    width: 80; height: 80
    color: "red"

    NumberAnimation on opacity {
        to: 0
        duration: 1000

        onRunningChanged: {
            if (!running) {
                console.log("Destroying...")
                rect.destroy();
            }
        }
    }
}

В качестве альтернативы application.qml мог бы уничтожить созданный объект, вызвав object.destroy().

Обратите внимание, что безопасно вызывать destroy() на объекте внутри этого объекта. Объекты не уничтожаются мгновенно после вызова destroy(), а очищаются в какой-то момент между концом этого блока сценария и следующим кадром (если вы не указали ненулевую задержку).

Также обратите внимание, что если экземпляр SelfDestroyingRect был создан статически, как показано ниже:

Item {
    SelfDestroyingRect {
        // ...
    }
}

Это приведет к ошибке, так как объекты могут быть уничтожены только динамически, если они были созданы динамически.

Объекты, созданные с помощью Qt.createQmlObject(), также могут быть уничтожены, используя destroy():

var newObject = Qt.createQmlObject('import QtQuick 2.0; Rectangle {color: "red"; width: 20; height: 20}',
                                   parentItem,
                                   "dynamicSnippet1");
newObject.destroy(1000);