Размещение с якорями

Помимо более традиционных Grid, Row и Column, Qt Quick также предоставляет способ размещения элементов с помощью концепции якорей. Каждый элемент можно представить как имеющий набор из 7 невидимых «линий якорей»: left, horizontalCenter, right, top, verticalCenter, baseline и bottom.

Линия baseline (не представленная выше) соответствует воображаемой линии, на которой располагается текст. Для элементов без текста она совпадает с линией top.

Система якорей Qt Quick позволяет определять взаимосвязи между линиями якорей разных элементов. Например, вы можете записать:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; ... }

В этом случае левая граница rect2 привязана к правой границе rect1, что приводит к следующему:

Вы можете указать несколько якорей. Например:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.top: rect1.bottom; ... }

Указав несколько горизонтальных или вертикальных якорей, вы можете контролировать размер элемента. Ниже, rect2 привязан к правой стороне rect1 и левой стороне rect3. Если любой из синих прямоугольников сместить, rect2 будет растягиваться и сжиматься по мере необходимости:

Rectangle { id: rect1; x: 0; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.right: rect3.left; ... }
Rectangle { id: rect3; x: 150; ... }

Также есть некоторые удобные якоря. anchors.fill — это удобный способ, который эквивалентен установке якорей left, right, top и bottom к соответствующим границам целевого элемента. anchors.centerIn — еще один удобный якорь, эквивалентный установке якорей verticalCenter и horizontalCenter к вертикальному и горизонтальному центрам целевого элемента.

Поля и смещения якорей

Система якорей также позволяет задавать поля и смещения для якорей элемента. Поля задают количество свободного места, которое следует оставить по внешнему краю якоря элемента, а смещения позволяют манипулировать позицией с помощью центральных линий якорей. Элемент может задавать свои поля якорей индивидуально через leftMargin, rightMargin, topMargin и bottomMargin, или использовать anchors.margins для задания одного значения поля для всех четырех границ. Смещения якорей задаются с помощью horizontalCenterOffset, verticalCenterOffset и baselineOffset.

Следующий пример задает левое поле:

Rectangle { id: rect1; ... }
Rectangle { id: rect2; anchors.left: rect1.right; anchors.leftMargin: 5; ... }

В этом случае поле в 5 пикселей резервируется слева от rect2, что приводит к следующему:

Примечание: Поля якорей применяются только к якорям; они не являются универсальным способом применения полей к элементу Item. Если поле якоря задано для грани, но элемент не привязан к элементу на этой грани, поле не применяется.

Изменение якорей

Qt Quick предоставляет тип AnchorChanges для задания якорей в состоянии.

State {
    name: "anchorRight"
    AnchorChanges {
        target: rect2
        anchors.right: parent.right
        anchors.left: undefined  //remove the left anchor
    }
}

AnchorChanges можно анимировать, используя тип AnchorAnimation.

Transition {
    AnchorAnimation {}  //animates any AnchorChanges in the corresponding state change
}

Якоря также можно изменять императивно в JavaScript. Однако эти изменения должны быть тщательно упорядочены, иначе могут возникнуть непредвиденные результаты. Следующий пример иллюстрирует проблему:

//bad code
Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.right = parent.right
        anchors.left = undefined
    }
}

Когда reanchorToRight вызывается, функция сначала устанавливает правый якорь. В этот момент оба якоря (левый и правый) установлены, и элемент будет растягиваться по горизонтали, чтобы заполнить родительский элемент. Когда левый якорь сброшен, новая ширина сохраняется. Таким образом, при обновлении якорей в JavaScript вы должны сначала сбросить все якоря, которые больше не требуются, а затем установить новые необходимые якоря, как показано ниже:

Rectangle {
    width: 50
    anchors.left: parent.left

    function reanchorToRight() {
        anchors.left = undefined
        anchors.right = parent.right
    }
}

Поскольку порядок вычисления связей не определен, не рекомендуется изменять якоря через условные связи, так как это может привести к описанной выше проблеме порядка. В следующем примере прямоугольник в конечном итоге увеличится до полной ширины своего родительского элемента, потому что оба якоря (левый и правый) будут одновременно установлены во время обновления связи.

//bad code
Rectangle {
    width: 50; height: 50
    anchors.left: state == "right" ? undefined : parent.left;
    anchors.right: state == "right" ? parent.right : undefined;
}

Это следует переписать, используя AnchorChanges вместо этого, поскольку AnchorChanges автоматически обрабатывает проблемы с порядком внутри.

Ограничения

По причинам производительности, вы можете привязать элемент только к своим соседям и непосредственно к родителю. Например, следующий якорь недействителен и вызовет предупреждение:

//bad code
Item {
    id: group1
    Rectangle { id: rect1; ... }
}
Item {
    id: group2
    Rectangle { id: rect2; anchors.left: rect1.right; ... }    // invalid anchor!
}

Кроме того, макеты на основе якорей нельзя смешивать с абсолютным позиционированием. Если элемент указывает свою позицию x и также устанавливает anchors.left, или привязывает свои левые и правые грани, но дополнительно устанавливает width, результат неопределён, так как неясно, должен ли элемент использовать привязку или абсолютное позиционирование. То же самое можно сказать о настройке свойств y и height с anchors.top и anchors.bottom, или установке anchors.fill вместе с width или height. То же самое относится к позиционерам, таким как Row и Grid, которые могут установить свойства x и y элемента. Если вы хотите перейти от использования якорей к абсолютному позиционированию, вы можете очистить значение якоря, установив его в undefined.