Размещение с помощью якорей

В дополнение к более традиционным Grid, Row и Column, Qt Quick также предоставляет способ компоновки элементов с использованием концепции якорей. Каждый элемент можно представить как имеющий набор из 7 невидимых «линий якорей»: left, horizontalCenter, right, top, verticalCenter, baseline и bottom.

Базовая линия (не показана выше) соответствует воображаемой линии, на которой будет располагаться текст. Для элементов без текста она совпадает с top.

Система якорей Qt Quick позволяет определять взаимосвязи между линиями якорей различных элементов. Например, можно написать:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; ... }

В этом случае левая граница rect2 привязана к правой границе rect1, что приводит к следующему:

Можно указать несколько якорей. Например:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.top: rect1.bottom; ... }

Указав несколько горизонтальных или вертикальных якорей, можно контролировать размер элемента. Ниже rect2 привязан к правой стороне rect1 и левой стороне rect3. Если любой из синих прямоугольников сместится, rect2 будет растягиваться и сжиматься по мере необходимости:

Rectangle { id: rect1; x: 0; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.right: rect3.left; ... }
Rectangle { id: rect3; x: 150; ... }

Также существуют некоторые удобные якоря. anchors.fill — это удобство, которое равнозначно установке якорей left, right, top и bottom к левой, правой, верхней и нижней границам целевого элемента. anchors.centerIn — еще один удобный якорь, и он эквивалентен установке вертикального и горизонтального центров к вертикальному и горизонтальному центрам целевого элемента.

Отступы и смещения якорей

Система якорей также позволяет задавать отступы и смещения для якорей элемента. Отступы задают количество свободного места снаружи от якоря элемента, а смещения позволяют манипулировать позицией, используя центральные линии якорей. Элемент может задавать свои отступы якорей индивидуально через leftMargin, rightMargin, topMargin и bottomMargin или использовать anchors.margins, чтобы задать одинаковое значение отступа для всех четырех границ. Смещения якорей задаются с помощью horizontalCenterOffset, verticalCenterOffset и baselineOffset.

Следующий пример задает левый отступ:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.leftMargin: 5; ... }

В этом случае отступ в 5 пикселей выделяется слева от rect2, что приводит к следующему:

Примечание: Отступы якорей применяются только к якорям; они не являются универсальным способом применения отступов к элементу Item. Если задан отступ якоря для края, но элемент не привязан к элементу на этом краю, отступ не применяется.

Изменение якорей

Qt Quick предоставляет тип AnchorChanges для задания якорей в состоянии.

State {
    name: "anchorRight"
    AnchorChanges {
        target: rect2
        anchors.right: parent.right
        anchors.left: undefined  //remove the left anchor
    }
}

AnchorChanges можно анимировать с помощью типа AnchorAnimation.

Transition {
    AnchorAnimation {}  //animates any AnchorChanges in the corresponding state change
}

Якоря также можно изменять императивно в JavaScript. Однако эти изменения должны быть тщательно упорядочены, иначе могут возникнуть непредвиденные результаты. Следующий пример иллюстрирует эту проблему:

//bad code
Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.right = parent.right
        anchors.left = undefined
    }
}

Когда reanchorToRight вызывается, функция сначала устанавливает правый якорь. В этот момент устанавливаются как левый, так и правый якоря, и элемент будет растянут по горизонтали, чтобы заполнить своего родителя. При снятии левого якоря новая ширина останется. Таким образом, при обновлении якорей в JavaScript вы должны сначала снять любые якоря, которые больше не нужны, и только затем установить любые новые необходимые якоря, как показано ниже:

Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.left = undefined
        anchors.right = parent.right
    }
}

Поскольку порядок вычисления связей не определен, не рекомендуется изменять якоря через условные связи, так как это может привести к проблеме упорядочения, описанной выше. В следующем примере прямоугольник в конечном итоге достигнет полной ширины своего родителя, потому что левый и правый якоря будут одновременно установлены во время обновления связей.

//bad code
Rectangle {
    width: 50; height: 50
    anchors.left: state == "right" ? undefined : parent.left;
    anchors.right: state == "right" ? parent.right : undefined;
}

Это следует переписать, используя AnchorChanges вместо этого, так как AnchorChanges будут автоматически обрабатывать проблемы упорядочения внутри.

Ограничения

По соображениям производительности вы можете привязать элемент только к своим элементам-побратимам и непосредственному родителю. Например, следующий якорь некорректен и вызовет предупреждение:

//bad code
Item {
    id: group1
    Rectangle { id: rect1; ... }
}
Item {
    id: group2
    Rectangle { id: rect2; anchors.left: rect1.right; ... }    // invalid anchor!
}

Кроме того, компоновки на основе якорей нельзя смешивать с абсолютным позиционированием. Если элемент указывает свою позицию x и также устанавливает anchors.left, или привязывает свои левые и правые границы, но дополнительно устанавливает width, результат неопределен, поскольку неясно, должен ли элемент использовать привязку или абсолютное позиционирование. То же самое можно сказать о настройке позиции y и высоты height с anchors.top и anchors.bottom или установкой anchors.fill наряду с width или height. То же самое относится к позиционерам, таким как Row и Grid, которые могут установить свойства x и y элемента. Если вы хотите перейти от использования привязки к абсолютному позиционированию, вы можете очистить значение привязки, установив его в undefined.