cmake_parse_arguments

Обработка аргументов функции или макроса.

cmake_parse_arguments(<prefix> <options> <one_value_keywords>
                      <multi_value_keywords> <args>...)

cmake_parse_arguments(PARSE_ARGV <N> <prefix> <options>
                      <one_value_keywords> <multi_value_keywords>)

Эта команда используется в макросах или функциях. Она обрабатывает аргументы, переданные данному макросу или функции, и определяет набор переменных, содержащих значения соответствующих опций.

Первый вариант обрабатывает аргументы, переданные в <args>.... Это может быть использовано как в macro(), так и в function().

Вариант PARSE_ARGV предназначен только для использования в теле function(). В этом случае аргументы, которые обрабатываются, берутся из переменных ARGV# вызывающей функции. Обработка начинается с <N>-го аргумента, где <N> - целое беззнаковое число. Это позволяет значениям содержать специальные символы, такие как ;.

Аргумент <options> содержит все опции для соответствующего макроса, т.е. ключевые слова, которые могут быть использованы при вызове макроса без последующего значения, например, ключевое слово OPTIONAL команды install().

Аргумент <one_value_keywords> содержит все ключевые слова для данного макроса, которые следуют за одним значением, например, ключевое слово DESTINATION команды install().

Аргумент <multi_value_keywords> содержит все ключевые слова для данного макроса, за которыми могут следовать более одного значения, например, ключевые слова TARGETS или FILES команды install().

По окончании выполнения, cmake_parse_arguments рассмотрит для каждого ключевого слова, перечисленного в <options>, <one_value_keywords> и <multi_value_keywords>, переменную, составленную из указанного <prefix> и названия соответствующего ключевого слова. Эти переменные будут содержать соответствующее значение из списка аргументов или будут не определены, если связанная опция не найдена. Для ключевых слов <options> эти переменные всегда будут определены, в TRUE или FALSE, независимо от того, есть ли опция в списке аргументов или нет.

Все оставшиеся аргументы собираются в переменную <prefix>_UNPARSED_ARGUMENTS, которая будет не определена, если все аргументы были распознаны. Это можно проверить позже, чтобы увидеть, был ли ваш макрос вызван с нераспознанными параметрами.

Ключевые слова <one_value_keywords> и <multi_value_keywords>, которым не были заданы значения, собираются в переменную <prefix>_KEYWORDS_MISSING_VALUES, которая будет не определена, если все ключевые слова получили значения. Это можно проверить, чтобы увидеть, были ли какие-либо ключевые слова без заданных значений.

Рассмотрим пример макроса, my_install(), который принимает аргументы, аналогичные реальной команде install():

macro(my_install)
    set(options OPTIONAL FAST)
    set(oneValueArgs DESTINATION RENAME)
    set(multiValueArgs TARGETS CONFIGURATIONS)
    cmake_parse_arguments(MY_INSTALL "${options}" "${oneValueArgs}"
                          "${multiValueArgs}" ${ARGN} )

    # ...

Предположим, что my_install() был вызван так:

my_install(TARGETS foo bar DESTINATION bin OPTIONAL blub CONFIGURATIONS)

После вызова cmake_parse_arguments макрос установит или объявит не определёнными следующие переменные:

MY_INSTALL_OPTIONAL = TRUE
MY_INSTALL_FAST = FALSE # was not used in call to my_install
MY_INSTALL_DESTINATION = "bin"
MY_INSTALL_RENAME <UNDEFINED> # was not used
MY_INSTALL_TARGETS = "foo;bar"
MY_INSTALL_CONFIGURATIONS <UNDEFINED> # was not used
MY_INSTALL_UNPARSED_ARGUMENTS = "blub" # nothing expected after "OPTIONAL"
MY_INSTALL_KEYWORDS_MISSING_VALUES = "CONFIGURATIONS"
         # No value for "CONFIGURATIONS" given

Затем вы можете продолжить и обработать эти переменные.

Ключевые слова завершают списки значений, например, если сразу после one_value_keyword следует другое распознанное ключевое слово, это интерпретируется как начало новой опции. Например, my_install(TARGETS foo DESTINATION OPTIONAL) приведет к тому, что MY_INSTALL_DESTINATION будет установлено в значение "OPTIONAL", но так как OPTIONAL само является ключевым словом, MY_INSTALL_DESTINATION будет пустым (но добавленным в MY_INSTALL_KEYWORDS_MISSING_VALUES) и, следовательно, MY_INSTALL_OPTIONAL будет установлено в TRUE.