Размещение с якорями

В дополнение к более традиционным сеткам, строкам и столбцам, Qt Quick также предоставляет способ размещения элементов с использованием концепции якорей. Каждый элемент можно рассматривать как имеющий набор из 7 невидимых «линий якорей»: левый, горизонтальный центр, правый, верхний, вертикальный центр, линия основания и нижний.

Линия основания (не показана выше) соответствует воображаемой линии, на которой располагается текст. Для элементов без текста она совпадает с верхним якорем.

Система якорей Qt Quick позволяет определять отношения между линиями якорей различных элементов. Например, можно записать:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; ... }

В этом случае левый край rect2 привязан к правому краю rect1, что приводит к следующему:

Можно указать несколько якорей. Например:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.top: rect1.bottom; ... }

Указав несколько горизонтальных или вертикальных якорей, можно управлять размером элемента. Ниже, rect2 привязан к правому краю rect1 и левому краю rect3. Если любой из прямоугольников синего цвета будет перемещен, rect2 будет растягиваться и сжиматься по мере необходимости:

Rectangle { id: rect1; x: 0; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.right: rect3.left; ... }
Rectangle { id: rect3; x: 150; ... }

Также существуют удобные якори. anchors.fill — это удобство, которое равносильно установке якорей left, right, top и bottom к левому, правому, верхнему и нижнему краям целевого элемента. anchors.centerIn — еще один удобный якорь, и он такой же, как установка якорей verticalCenter и horizontalCenter к вертикальному и горизонтальному центрам целевого элемента.

Поля и смещения якорей

Система якорей также позволяет задавать поля и смещения для якорей элемента. Поля задают количество свободного места, оставляемого снаружи от якоря элемента, в то время как смещения позволяют управлять позицией с помощью центральных линий якорей. Элемент может задавать свои поля якорей индивидуально через leftMargin, rightMargin, topMargin и bottomMargin или использовать anchors.margins для задания одного значения поля для всех четырех краев. Смещения якорей задаются с помощью horizontalCenterOffset, verticalCenterOffset и baselineOffset.

Следующий пример задает левое поле:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.leftMargin: 5; ... }

В этом случае отводится отступ в 5 пикселей слева от rect2, что приводит к следующему:

Примечание: Поля якорей применяются только к якорям; они не являются общим способом применения полей к элементу Item. Если для края задано поле якоря, но элемент не привязан ни к какому элементу по этому краю, поле не применяется.

Изменение якорей

Qt Quick предоставляет тип AnchorChanges для задания якорей в состоянии.

State {
    name: "anchorRight"
    AnchorChanges {
        target: rect2
        anchors.right: parent.right
        anchors.left: undefined  //remove the left anchor
    }
}

AnchorChanges можно анимировать с помощью типа AnchorAnimation.

Transition {
    AnchorAnimation {}  //animates any AnchorChanges in the corresponding state change
}

Якоря также можно изменять императивно в JavaScript. Однако эти изменения должны быть тщательно упорядочены, иначе могут возникнуть непредвиденные результаты. Следующий пример иллюстрирует эту проблему:

//bad code
Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.right = parent.right
        anchors.left = undefined
    }
}

Когда reanchorToRight вызывается, функция сначала устанавливает правый якорь. В этот момент устанавливаются оба якоря (левый и правый), и элемент будет растягиваться по горизонтали, чтобы заполнить своего родителя. Когда левый якорь снимается, новая ширина останется неизменной. Таким образом, при обновлении якорей в JavaScript необходимо сначала снять любые больше не требуемые якоря, а затем установить любые новые требуемые якоря, как показано ниже:

Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.left = undefined
        anchors.right = parent.right
    }
}

Поскольку порядок оценки привязок не определен, не рекомендуется изменять якоря с помощью условных привязок, так как это может привести к описанной выше проблеме с порядком. В следующем примере прямоугольник в конечном итоге увеличится до полной ширины своего родителя, потому что оба якоря (левый и правый) будут одновременно установлены во время обновления привязки.

//bad code
Rectangle {
    width: 50; height: 50
    anchors.left: state == "right" ? undefined : parent.left;
    anchors.right: state == "right" ? parent.right : undefined;
}

Это следует переписать, используя AnchorChanges вместо этого, так как AnchorChanges будут автоматически обрабатывать проблемы с порядком внутри.

Ограничения

По соображениям производительности элемент можно привязать только к своим братьям и непосредственно к родителю. Например, следующий якорь недействителен и вызовет предупреждение:

//bad code
Item {
    id: group1
    Rectangle { id: rect1; ... }
}
Item {
    id: group2
    Rectangle { id: rect2; anchors.left: rect1.right; ... }    // invalid anchor!
}

Кроме того, макеты на основе якорей не могут быть смешаны с абсолютным позиционированием. Если элемент указывает свою позицию x и также устанавливает anchors.left, или привязывает свои левые и правые края, но дополнительно задает width, результат неопределен, так как не будет ясно, должен ли элемент использовать привязку или абсолютное позиционирование. То же самое можно сказать о задании свойства y и height элемента с anchors.top и anchors.bottom или установке anchors.fill вместе с width или height. То же самое относится к использованию позиционеров, таких как Row и Grid, которые могут устанавливать свойства x и y элемента. Если вы хотите перейти от использования привязки к абсолютной позиции, можно очистить значение якоря, установив его в undefined.