message

Записать сообщение.

Синтаксис

General messages
  message([<mode>] "message text" ...)

Reporting checks
  message(<checkState> "message text" ...)

Configure Log
  message(CONFIGURE_LOG <text>...)

Общие сообщения

message([<mode>] "message text" ...)

Записать указанный текст сообщения в журнал. Если задано более одной строки сообщения, они конкатенируются в одно сообщение без разделителей между строками.

Необязательное ключевое слово <mode> определяет тип сообщения, что влияет на способ обработки сообщения:

FATAL_ERROR

Ошибка CMake, остановить обработку и генерацию.

Исполняемый файл cmake(1) вернёт ненулевое значение выхода.

SEND_ERROR

Ошибка CMake, продолжить обработку, но пропустить генерацию.

WARNING

Предупреждение CMake, продолжить обработку.

AUTHOR_WARNING

Предупреждение CMake (dev), продолжить обработку.

DEPRECATION

Ошибка или предупреждение об устаревании CMake, если переменная CMAKE_ERROR_DEPRECATED или CMAKE_WARN_DEPRECATED соответственно включена, в противном случае сообщение не выводится.

(none) or NOTICE

Важное сообщение, выводимое в stderr, чтобы привлечь внимание пользователя.

STATUS

Основные интересные сообщения, которые могут заинтересовать пользователей проекта. В идеале они должны быть краткими, не более одной строки, но при этом информативными.

VERBOSE

Подробные информационные сообщения, предназначенные для пользователей проекта. Эти сообщения должны предоставлять дополнительную информацию, которая в большинстве случаев не будет интересна, но может быть полезна разработчикам проекта, когда они хотят более глубоко понять происходящее.

DEBUG

Подробные информационные сообщения, предназначенные для разработчиков, работающих над самим проектом, а не для пользователей, которые просто хотят его собрать. Эти сообщения обычно не будут представлять интереса для других пользователей, собирающих проект, и часто будут тесно связаны с внутренними деталями реализации.

TRACE

Детализированные сообщения с очень низкоуровневыми подробностями реализации. Сообщения, использующие этот уровень журнала, обычно являются временными и должны быть удалены до выпуска проекта, создания пакетов и т. д.

Инструмент CMake отображает сообщения уровней STATUS до TRACE в stdout с сообщением, предваряемым двумя дефисами и пробелом. Все остальные типы сообщений отправляются в stderr и не предваряются дефисами. CMake GUI отображает все сообщения в области своего журнала. curses interface отображает сообщения уровней STATUS до TRACE по одному в строке состояния и другие сообщения в интерактивном всплывающем окне. Команда командной строки --log-level для каждого из этих инструментов может использоваться для управления отображаемыми сообщениями.

Текст сообщения CMake Warning и Error отображается с помощью простого языка разметки. Неотступленный текст форматируется в параграфах с переходом на новую строку, ограниченных переводами строк. Отступленный текст считается предварительно отформатированным.

Отчёт о проверках

Общая схема в выводе CMake — это сообщение, указывающее на начало какой-либо проверки, за которым следует другое сообщение, сообщающее результат этой проверки. Например:

message(STATUS "Looking for someheader.h")
#... do the checks, set checkSuccess with the result
if(checkSuccess)
  message(STATUS "Looking for someheader.h - found")
else()
  message(STATUS "Looking for someheader.h - not found")
endif()

Это можно более надёжно и удобно выразить с помощью ключевой формы команды CHECK_... message():

message(<checkState> "message" ...)

где <checkState> должно быть одним из следующих:

CHECK_START

Запись краткого сообщения о проверке, которая будет выполняться.

CHECK_PASS

Запись успешного результата проверки.

CHECK_FAIL

Запись неуспешного результата проверки.

При записи результата проверки команда повторяет сообщение из последней начатой проверки, для которой ещё не был сообщен результат, затем отделяющие символы и затем текст сообщения, предоставленный после ключевых слов CHECK_PASS или CHECK_FAIL. Сообщения о проверках всегда отображаются на уровне журнала STATUS.

Проверки могут быть вложены и каждое CHECK_START должно иметь ровно одно соответствующее CHECK_PASS или CHECK_FAIL. Переменная CMAKE_MESSAGE_INDENT также может использоваться для добавления отступов к вложенным проверкам, если это необходимо. Например:

message(CHECK_START "Finding my things")
list(APPEND CMAKE_MESSAGE_INDENT "  ")
unset(missingComponents)

message(CHECK_START "Finding partA")
# ... do check, assume we find A
message(CHECK_PASS "found")

message(CHECK_START "Finding partB")
# ... do check, assume we don't find B
list(APPEND missingComponents B)
message(CHECK_FAIL "not found")

list(POP_BACK CMAKE_MESSAGE_INDENT)
if(missingComponents)
  message(CHECK_FAIL "missing components: ${missingComponents}")
else()
  message(CHECK_PASS "all components found")
endif()

Вывод из приведённого выше примера будет выглядеть примерно так:

-- Finding my things
--   Finding partA
--   Finding partA - found
--   Finding partB
--   Finding partB - not found
-- Finding my things - missing components: B

Журнал конфигурации

message(CONFIGURE_LOG <text>...)

Записывает событие сообщения конфигурации configure-log с указанным <text>. По соглашению, если текст содержит более одной строки, первая строка должна быть сводкой события.

Этот режим предназначен для записи деталей проверки системы или других одноразовых операций, защищенных элементом кэша, но которые не выполняются с помощью try_compile() или try_run(), которые автоматически записывают свои подробности. Проекты должны избегать его вызова каждый раз при запуске CMake. Например:

if (NOT DEFINED MY_CHECK_RESULT)
  # Print check summary in configure output.
  message(CHECK_START "My Check")

  # ... perform system inspection, e.g., with execute_process ...

  # Cache the result so we do not run the check again.
  set(MY_CHECK_RESULT "${MY_CHECK_RESULT}" CACHE INTERNAL "My Check")

  # Record the check details in the cmake-configure-log.
  message(CONFIGURE_LOG
    "My Check Result: ${MY_CHECK_RESULT}\n"
    "${details}"
  )

  # Print check result in configure output.
  if(MY_CHECK_RESULT)
    message(CHECK_PASS "passed")
  else()
    message(CHECK_FAIL "failed")
  endif()
endif()

Если в данный момент никакой проект не настраивается, например, в режиме сценариев cmake -P, эта команда ничего не делает.

См. также

• cmake_language(GET_MESSAGE_LOG_LEVEL)