cfoutput

Выводит данные, которые могут содержать результаты обработки переменных и функций CFML. Атрибут query можно использовать для перебора набора результатов запроса к базе данных.

<cfoutput>

writeOutput()

Lucee

BL 1.0.0+

Справочник по атрибутам

query query

Имя cfquery, из которого извлекаются данные для секции вывода.

group string

Столбец запроса, используемый для группировки наборов записей. Удаляет смежные дубликаты строк, если данные отсортированы. Используйте, если получен набор записей, упорядоченный по одному или нескольким столбцам запроса. Например, если набор записей упорядочен по "Customer_ID" в теге cfquery, выходные данные можно сгруппировать по "Customer_ID".

groupcasesensitive boolean

Учитывать ли регистр при группировке строк.

Значения:

true
false

startrow numeric

Строка, с которой начинается вывод. Учитывается только при установленном атрибуте query. Этот атрибут вместе с maxrows можно использовать для разбиения на страницы.

maxrows numeric

Максимальное количество отображаемых строк. Учитывается только при установленном атрибуте query.

encodefor string

CF 2016+ Lucee 5.1+ При установке этого атрибута ко всем переменным применяется кодировщик для защиты от XSS. Например, если указать html, каждая переменная будет обернута вызовом функции encodeForHTML.

Значения:

html
htmlattribute
javascript
css
xml
xmlattribute
url
xpath
ldap
dn

Совместимость

BoxLang:

Версия 1.0.0+ <bx:output> в BoxLang

Примеры
Примеры кода с использованием тега cfoutput

Пример простого тега

<cfoutput>Some text and a #encodeForHTML(variable)#</cfoutput>

Перебор запроса

Перебирает каждую строку указанного запроса и выводит результат.

<cfoutput query="news">
    <h2>#encodeForHTML(news.headline)#</h2>
    <p>#encodeForHTML(news.byline)#</p>
</cfoutput>

Перебор диапазона строк запроса

Перебирает 10 строк указанного запроса, начиная со строки 5, и выводит результат.

<cfoutput query="news" startrow="5" maxrows="10">
    <h2>#encodeForHTML(news.headline)#</h2>
    <p>#encodeForHTML(news.byline)#</p>
</cfoutput>

Использование атрибута encodeFor

CF 2016+ Lucee 5.1+ При указании encodefor="html" каждая переменная кодируется с помощью функции encodeForHTML перед выводом.

<cfoutput query="news" encodefor="html">
    <h2>#news.headline#</h2>
    <p>#news.byline#</p>
</cfoutput>

Использование атрибута group

Создает фиктивный запрос food со столбцами name и type. Затем выводит продукты питания, сгруппировав их по типу.

<cfset food = queryNew("name,type",
    "varchar,varchar",
    [ {name:"Apple",type:"Fruit"}, 
      {name:"Orange",type:"Fruit"}, 
      {name:"Chicken",type:"Meat"} ])>
<cfoutput query="food" group="type">
    <h2>#type#</h2>
    <ul>
      <cfoutput><li>#name#</li></cfoutput>
    </ul>
</cfoutput>

© 2012–present Foundeo, Inc. and the CFDocs contributors.
Licensed under the MIT License.
ColdFusion is a trademark of Adobe Systems Incorporated.
https://cfdocs.org/cfoutput