Определение JavaScript-ресурсов в QML

Логика программы для приложения QML может быть определена на JavaScript. JavaScript-код может быть определён в строке документа QML или отделён в JavaScript-файлы (известные как JavaScript Resources в QML).

Существует два разных типа JavaScript-ресурсов, поддерживаемых в QML: файлы реализации «за кулисами» и общие (библиотечные) файлы. Оба типа JavaScript-ресурсов могут быть импортированы другими JavaScript-ресурсами или включены в модули QML.

Ресурс реализации «за кулисами»

Большинство JavaScript-файлов, импортированных в документ QML, представляют собой реализацию с состоянием для документа QML, их импортирующего. В таких случаях, каждый экземпляр типа QML-объекта, определённого в документе, требует отдельной копии JavaScript-объектов и состояния, чтобы работать корректно.

По умолчанию, при импорте JavaScript-файлов предоставляется уникальная, изолированная копия для каждого экземпляра QML-компонента. Если этот JavaScript-файл не импортирует никаких ресурсов или модулей с инструкцией .import, его код будет выполняться в том же контексте, что и экземпляр QML-компонента, и, следовательно, сможет обращаться к объектам и свойствам, объявленным в этом QML-компоненте и манипулировать ими. В противном случае, у него будет свой уникальный контекст, и объекты и свойства QML-компонента должны передаваться функциям JavaScript-файла в качестве параметров, если они необходимы.

Следующий пример ресурса реализации «за кулисами»:

// MyButton.qml
import QtQuick 2.0
import "my_button_impl.js" as Logic // a new instance of this JavaScript resource is loaded for each instance of Button.qml

Rectangle {
    id: rect
    width: 200
    height: 100
    color: "red"

    MouseArea {
        id: mousearea
        anchors.fill: parent
        onClicked: Logic.onClicked(rect)
    }
}

// my_button_impl.js
var clickCount = 0;   // this state is separate for each instance of MyButton
function onClicked(button) {
    clickCount += 1;
    if ((clickCount % 5) == 0) {
        button.color = Qt.rgba(1,0,0,1);
    } else {
        button.color = Qt.rgba(0,1,0,1);
    }
}

В целом, простая логика должна быть определена непосредственно в файле QML, но более сложная логика должна быть разделена на ресурсы реализации «за кулисами» для поддержания и читабельности.

Общие JavaScript-ресурсы (библиотеки)

Некоторые JavaScript-файлы действуют больше как библиотеки — они предоставляют набор вспомогательных функций, которые принимают входные данные и вычисляют выходные данные, но никогда не манипулируют экземплярами QML-компонентов напрямую.

Поскольку было бы неэффективно, если бы каждый экземпляр QML-компонента имел уникальную копию этих библиотек, программист JavaScript может указать, что определённый файл является общей библиотекой, с помощью псевдодирективы, как показано в следующем примере.

// factorial.js
.pragma library

var factorialCount = 0;

function factorial(a) {
    a = parseInt(a);

    // factorial recursion
    if (a > 0)
        return a * factorial(a - 1);

    // shared state
    factorialCount += 1;

    // recursion base-case.
    return 1;
}

function factorialCallCount() {
    return factorialCount;
}

Директива pragma должна появляться перед любым JavaScript-кодом, за исключением комментариев.

Обратите внимание, что несколько QML-документов могут импортировать "factorial.js" и вызывать предоставляемые им функции factorial и factorialCallCount. Состояние JavaScript-импорта делится между QML-документами, которые его импортируют, и, следовательно, значение функции factorialCallCount может быть отличным от нуля, когда она вызывается в QML-документе, который никогда не вызывал функцию factorial.

Например:

// Calculator.qml
import QtQuick 2.0
import "factorial.js" as FactorialCalculator // this JavaScript resource is only ever loaded once by the engine, even if multiple instances of Calculator.qml are created

Text {
    width: 500
    height: 100
    property int input: 17
    text: "The factorial of " + input + " is: " + FactorialCalculator.factorial(input)
}

Поскольку они общие, файлы .pragma library не могут напрямую получать доступ к объектам или свойствам экземпляров QML-компонентов, хотя значения QML могут передаваться в качестве параметров функций.