cmake_language

Вызов метаопераций на команды CMake.

Синтаксис

cmake_language(CALL <command> [<arg>...])
cmake_language(EVAL CODE <code>...)
cmake_language(DEFER <options>... CALL <command> [<arg>...])
cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)
cmake_language(GET_MESSAGE_LOG_LEVEL <out-var>)
cmake_language(EXIT <exit-code>)

Введение

Эта команда будет вызывать метаоперации на встроенные команды CMake или те, которые созданы с помощью команд macro() или function().

cmake_language не вводит новую переменную или область политики.

Вызов команд

cmake_language(CALL <command> [<arg>...])

Вызывает указанную <command> с заданными аргументами (если таковые имеются). Например, код:

set(message_command "message")
cmake_language(CALL ${message_command} STATUS "Hello World!")

эквивалентен

message(STATUS "Hello World!")

Примечание

Для обеспечения согласованности кода следующие команды запрещены:

• if / elseif / else / endif
• block / endblock
• while / endwhile
• foreach / endforeach
• function / endfunction
• macro / endmacro

Вычисление кода

cmake_language(EVAL CODE <code>...)

Вычисляет <code>... как код CMake.

Например, код:

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

cmake_language(EVAL CODE "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

эквивалентен

set(A TRUE)
set(B TRUE)
set(C TRUE)
set(condition "(A AND B) OR C")

file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/eval.cmake "
  if (${condition})
    message(STATUS TRUE)
  else()
    message(STATUS FALSE)
  endif()"
)

include(${CMAKE_CURRENT_BINARY_DIR}/eval.cmake)

Отложенные вызовы

cmake_language(DEFER <options>... CALL <command> [<arg>...])

Планирует вызов указанной <command> с заданными аргументами (если таковые имеются) на более позднее время. По умолчанию отложенные вызовы выполняются так, как будто они написаны в конце файла CMakeLists.txt текущей директории, за исключением того, что они выполняются даже после вызова return(). Ссылки на переменные в аргументах вычисляются в момент выполнения отложенного вызова.

Доступны следующие опции:

DIRECTORY <dir>

Планирует вызов для конца указанной директории вместо текущей. <dir> может ссылаться как на исходную директорию, так и на соответствующую двоичную директорию. Относительные пути обрабатываются как относительные к текущей исходной директории.

Указанная директория должна быть известна CMake, являясь либо корневой директорией, либо добавленной с помощью add_subdirectory(). Кроме того, указанная директория не должна ещё быть обработана. Это означает, что она может быть текущей директорией или одной из её предков.

ID <id>

Указывает идентификатор для отложенного вызова. <id> не может быть пустым и не может начинаться с заглавной буквы A-Z. <id> может начинаться с подчёркивания (_) только если он был сгенерирован автоматически предыдущим вызовом, который использовал ID_VAR для получения идентификатора.

ID_VAR <var>

Указывает переменную, в которой будет храниться идентификатор отложенного вызова. Если ID <id> не указана, будет сгенерирован новый идентификатор, и сгенерированный идентификатор будет начинаться с подчёркивания (_).

Список запланированных отложенных вызовов можно получить:

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL_IDS <var>)

Это сохранит в <var> список отложенных идентификаторов вызовов, разделённых точкой с запятой. Идентификаторы предназначены для области директории, в которую планируются вызовы (т.е. где они будут выполнены), что может отличаться от области, в которой они были созданы. Опция DIRECTORY может использоваться для указания области, для которой необходимо получить идентификаторы вызовов. Если эта опция не указана, будут возвращены идентификаторы вызовов текущей области директории.

Подробности о конкретном вызове можно получить по его идентификатору:

cmake_language(DEFER [DIRECTORY <dir>] GET_CALL <id> <var>)

Это сохранит в <var> список, разделённый точкой с запятой, в котором первый элемент — имя вызываемой команды, а оставшиеся элементы — её невычисленные аргументы (любые символы ; включены буквально и не могут быть отличимы от нескольких аргументов). Если несколько вызовов запланированы с тем же идентификатором, это возвращает первый из них. Если в указанной DIRECTORY области (или текущей области директории, если опция DIRECTORY не указана) нет запланированного вызова с данным идентификатором, в переменной будет сохранена пустая строка.

Отложенные вызовы могут быть отменены по их идентификатору:

cmake_language(DEFER [DIRECTORY <dir>] CANCEL_CALL <id>...)

Это отменяет все отложенные вызовы, соответствующие любому из указанных идентификаторов в указанной DIRECTORY области (или текущей области директории, если опция DIRECTORY не указана). Неизвестные идентификаторы игнорируются.

Примеры отложенных вызовов

Например, код:

cmake_language(DEFER CALL message "${deferred_message}")
cmake_language(DEFER ID_VAR id CALL message "Canceled Message")
cmake_language(DEFER CANCEL_CALL ${id})
message("Immediate Message")
set(deferred_message "Deferred Message")

выводит:

Immediate Message
Deferred Message

Canceled Message не выводится, поскольку его команда отменена. Ссылка на переменную deferred_message не вычисляется до момента вызова, поэтому она может быть установлена после планирования отложенного вызова.

Для немедленного вычисления ссылок на переменные при планировании отложенного вызова, оберните его с помощью cmake_language(EVAL). Однако обратите внимание, что аргументы будут повторно вычислены в отложенном вызове, хотя это можно избежать с помощью скобочных аргументов. Например:

set(deferred_message "Deferred Message 1")
set(re_evaluated [[${deferred_message}]])
cmake_language(EVAL CODE "
  cmake_language(DEFER CALL message [[${deferred_message}]])
  cmake_language(DEFER CALL message \"${re_evaluated}\")
")
message("Immediate Message")
set(deferred_message "Deferred Message 2")

также выводит:

Immediate Message
Deferred Message 1
Deferred Message 2

Поставщики зависимостей

cmake_language(SET_DEPENDENCY_PROVIDER <command> SUPPORTED_METHODS <methods>...)

Когда выполняется вызов find_package() или FetchContent_MakeAvailable(), вызов может быть перенаправлен поставщику зависимостей, который затем имеет возможность выполнить запрос. Если запрос относится к одной из <methods> указанных при настройке поставщика, CMake вызывает метод <command> поставщика с набором аргументов, специфичных для метода. Если поставщик не выполняет запрос, или если поставщик не поддерживает метод запроса, или поставщик не установлен, используется встроенная реализация find_package() или FetchContent_MakeAvailable() для выполнения запроса обычным способом.

Для <methods> при настройке поставщика можно указать один или несколько из следующих значений:

FIND_PACKAGE

Команда поставщика принимает запросы find_package().

FETCHCONTENT_MAKEAVAILABLE_SERIAL

Команда поставщика принимает запросы FetchContent_MakeAvailable(). Она ожидает, что каждая зависимость будет передана команде поставщика по одной, а не весь список сразу.

В любой момент времени может быть установлен только один поставщик. Если поставщик уже установлен при вызове cmake_language(SET_DEPENDENCY_PROVIDER), новый поставщик заменяет ранее установленный. Указанный <command> должен уже существовать при вызове cmake_language(SET_DEPENDENCY_PROVIDER). В качестве специального случая, предоставление пустой строки для <command> и отсутствие <methods> отменяет ранее установленного поставщика.

Поставщик зависимостей может быть установлен только во время обработки одного из файлов, указанных в переменной CMAKE_PROJECT_TOP_LEVEL_INCLUDES. Таким образом, поставщики зависимостей могут быть установлены только в рамках первого вызова project(). Вызов cmake_language(SET_DEPENDENCY_PROVIDER) вне этого контекста приведет к ошибке.

Добавлена в версии 3.30: Глобальное свойство PROPAGATE_TOP_LEVEL_INCLUDES_TO_TRY_COMPILE может быть установлено, если поставщик зависимостей также должен быть включен в вызовах try_compile() для всего проекта.

Примечание

Выбор поставщика зависимостей всегда должен быть под контролем пользователя. Для удобства проект может предоставить файл, который пользователи могут перечислить в переменной CMAKE_PROJECT_TOP_LEVEL_INCLUDES, но использование такого файла всегда должно быть выбором пользователя.

Команды поставщиков

Поставщики определяют единственную <command> для принятия запросов. Имя команды должно быть специфичным для данного поставщика, а не чрезмерно общим, которое может использовать другой поставщик. Рекомендуемая форма xxx_provide_dependency(), где xxx — часть, специфичная для поставщика (например, vcpkg_provide_dependency(), conan_provide_dependency(), ourcompany_provide_dependency() и т.д.).

xxx_provide_dependency(<method> [<method-specific-args>...])

Так как некоторые методы ожидают, что определённые переменные будут установлены в вызывающей области, команда поставщика, как правило, реализуется как макрос, а не как функция. Это гарантирует, что она не вводит новую область переменных.

Аргументы, которые CMake передает поставщику зависимостей, зависят от типа запроса. Первый аргумент всегда — метод, и он может быть только одним из <methods>, указанных при настройке поставщика.

FIND_PACKAGE

<method-specific-args> будут содержать все, что было передано в вызов find_package(), который запросил зависимость. Таким образом, первый из <method-specific-args> всегда будет именем зависимости. Имена зависимостей чувствительны к регистру для этого метода, так как find_package() также обрабатывает их как чувствительные к регистру.

Если команда поставщика удовлетворяет запрос, она должна установить ту же переменную, которую ожидает find_package(). Для зависимости с именем depName, поставщик должен установить depName_FOUND в значение true, если запрос был удовлетворён. Если поставщик возвращается без установки этой переменной, CMake посчитает, что запрос не был удовлетворен, и вернётся к встроенной реализации.

Если поставщику необходимо вызвать встроенную реализацию find_package() как часть обработки, он может сделать это, включив ключевое слово BYPASS_PROVIDER в качестве одного из аргументов.

FETCHCONTENT_MAKEAVAILABLE_SERIAL

<method-specific-args> будут содержать все, что было передано в вызов FetchContent_Declare(), соответствующий запрошенной зависимости, за исключением следующих моментов:

• Если SOURCE_DIR или BINARY_DIR не были частью исходных аргументов, они будут добавлены со своими значениями по умолчанию.
• Если FETCHCONTENT_TRY_FIND_PACKAGE_MODE установлено в значение NEVER, любые FIND_PACKAGE_ARGS будут опущены.
• Ключевое слово OVERRIDE_FIND_PACKAGE всегда опускается.

Первый из <method-specific-args> всегда будет именем зависимости. Имена зависимостей нечувствительны к регистру для этого метода, так как FetchContent также обрабатывает их как нечувствительные к регистру.

Если поставщик удовлетворяет запрос, он должен вызвать FetchContent_SetPopulated(), передав имя зависимости в качестве первого аргумента. Аргументы SOURCE_DIR и BINARY_DIR для этой команды должны быть указаны только в том случае, если поставщик предоставляет директории исходного кода и сборки зависимости точно так же, как встроенная команда FetchContent_MakeAvailable().

Если поставщик возвращается без вызова FetchContent_SetPopulated() для указанной зависимости, CMake посчитает, что запрос не был удовлетворён, и вернётся к встроенной реализации.

Обратите внимание, что пустые аргументы могут быть значимыми для этого метода (например, пустая строка после ключевого слова GIT_SUBMODULES). Поэтому, если эти аргументы передаются другой команде, необходимо принять дополнительные меры, чтобы избежать их неявного удаления.

Если FETCHCONTENT_SOURCE_DIR_<uppercaseDepName> установлено, тогда поставщик зависимостей никогда не увидит запросы для зависимости <depName> для этого метода. Когда пользователь устанавливает такую переменную, он явно переопределяет источник получения этой зависимости и берёт на себя ответственность за то, что его переопределённая версия соответствует всем требованиям к этой зависимости и совместима с тем, что ещё используется в проекте. В зависимости от значения FETCHCONTENT_TRY_FIND_PACKAGE_MODE и того, был ли задан параметр OVERRIDE_FIND_PACKAGE в FetchContent_Declare(), установка FETCHCONTENT_SOURCE_DIR_<uppercaseDepName> также может предотвратить получение поставщиком запросов для вызова find_package(depName).

Примеры поставщиков

В первом примере перехватываются только вызовы find_package(). Команда поставщика запускает внешнюю утилиту, которая копирует соответствующие артефакты в каталог, специфичный для поставщика, если эта утилита знает о зависимости. Затем она полагается на встроенную реализацию для поиска этих артефактов. Вызовы FetchContent_MakeAvailable() не будут проходить через поставщика.

# Always ensure we have the policy settings this provider expects
cmake_minimum_required(VERSION 3.24)

set(MYCOMP_PROVIDER_INSTALL_DIR ${CMAKE_BINARY_DIR}/mycomp_packages
  CACHE PATH "The directory this provider installs packages to"
)
# Tell the built-in implementation to look in our area first, unless
# the find_package() call uses NO_..._PATH options to exclude it
list(APPEND CMAKE_MODULE_PATH ${MYCOMP_PROVIDER_INSTALL_DIR}/cmake)
list(APPEND CMAKE_PREFIX_PATH ${MYCOMP_PROVIDER_INSTALL_DIR})

macro(mycomp_provide_dependency method package_name)
  execute_process(
    COMMAND some_tool ${package_name} --installdir ${MYCOMP_PROVIDER_INSTALL_DIR}
    COMMAND_ERROR_IS_FATAL ANY
  )
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

Пользователь, как правило, использует вышеуказанный файл следующим образом:

cmake -DCMAKE_PROJECT_TOP_LEVEL_INCLUDES=/path/to/mycomp_provider.cmake ...

Следующий пример демонстрирует поставщика, принимающего оба метода, но обрабатывающего только одну конкретную зависимость. Он обеспечивает предоставление Google Test с помощью FetchContent, но оставляет все другие зависимости для выполнения встроенной реализацией CMake. Он принимает несколько разных имён, что демонстрирует один способ обойти проекты, которые жестко закодировали необычный или нежелательный способ добавления этой конкретной зависимости в сборку. Пример также демонстрирует, как использовать команду list() для сохранения переменных, которые могут быть перезаписаны вызовом FetchContent_MakeAvailable().

cmake_minimum_required(VERSION 3.24)

# Because we declare this very early, it will take precedence over any
# details the project might declare later for the same thing
include(FetchContent)
FetchContent_Declare(
  googletest
  GIT_REPOSITORY https://github.com/google/googletest.git
  GIT_TAG        e2239ee6043f73722e7aa812a459f54a28552929 # release-1.11.0
)

# Both FIND_PACKAGE and FETCHCONTENT_MAKEAVAILABLE_SERIAL methods provide
# the package or dependency name as the first method-specific argument.
macro(mycomp_provide_dependency method dep_name)
  if("${dep_name}" MATCHES "^(gtest|googletest)$")
    # Save our current command arguments in case we are called recursively
    list(APPEND mycomp_provider_args ${method} ${dep_name})

    # This will forward to the built-in FetchContent implementation,
    # which detects a recursive call for the same thing and avoids calling
    # the provider again if dep_name is the same as the current call.
    FetchContent_MakeAvailable(googletest)

    # Restore our command arguments
    list(POP_BACK mycomp_provider_args dep_name method)

    # Tell the caller we fulfilled the request
    if("${method}" STREQUAL "FIND_PACKAGE")
      # We need to set this if we got here from a find_package() call
      # since we used a different method to fulfill the request.
      # This example assumes projects only use the gtest targets,
      # not any of the variables the FindGTest module may define.
      set(${dep_name}_FOUND TRUE)
    elseif(NOT "${dep_name}" STREQUAL "googletest")
      # We used the same method, but were given a different name to the
      # one we populated with. Tell the caller about the name it used.
      FetchContent_SetPopulated(${dep_name}
        SOURCE_DIR "${googletest_SOURCE_DIR}"
        BINARY_DIR "${googletest_BINARY_DIR}"
      )
    endif()
  endif()
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS
    FIND_PACKAGE
    FETCHCONTENT_MAKEAVAILABLE_SERIAL
)

Последний пример демонстрирует, как изменить аргументы вызова find_package(). Он принудительно добавляет ключевое слово QUIET ко всем таким вызовам. Он использует ключевое слово BYPASS_PROVIDER для предотвращения рекурсивного вызова команды поставщика для той же зависимости.

cmake_minimum_required(VERSION 3.24)

macro(mycomp_provide_dependency method)
  find_package(${ARGN} BYPASS_PROVIDER QUIET)
endmacro()

cmake_language(
  SET_DEPENDENCY_PROVIDER mycomp_provide_dependency
  SUPPORTED_METHODS FIND_PACKAGE
)

Получение текущего уровня ведения журнала сообщений

cmake_language(GET_MESSAGE_LOG_LEVEL <output_variable>)

Записывает текущий уровень ведения журнала message() в заданный <output_variable>.

См. message() для возможных уровней ведения журнала.

Текущий уровень ведения журнала сообщений можно установить, используя параметр командной строки --log-level программы cmake(1) или с помощью переменной CMAKE_MESSAGE_LOG_LEVEL.

Если установлен и параметр командной строки, и переменная, имеет приоритет параметр командной строки. Если ни тот, ни другой не установлены, возвращается уровень ведения журнала по умолчанию.

Завершение сценариев

cmake_language(EXIT <exit-code>)

Завершает текущий сценарий cmake -P и завершает выполнение с кодом <exit-code>.

Эта команда работает только в режиме обработки сценариев. Если используется вне этого контекста, будет выведено сообщение об ошибке.

Значение <exit-code> должно быть неотрицательным. Если <exit-code> отрицательно, поведение не определено (например, в Windows код ошибки -1 становится 0xffffffff, а в Linux — 255). Коды выхода выше 255 могут не поддерживаться базовой оболочкой или платформой, и некоторые оболочки могут интерпретировать значения выше 125 специальным образом. Поэтому рекомендуется указывать только <exit-code> в диапазоне от 0 до 125.