Плагин наложения элементов Qt Location

Обзор

Этот плагин гео-сервисов — специальный плагин, обеспечивающий только пустую карту. Этот плагин не предоставляет сервисы и предназначен для случаев, когда элемент Карта должен отображать только добавленные элементы карты.

Плагин гео-сервисов наложения элементов можно загрузить, используя ключ плагина "itemsoverlay".

Пример использования

Следующий фрагмент кода демонстрирует, как карта, использующая этот плагин, может быть добавлена в качестве наложения для отображения элементов карты с антиалиасингом. Обратите внимание, что для того, чтобы такое наложение карты было прозрачным, также необходимо установить его цвет в прозрачный, например, прозрачный, как в примере.

Window {
    id: win
    visible: true
    width: 640
    height: 640

    Map {
        id: mapBase
        gesture.enabled: true
        anchors.fill: parent
        plugin: Plugin { name: "osm" }
        center: QtPositioning.coordinate(45,10)
        zoomLevel: 4
        z: parent.z + 1
    }

    Map {
        id: mapOverlay
        anchors.fill: parent
        plugin: Plugin { name: "itemsoverlay" }
        gesture.enabled: false
        center: mapBase.center
        color: 'transparent' // Necessary to make this map transparent
        minimumFieldOfView: mapBase.minimumFieldOfView
        maximumFieldOfView: mapBase.maximumFieldOfView
        minimumTilt: mapBase.minimumTilt
        maximumTilt: mapBase.maximumTilt
        minimumZoomLevel: mapBase.minimumZoomLevel
        maximumZoomLevel: mapBase.maximumZoomLevel
        zoomLevel: mapBase.zoomLevel
        tilt: mapBase.tilt;
        bearing: mapBase.bearing
        fieldOfView: mapBase.fieldOfView
        z: mapBase.z + 1

        MapCircle {
            id: circle
            center: QtPositioning.coordinate(44, 10)
            radius: 200000
            border.width: 5

            MouseArea {
                anchors.fill: parent
                drag.target: parent
            }
        }

        // The code below enables SSAA
        layer.enabled: true
        layer.smooth: true
        property int w : mapOverlay.width
        property int h : mapOverlay.height
        property int pr: Screen.devicePixelRatio
        layer.textureSize: Qt.size(w  * 2 * pr, h * 2 * pr)
    }
}