Фреймворк Декларативных Автоматов Состояний

Фреймворк декларативных автоматов состояний предоставляет типы для создания и выполнения графов состояний в QML. Он похож на фреймворк автоматов состояний на C++ на основе Statecharts: A visual formalism for complex systems Харела, который также является основой для диаграмм состояний UML. Как и его аналог на C++, фреймворк предоставляет API и модель выполнения, основанную на State Chart XML (SCXML), для встраивания элементов и семантики диаграмм состояний в приложения QML.

Для пользовательских интерфейсов с несколькими визуальными состояниями, независимыми от логического состояния приложения, рассмотрите использование QML состояний и переходов.

Следующие типы QML предоставляются фреймворком для создания управляемых событиями автоматов состояний:

Использование QtQuick и QtQml.StateMachine импортов

Предупреждение: Если вы пытаетесь импортировать как QtQuick, так и QtQml.StateMachine в одном файле QML, убедитесь, что QtQml.StateMachine импортируется последним. Таким образом, тип State предоставляется фреймворком декларативных автоматов состояний, а не QtQuick:

import QtQuick 2.0
import QtQml.StateMachine 1.0

StateMachine {
    State {
        // okay, is of type QtQml.StateMachine.State
    }
}

В качестве альтернативы вы можете импортировать QtQml.StateMachine в отдельное пространство имен, чтобы избежать неоднозначности с элементом State QtQuick:

import QtQuick 2.0
import QtQml.StateMachine 1.0 as DSM

DSM.StateMachine {
    DSM.State {
        // ...
    }
}

Простой автомат состояний

Чтобы продемонстрировать основные возможности API автомата состояний, рассмотрим пример: автомат состояний с тремя состояниями, s1, s2 и s3. Автомат состояний управляется единственной кнопкой; при нажатии кнопки автомат переходит в другое состояние. Изначально автомат состояний находится в состоянии s1. Ниже приведена диаграмма состояний, показывающая различные состояния в нашем примере.

Следующий фрагмент кода показывает код, необходимый для создания такого автомата состояний.

    Button {
        anchors.fill: parent
        id: button

        // change the button label to the active state id
        text: s1.active ? "s1" : s2.active ? "s2" : "s3"
    }

    StateMachine {
        id: stateMachine
        // set the initial state
        initialState: s1

        // start the state machine
        running: true

        State {
            id: s1
            // create a transition from s1 to s2 when the button is clicked
            SignalTransition {
                targetState: s2
                signal: button.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s1 entered")
            onExited: console.log("s1 exited")
        }

        State {
            id: s2
            // create a transition from s2 to s3 when the button is clicked
            SignalTransition {
                targetState: s3
                signal: button.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s2 entered")
            onExited: console.log("s2 exited")
        }
        State {
            id: s3
            // create a transition from s3 to s1 when the button is clicked
            SignalTransition {
                targetState: s1
                signal: button.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s3 entered")
            onExited: console.log("s3 exited")
        }
    }

Автомат состояний работает асинхронно, чтобы стать частью цикла событий вашего приложения.

Автоматы состояний, которые завершаются

Автомат состояний, определенный в предыдущем разделе, никогда не завершается. Для того, чтобы автомат состояний мог завершиться, ему необходимо иметь конечное состояние верхнего уровня (FinalState объект). Когда автомат состояний входит в конечное состояние верхнего уровня, он генерирует сигнал finished и останавливается.

Для добавления конечного состояния в график вам нужно создать объект FinalState и использовать его в качестве целевого объекта одного или нескольких переходов.

Общий переход

Предположим, мы хотели, чтобы пользователь мог выйти из приложения в любое время, нажав кнопку «Выход». Для этого нам нужно создать конечное состояние и сделать его целевым объектом перехода, связанного с сигналом clicked() кнопки «Выход». Мы могли бы добавить переход для каждого состояния; однако это кажется избыточным, и вам также нужно будет помнить о добавлении такого перехода для каждого нового состояния, которое будет добавлено в будущем.

Мы можем добиться того же поведения (а именно, что нажатие кнопки «Выход» завершает автомат состояний независимо от того, в каком состоянии находится автомат состояний) путем группировки состояний s1, s2 и s3. Это делается путем создания нового состояния верхнего уровня и добавления трех исходных состояний в качестве дочерних состояний нового состояния. На следующей диаграмме показан новый автомат состояний.

Три исходных состояния были переименованы в s11, s12 и s13, чтобы отразить, что они теперь являются дочерними состояниями нового состояния верхнего уровня, s1. Дочерние состояния неявно наследуют переходы своего родительского состояния. Это означает, что теперь достаточно добавить один переход от s1 к конечному состоянию, s2. Новые состояния, добавленные в s1, автоматически унаследуют этот переход.

Для группировки состояний достаточно указать соответствующего родителя при создании состояния. Вы также должны указать, какое из дочерних состояний является начальным (дочернее состояние, в которое автомат состояний должен войти, когда родительское состояние является целевым объектом перехода).

    Row {
        anchors.fill: parent
        spacing: 2
        Button {
            id: button
            // change the button label to the active state id
            text: s11.active ? "s11" : s12.active ? "s12" : "s13"
        }
        Button {
            id: quitButton
            text: "quit"
        }
    }

    StateMachine {
        id: stateMachine
        // set the initial state
        initialState: s1

        // start the state machine
        running: true

        State {
            id: s1
            // set the initial state
            initialState: s11

            // create a transition from s1 to s2 when the button is clicked
            SignalTransition {
                targetState: s2
                signal: quitButton.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s1 entered")
            onExited: console.log("s1 exited")
            State {
                id: s11
                // create a transition from s11 to s12 when the button is clicked
                SignalTransition {
                    targetState: s12
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s11 entered")
                onExited: console.log("s11 exited")
            }

            State {
                id: s12
                // create a transition from s12 to s13 when the button is clicked
                SignalTransition {
                    targetState: s13
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s12 entered")
                onExited: console.log("s12 exited")
            }
            State {
                id: s13
                // create a transition from s13 to s11 when the button is clicked
                SignalTransition {
                    targetState: s11
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s13 entered")
                onExited: console.log("s13 exited")
            }
        }
        FinalState {
            id: s2
            onEntered: console.log("s2 entered")
            onExited: console.log("s2 exited")
        }
        onFinished: Qt.quit()
    }

В данном случае мы хотим, чтобы приложение завершалось при завершении автомата состояний, поэтому сигнал finished() автомата подключается к слоту quit() приложения.

Дочернее состояние может переопределить унаследованный переход. Например, следующий код добавляет переход, который фактически приводит к тому, что нажатие кнопки «Выход» игнорируется, когда автомат состояний находится в состоянии s12.

            State {
                id: s12
                // create a transition from s12 to s13 when the button is clicked
                SignalTransition {
                    targetState: s13
                    signal: button.clicked
                }

                // ignore Quit button when we are in state 12
                SignalTransition {
                    targetState: s12
                    signal: quitButton.clicked
                }

                // do something when the state enters/exits
                onEntered: console.log("s12 entered")
                onExited: console.log("s12 exited")
            }

Переход может иметь любое состояние в качестве целевого объекта, независимо от того, где находится целевое состояние в иерархии состояний.

Использование состояний истории

Представьте, что мы хотели добавить механизм «прерывания» к примеру, обсуждавшемуся в предыдущем разделе; пользователь должен иметь возможность нажать кнопку, чтобы автомат состояний выполнил некоторую не связанную задачу, после чего автомат состояний должен возобновить то, что он делал до этого (т. е. вернуться к предыдущему состоянию, которое в данном случае является одним из трех состояний).

Это поведение можно легко смоделировать с помощью состояний истории. Состояние истории (HistoryState объект) — это псевдосостояние, которое представляет дочернее состояние, в котором родительское состояние находилось до последнего выхода из него.

Состояние истории создается как дочернее состояние состояния, для которого мы хотим сохранить текущее дочернее состояние; когда автомат состояний обнаруживает такое состояние во время выполнения, он автоматически сохраняет текущее (реальное) дочернее состояние при выходе из родительского состояния. Переход в состояние истории фактически является переходом в дочернее состояние, которое автомат состояний ранее сохранил; автомат состояний автоматически «перенаправляет» переход в реальное дочернее состояние.

На следующей диаграмме показан автомат состояний после добавления механизма прерывания.

Следующий код показывает, как это можно реализовать; в данном примере при входе в s3 просто отображается диалоговое окно, а затем немедленно происходит возврат к предыдущему дочернему состоянию s1 через состояние истории.

    Row {
        anchors.fill: parent
        spacing: 2
        Button {
            id: button
            // change the button label to the active state id
            text: s11.active ? "s11" : s12.active ? "s12" :  s13.active ? "s13" : "s3"
        }
        Button {
            id: interruptButton
            text: s1.active ? "Interrupt" : "Resume"
        }
        Button {
            id: quitButton
            text: "quit"
        }
    }

    StateMachine {
        id: stateMachine
        // set the initial state
        initialState: s1

        // start the state machine
        running: true

        State {
            id: s1
            // set the initial state
            initialState: s11

            // create a transition from s1 to s2 when the button is clicked
            SignalTransition {
                targetState: s2
                signal: quitButton.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s1 entered")
            onExited: console.log("s1 exited")
            State {
                id: s11
                // create a transition from s1 to s2 when the button is clicked
                SignalTransition {
                    targetState: s12
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s11 entered")
                onExited: console.log("s11 exited")
            }

            State {
                id: s12
                // create a transition from s2 to s3 when the button is clicked
                SignalTransition {
                    targetState: s13
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s12 entered")
                onExited: console.log("s12 exited")
            }
            State {
                id: s13
                // create a transition from s3 to s1 when the button is clicked
                SignalTransition {
                    targetState: s1
                    signal: button.clicked
                }
                // do something when the state enters/exits
                onEntered: console.log("s13 entered")
                onExited: console.log("s13 exited")
            }

            // create a transition from s1 to s3 when the button is clicked
            SignalTransition {
                targetState: s3
                signal: interruptButton.clicked
            }
            HistoryState {
                id: s1h
            }
        }
        FinalState {
            id: s2
            onEntered: console.log("s2 entered")
            onExited: console.log("s2 exited")
        }
        State {
            id: s3
            SignalTransition {
                targetState: s1h
                signal: interruptButton.clicked
            }
            // do something when the state enters/exits
            onEntered: console.log("s3 entered")
            onExited: console.log("s3 exited")
        }
        onFinished: Qt.quit()
    }

Использование параллельных состояний

Предположим, вы хотите смоделировать набор взаимоисключающих свойств автомобиля в одном автомате состояний. Допустим, нас интересуют свойства «Чистый/Грязный» и «Движется/Не движется». Для представления состояний и свободного перехода между всеми возможными комбинациями потребуется четыре взаимоисключающих состояния и восемь переходов, как показано на следующей диаграмме состояний.

Если мы добавим третье свойство (скажем, «Красный/Синий»), общее количество состояний удвоится до восьми; а если мы добавим четвертое свойство (скажем, «Закрытый/Кабриолет»), общее количество состояний снова удвоится до 16.

Это экспоненциальное увеличение можно уменьшить с помощью параллельных состояний, что позволяет линейно увеличивать количество состояний и переходов при добавлении дополнительных свойств. Кроме того, состояния могут быть добавлены или удалены из параллельного состояния без влияния на какие-либо его состояния-«братья». На следующей диаграмме состояний показаны различные параллельные состояния для примера с автомобилем.

Для создания группы параллельных состояний установите childMode в QState.ParallelStates.

State {
    id: s1
    childMode: QState.ParallelStates
    State {
        id: s11
    }
    State {
        id: s12
    }
}

При входе в группу параллельных состояний все ее дочерние состояния будут входить одновременно. Переходы внутри отдельных дочерних состояний работают нормально. Однако любое из дочерних состояний может выполнить переход, который выйдет из родительского состояния. Когда это происходит, родительское состояние и все его дочерние состояния выходят.

Параллелизм во фреймворке автоматов состояний следует интерливированной семантике. Все параллельные операции будут выполняться в одном атомарном шаге обработки событий, поэтому ни одно событие не может прервать параллельные операции. Однако события все равно будут обрабатываться последовательно, поскольку сам автомат однопоточный. Например, рассмотрим ситуацию, когда существуют два перехода, которые выходят из той же группы параллельных состояний, и их условия становятся истинными одновременно. В этом случае событие, которое обрабатывается последним из двух, не окажет никакого влияния.

Выход из составного состояния

Дочернее состояние может быть конечным (FinalState объект); при входе в конечное дочернее состояние родительское состояние генерирует сигнал State::finished. На следующей диаграмме показано составное состояние s1, которое выполняет некоторую обработку перед входом в конечное состояние:

Когда вводится конечное состояние s1, s1 автоматически генерирует finished. Мы используем переход сигнала, чтобы заставить это событие инициировать изменение состояния:

State {
    id: s1
    SignalTransition {
        targetState: s2
        signal: s1.finished
    }
}

Использование конечных состояний в составных состояниях полезно, когда вы хотите скрыть внутренние детали составного состояния. Внешний мир должен иметь возможность войти в состояние и получить уведомление о завершении работы состояния, не зная внутренних деталей. Это очень мощный механизм абстракции и инкапсуляции при построении сложных (глубоко вложенных) автоматов состояний. (В приведенном выше примере, вы конечно можете создать переход непосредственно из состояния s1 в состояние done, а не полагаться на сигнал finished() s1, но с тем последствием, что детали реализации s1 будут раскрыты и от них будет зависеть).

Для параллельных групп состояний сигнал State::finished генерируется, когда все дочерние состояния перешли в конечные состояния.

Переходы без цели

Переход не обязательно должен иметь целевое состояние. Переход без цели может быть инициирован таким же образом, как и любой другой переход; разница заключается в том, что он не вызывает никаких изменений состояния. Это позволяет вам реагировать на сигнал или событие, когда ваша машина находится в определённом состоянии, не выходя из этого состояния. Например:

Button {
    id: button
    text: "button"
    StateMachine {
        id: stateMachine
        initialState: s1
        running: true
        State {
            id: s1
            SignalTransition {
                signal: button.clicked
                onTriggered: console.log("button pressed")
            }
        }
    }
}

Сообщения «нажатие кнопки» будут отображаться каждый раз при нажатии кнопки, но автомат состояния останется в текущем состоянии (s1). Если целевое состояние было явно установлено на s1, s1 будет выходить и повторно входить каждый раз (будут генерироваться сигналы QAbstractState::entered и QAbstractState::exited).

Связанная информация

• Типы QML декларативного автомата состояний
• Фреймворк автомата состояний