Импорт JavaScript-ресурсов в QML

JavaScript-ресурсы могут быть импортированы документами QML и другими JavaScript-ресурсами. JavaScript-ресурсы могут быть импортированы с помощью относительных или абсолютных URL-адресов. В случае относительного URL-адреса расположение определяется относительно расположения документа QML или JavaScript-ресурса, содержащего импорт. Если файл скрипта недоступен, произойдёт ошибка. Если JavaScript необходимо извлечь из сетевого ресурса, статус компонента status устанавливается в «Загрузка» до тех пор, пока скрипт не будет загружен.

JavaScript-ресурсы также могут импортировать модули QML и другие JavaScript-ресурсы. Синтаксис оператора импорта внутри JavaScript-ресурса немного отличается от оператора импорта внутри документа QML, что подробно документировано ниже.

Импорт JavaScript-ресурса из документа QML

Документ QML может импортировать JavaScript-ресурс с помощью следующего синтаксиса:

import "ResourceURL" as Qualifier

Например:

import "jsfile.js" as Logic

Импортированные JavaScript-ресурсы всегда квалифицируются с помощью ключевого слова «as». Квалификатор для JavaScript-ресурсов должен начинаться с заглавной буквы и быть уникальным, поэтому всегда существует взаимно однозначное соответствие между квалификаторами и JavaScript-файлами. (Это также означает, что квалификаторы не могут быть названы так же, как встроенные JavaScript-объекты, такие как Date и Math).

Функции, определённые в импортированном JavaScript-файле, доступны объектам, определённым в импортирующем документе QML, через синтаксис "Qualifier.functionName(params)". Функции в JavaScript-ресурсах могут принимать параметры, тип которых может быть любым из поддерживаемых QML основных типов или типов объектов, а также обычные типы JavaScript. При вызове таких функций из QML будут применяться стандартные правила преобразования типов данных.

Импорты внутри JavaScript-ресурсов

В QtQuick 2.0, была добавлена поддержка, позволяющая JavaScript-ресурсам импортировать другие JavaScript-ресурсы, а также пространства имён типов QML с использованием варианта стандартного синтаксиса импорта QML (где применяются все ранее описанные правила и квалификаторы).

Из-за возможности JavaScript-ресурса импортировать другой скрипт или модуль QML таким образом в QtQuick 2.0, определены некоторые дополнительные семантики:

• скрипт с импортами не будет наследовать импорты из документа QML, который его импортировал (например, доступ к Component.errorString не будет работать)
• скрипт без импортов будет наследовать импорты из документа QML, который его импортировал (например, доступ к Component.errorString будет работать)
• общий скрипт (т.е. определённый как .pragma library) не наследует импорты из какого-либо документа QML, даже если он не импортирует другие скрипты или модули

Первая семантика концептуально верна, учитывая, что определённый скрипт может быть импортирован произвольным количеством QML-файлов. Вторая семантика сохранена для обеспечения обратной совместимости. Третья семантика остаётся неизменной по сравнению с текущей семантикой общих скриптов, но уточняется здесь в отношении нового возможного случая (когда скрипт импортирует другие скрипты или модули).

Импорт JavaScript-ресурса из другого JavaScript-ресурса

JavaScript-ресурс может импортировать другой следующим образом:

.import "filename.js" as Qualifier

Например:

.import "factorial.js" as MathFunctions

Импорт QML-модуля из JavaScript-ресурса

JavaScript-ресурс может импортировать QML-модуль следующим образом:

.import TypeNamespace MajorVersion.MinorVersion as Qualifier

Например:

.import Qt.test 1.0 as JsQtTest

Это особенно полезно для доступа к функциональности, предоставляемой через тип-синглтон; см. qmlRegisterSingletonType() для получения дополнительной информации.

Примечание: синтаксис .import не работает для скриптов, используемых в WorkerScript

Включение JavaScript-ресурса из другого JavaScript-ресурса

Когда JavaScript-файл импортируется, он должен быть импортирован с квалификатором. Функции в этом файле затем доступны из импортирующего скрипта с помощью квалификатора (то есть как Qualifier.functionName(params)). Иногда желательно, чтобы функции были доступны в импортирующем контексте без необходимости квалификации, и в этом случае функция Qt.include() может быть использована для включения одного JavaScript-файла из другого. Это копирует все функции из другого файла в текущее пространство имён файла, но игнорирует все pragmas и импорты, определённые в этом файле.

Например, QML-код слева вызывает showCalculations() в script.js, который, в свою очередь, может вызвать factorial() в factorial.js, поскольку он включил factorial.js с помощью Qt.include().

import QtQuick 2.0
import "script.js" as MyScript

Item {
    width: 100; height: 100

    MouseArea {
        anchors.fill: parent
        onClicked: {
            MyScript.showCalculations(10)
            console.log("Call factorial() from QML:",
                MyScript.factorial(10))
        }
    }
}

// script.js
Qt.include("factorial.js")

function showCalculations(value) {
    console.log(
        "Call factorial() from script.js:",
        factorial(value));
}

// factorial.js
function factorial(a) {
    a = parseInt(a);
    if (a <= 0)
        return 1;
    else
        return a * factorial(a - 1);
}

Обратите внимание, что вызов Qt.include() копирует все функции из factorial.js в пространство имён MyScript, что означает, что QML-компонент также может получить доступ к factorial() непосредственно как MyScript.factorial().