Application.cfc

Пример очень простого скрипта

component {
    this.name = "AppName";
    this.datasource = "AppDataSource";
    this.sessionManagement = true;

    function onApplicationStart() {
        application.config="xyz";
    }

 }

В этом примере используются getCurrentTemplatePath и getDirectoryFromPath, чтобы динамически получить каталог, в котором находится текущий файл Application.cfc, а затем определить несколько отображений относительно него. Не используйте expandPath в Application.cfc, поскольку путь будет рассчитываться относительно пути текущего шаблона, а не пути к Application.cfc.

component {
    this.name = "AppName";
    this.appBasePath = getDirectoryFromPath(getCurrentTemplatePath());
    this.mappings["/components"] = this.appBasePath & "components";
    this.mappings["/frameworks"] = this.appBasePath & "frameworks";

}

Для создания канала WebSocket достаточно указать атрибут name. Также для канала можно задать пользовательский CFC-обработчик канала. Если он не указан, вызывается ChannelListener.cfc из каталога wwwroot/CFIDE/websocket (Использование обработчиков каналов).Примечание: Хотя можно использовать любое количество подканалов, указывать их не нужно, так как они создаются динамически (с помощью точечной нотации). Чтобы подписаться на каналы, создайте объект WebSocket с помощью тега cfwebsocket в шаблоне CFM.

component {
    this.name = "AppName";
    this.wschannels = [{name=channelName, cfclistener=channel_listener_CFC}];
}

В этом примере показано, как сопоставлять каталоги, расположенные уровнем выше Application.cfc (корня веб-сайта), а также как обрабатывать приложение, которое потребуется развернуть в нескольких операционных системах (Mac, Unix, Windows) из-за различий в средах разработки. С помощью Find определяется, какие разделители путей использовать — прямые или обратные косые черты, а с помощью ListDeleteAt из пути удаляется текущий каталог. Затем на основе этой информации можно сформировать пути для отображений и пользовательских тегов.

component {
    this.name = "AppName";
    this.currentPath = getDirectoryFromPath( getCurrentTemplatePath() );
    this.delim = find("/", this.currentPath) ? "/" : "\";
    this.basePath = listDeleteAt(this.currentPath, listLen(this.currentPath, this.delim), this.delim);
    this.mappings["/components"] = this.basePath & this.delim & "components";
    this.mappings["/frameworks"] = this.basePath & this.delim & "frameworks";
    this.customtagpaths = this.basePath & this.delim & "customtags";

}