Размещение с якорями

Помимо более традиционных Grid, Row и Column, Qt Quick также предоставляет способ размещения элементов с помощью концепции якорей. Каждый элемент можно представить как имеющий набор из 7 невидимых «линий якорей»: left, horizontalCenter, right, top, verticalCenter, baseline и bottom.

Линия базового выравнивания (не показана выше) соответствует воображаемой линии, на которой располагается текст. Для элементов без текста она совпадает с линией top.

Система якорей Qt Quick позволяет определить отношения между линиями якорей различных элементов. Например, вы можете написать:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; ... }

В этом случае левая граница rect2 привязана к правой границе rect1, что приводит к следующему:

Вы можете указать несколько якорей. Например:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.top: rect1.bottom; ... }

Указание нескольких горизонтальных или вертикальных якорей позволяет контролировать размер элемента. Ниже, rect2 привязан к правой стороне rect1 и левой стороне rect3. Если любой из синих прямоугольников перемещается, rect2 будет растягиваться и сжиматься по мере необходимости:

Rectangle { id: rect1; x: 0; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.right: rect3.left; ... }
Rectangle { id: rect3; x: 150; ... }

Также существуют некоторые удобные якори. anchors.fill — это удобство, эквивалентное установке якорей left, right, top и bottom к левой, правой, верхней и нижней границам целевого элемента. anchors.centerIn — еще один удобный якорь, эквивалентный установке якорей verticalCenter и horizontalCenter к verticalCenter и horizontalCenter целевого элемента.

Поля и смещения якорей

Система якорей также позволяет указывать поля и смещения для якорей элемента. Поля задают количество свободного пространства, которое нужно оставить снаружи якоря элемента, а смещения позволяют изменять позиционирование с использованием центральных линий якорей. Элемент может задавать поля якорей индивидуально через leftMargin, rightMargin, topMargin и bottomMargin, или использовать anchors.margins для задания одинакового значения поля для всех четырех границ. Смещения якорей задаются с помощью horizontalCenterOffset, verticalCenterOffset и baselineOffset.

Следующий пример задает поле слева:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.leftMargin: 5; ... }

В этом случае слева от rect2 выделяется отступ в 5 пикселей, что приводит к следующему:

Примечание: Поля якорей применяются только к якорям; они не являются универсальным способом применения полей к элементу Item. Если для грани задано поле якоря, но элемент не привязан к какому-либо элементу на этой грани, поле не применяется.

Изменение якорей

Qt Quick предоставляет тип AnchorChanges для указания якорей в состоянии.

State {
    name: "anchorRight"
    AnchorChanges {
        target: rect2
        anchors.right: parent.right
        anchors.left: undefined  //remove the left anchor
    }
}

Тип AnchorAnimation позволяет анимировать изменения AnchorChanges.

Transition {
    AnchorAnimation {}  //animates any AnchorChanges in the corresponding state change
}

Якоря также можно изменять императивно в JavaScript. Однако эти изменения должны быть тщательно упорядочены, иначе могут возникнуть непредвиденные результаты. Следующий пример иллюстрирует эту проблему:

//bad code
Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.right = parent.right
        anchors.left = undefined
    }
}

Когда reanchorToRight вызывается, функция сначала устанавливает правый якорь. В этот момент устанавливаются и левый, и правый якоря, и элемент будет растягиваться по горизонтали, чтобы заполнить своего родителя. Когда левый якорь отменяется, новая ширина останется неизменной. Таким образом, при обновлении якорей в JavaScript вы должны сначала отменить любые больше не требуемые якоря, а затем установить любые новые необходимые якоря, как показано ниже:

Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.left = undefined
        anchors.right = parent.right
    }
}

Поскольку порядок вычисления привязок не определен, не рекомендуется изменять якоря через условные привязки, так как это может привести к описанной выше проблеме упорядочения. В следующем примере прямоугольник в конечном итоге будет растянут на всю ширину родителя, потому что оба якоря (левый и правый) будут одновременно установлены во время обновления привязки.

//bad code
Rectangle {
    width: 50; height: 50
    anchors.left: state == "right" ? undefined : parent.left;
    anchors.right: state == "right" ? parent.right : undefined;
}

Это следует переписать, используя AnchorChanges вместо этого, так как AnchorChanges автоматически обрабатывают проблемы упорядочения.

Ограничения

По соображениям производительности вы можете привязывать элемент только к своим братьям по дереву и прямому родителю. Например, следующий якорь недопустим и вызовет предупреждение:

//bad code
Item {
    id: group1
    Rectangle { id: rect1; ... }
}
Item {
    id: group2
    Rectangle { id: rect2; anchors.left: rect1.right; ... }    // invalid anchor!
}

Кроме того, макеты на основе якорей нельзя смешивать с абсолютным позиционированием. Если элемент задает свое положение x и также устанавливает anchors.left, или привязывает левую и правую грани, но дополнительно задает ширину width, результат неопределен, так как неясно, следует ли использовать привязку или абсолютное позиционирование. То же самое относится к установке координаты y и высоты height вместе с anchors.top и anchors.bottom, или установке anchors.fill вместе с width или height. То же самое относится к использованию позиционеров, таких как Row и Grid, которые могут задавать свойства x и y элемента. Если вы хотите перейти от использования привязки к абсолютному позиционированию, вы можете очистить значение якоря, установив его в undefined.