Spec-Zone.ru › Elixir 1.13

NaiveDateTime

Структура NaiveDateTime (без часового пояса) и функции.

Структура NaiveDateTime содержит поля year, month, day, hour, minute, second, microsecond и calendar. Новые значения naive datetimes можно создать с помощью функций new/2 и new/8 или используя сигил ~N (см. Kernel.sigil_N/2):

iex> ~N[2000-01-01 23:00:07]
~N[2000-01-01 23:00:07]

К полям даты и времени в структуре можно получить доступ напрямую:

iex> naive = ~N[2000-01-01 23:00:07]
iex> naive.year
2000
iex> naive.second
7

Мы называем их "naive", потому что эта структура даты и времени не имеет часового пояса. Это означает, что эта дата и время могут не существовать в некоторых частях мира, даже если она валидная.

Например, когда в регионе применяются изменения летнего времени, часы обычно переходят вперёд или назад на один час. Это означает, что некоторые даты и времена никогда не происходят или могут происходить более одного раза. Поскольку NaiveDateTime не проверяется на соответствие часовому поясу, такие ошибки останутся незамеченными.

Разработчики должны избегать непосредственного создания структур NaiveDateTime и вместо этого полагаться на функции, предоставляемые этим модулем, а также на функции сторонних библиотек календарей.

Сравнение naive date times

Сравнения в Elixir с использованием ==/2, >/2, </2 и аналогичных основаны на структуре NaiveDateTime полей. Для правильного сравнения naive date times используйте функцию compare/2.

Использование эпох

Функции add/3 и diff/3 можно использовать для вычислений с датами и временем или получения количества секунд между моментами. Например, если есть интерес вычислить количество секунд от Unix эпохи (1970-01-01 00:00:00):

iex> NaiveDateTime.diff(~N[2010-04-17 14:00:00], ~N[1970-01-01 00:00:00])
1271512800

iex> NaiveDateTime.add(~N[1970-01-01 00:00:00], 1_271_512_800)
~N[2010-04-17 14:00:00]

Эти функции оптимизированы для работы с общими эпохами, такими как Unix эпоха выше или эпоха Григорианского календаря (0000-01-01 00:00:00).

Резюме

Типы

t()

Функции

add(naive_datetime, amount_to_add, unit \\ :second)

Добавляет заданное количество времени к NaiveDateTime.

compare(naive_datetime1, naive_datetime2)

Сравнивает две структуры NaiveDateTime.

convert!(naive_datetime, calendar)

Преобразует данную naive_datetime из одного календаря в другой.

convert(naive_datetime, calendar)

Преобразует данную naive_datetime из одного календаря в другой.

diff(naive_datetime1, naive_datetime2, unit \\ :second)

Вычитает naive_datetime2 из naive_datetime1.

from_erl!(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

Преобразует кортеж Erlang datetime в структуру NaiveDateTime.

from_erl(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

Преобразует кортеж Erlang datetime в структуру NaiveDateTime.

from_gregorian_seconds(seconds, arg \\ {0, 0}, calendar \\ Calendar.ISO)

Преобразует количество секунд gregorian в структуру NaiveDateTime.

from_iso8601!(string, calendar \\ Calendar.ISO)

Парсит расширенный формат "Дата и время суток", описанный в ISO 8601:2019.

from_iso8601(string, calendar \\ Calendar.ISO)

Парсит расширенный формат "Дата и время суток", описанный в ISO 8601:2019.

local_now(calendar \\ Calendar.ISO)

Возвращает "местное время" для машины, на которой выполняется программа Elixir.

new!(date, time)

Создаёт naive datetime из структур date и time.

new!(year, month, day, hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

Создаёт новую naive datetime в формате ISO.

new(date, time)

Создаёт naive datetime из структур date и time.

new(year, month, day, hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

Создаёт новую naive datetime в формате ISO.

to_date(map)

Преобразует NaiveDateTime в Date.

to_erl(naive_datetime)

Преобразует структуру NaiveDateTime в кортеж Erlang datetime.

to_gregorian_seconds(map)

Преобразует структуру NaiveDateTime в количество секунд и микросекунд gregorian.

to_iso8601(naive_datetime, format \\ :extended)

Преобразует данную naive datetime в ISO 8601:2019.

to_string(naive_datetime)

Преобразует данную naive datetime в строку в соответствии с её календарём.

to_time(map)

Преобразует NaiveDateTime в Time.

truncate(naive_datetime, precision)

Возвращает данную naive datetime с полем microsecond, усечённым до заданной точности (:microsecond, :millisecond или :second).

utc_now(calendar \\ Calendar.ISO)

Возвращает текущую naive datetime в UTC.

Типы

t()Исходный код 

@type t() :: %NaiveDateTime{
  calendar: Calendar.calendar(),
  day: Calendar.day(),
  hour: Calendar.hour(),
  microsecond: Calendar.microsecond(),
  minute: Calendar.minute(),
  month: Calendar.month(),
  second: Calendar.second(),
  year: Calendar.year()
}

Функции

add(naive_datetime, amount_to_add, unit \\ :second)Source 

@spec add(Calendar.naive_datetime(), integer(), System.time_unit()) :: t()

Добавляет указанное количество времени к NaiveDateTime.

Принимает amount_to_add в любом unit из System.time_unit/0. Отрицательные значения перемещают во времени назад.

Примеры 

# adds seconds by default
iex> NaiveDateTime.add(~N[2014-10-02 00:29:10], 2)
~N[2014-10-02 00:29:12]

# accepts negative offsets
iex> NaiveDateTime.add(~N[2014-10-02 00:29:10], -2)
~N[2014-10-02 00:29:08]

# can work with other units
iex> NaiveDateTime.add(~N[2014-10-02 00:29:10], 2_000, :millisecond)
~N[2014-10-02 00:29:12]

# keeps the same precision
iex> NaiveDateTime.add(~N[2014-10-02 00:29:10.021], 21, :second)
~N[2014-10-02 00:29:31.021]

# changes below the precision will not be visible
iex> hidden = NaiveDateTime.add(~N[2014-10-02 00:29:10], 21, :millisecond)
iex> hidden.microsecond # ~N[2014-10-02 00:29:10]
{21000, 0}

# from Gregorian seconds
iex> NaiveDateTime.add(~N[0000-01-01 00:00:00], 63_579_428_950)
~N[2014-10-02 00:29:10]

Передача DateTime автоматически преобразует её в NaiveDateTime, отбрасывая информацию о часовом поясе:

iex> dt = %DateTime{year: 2000, month: 2, day: 29, zone_abbr: "CET",
...>                hour: 23, minute: 0, second: 7, microsecond: {0, 0},
...>                utc_offset: 3600, std_offset: 0, time_zone: "Europe/Warsaw"}
iex> NaiveDateTime.add(dt, 21, :second)
~N[2000-02-29 23:00:28]

compare(naive_datetime1, naive_datetime2)Source 

@spec compare(Calendar.naive_datetime(), Calendar.naive_datetime()) :: :lt | :eq | :gt

Сравнивает две структуры NaiveDateTime.

Возвращает :gt если первая структура позже второй и :lt в противном случае. Если две структуры NaiveDateTime равны, возвращается :eq.

Примеры 

iex> NaiveDateTime.compare(~N[2016-04-16 13:30:15], ~N[2016-04-28 16:19:25])
:lt
iex> NaiveDateTime.compare(~N[2016-04-16 13:30:15.1], ~N[2016-04-16 13:30:15.01])
:gt

Эта функция также может использоваться для сравнения DateTime без информации о часовом поясе:

iex> dt = %DateTime{year: 2000, month: 2, day: 29, zone_abbr: "CET",
...>                hour: 23, minute: 0, second: 7, microsecond: {0, 0},
...>                utc_offset: 3600, std_offset: 0, time_zone: "Europe/Warsaw"}
iex> NaiveDateTime.compare(dt, ~N[2000-02-29 23:00:07])
:eq
iex> NaiveDateTime.compare(dt, ~N[2000-01-29 23:00:07])
:gt
iex> NaiveDateTime.compare(dt, ~N[2000-03-29 23:00:07])
:lt

convert!(naive_datetime, calendar)Source 

@spec convert!(Calendar.naive_datetime(), Calendar.calendar()) :: t()

Преобразует данное naive_datetime из одного календаря в другой.

Если не удаётся однозначно преобразовать между календарями (см. Calendar.compatible_calendars?/2), генерируется ArgumentError.

Примеры

Представьте, что кто-то реализовал Calendar.Holocene, календарь, основанный на григорианском календаре, который добавляет ровно 10 000 лет к текущему григорианскому году:

iex> NaiveDateTime.convert!(~N[2000-01-01 13:30:15], Calendar.Holocene)
%NaiveDateTime{calendar: Calendar.Holocene, year: 12000, month: 1, day: 1,
               hour: 13, minute: 30, second: 15, microsecond: {0, 0}}

convert(naive_datetime, calendar)Source 

@spec convert(Calendar.naive_datetime(), Calendar.calendar()) ::
  {:ok, t()} | {:error, :incompatible_calendars}

Преобразует данное naive_datetime из одного календаря в другой.

Если не удаётся однозначно преобразовать между календарями (см. Calendar.compatible_calendars?/2), возвращается кортеж {:error, :incompatible_calendars}.

Примеры

Представьте, что кто-то реализовал Calendar.Holocene, календарь, основанный на григорианском календаре, который добавляет ровно 10 000 лет к текущему григорианскому году:

iex> NaiveDateTime.convert(~N[2000-01-01 13:30:15], Calendar.Holocene)
{:ok, %NaiveDateTime{calendar: Calendar.Holocene, year: 12000, month: 1, day: 1,
                     hour: 13, minute: 30, second: 15, microsecond: {0, 0}}}

diff(naive_datetime1, naive_datetime2, unit \\ :second)Source 

@spec diff(Calendar.naive_datetime(), Calendar.naive_datetime(), System.time_unit()) ::
  integer()

Вычитает naive_datetime2 из naive_datetime1.

Результат может быть возвращён в любом unit из System.time_unit/0.

Эта функция возвращает разницу во времени в секундах, измеренную согласно Calendar.ISO.

Примеры 

iex> NaiveDateTime.diff(~N[2014-10-02 00:29:12], ~N[2014-10-02 00:29:10])
2
iex> NaiveDateTime.diff(~N[2014-10-02 00:29:12], ~N[2014-10-02 00:29:10], :microsecond)
2_000_000
iex> NaiveDateTime.diff(~N[2014-10-02 00:29:10.042], ~N[2014-10-02 00:29:10.021], :millisecond)
21
iex> NaiveDateTime.diff(~N[2014-10-02 00:29:10], ~N[2014-10-02 00:29:12])
-2
iex> NaiveDateTime.diff(~N[-0001-10-02 00:29:10], ~N[-0001-10-02 00:29:12])
-2

# to Gregorian seconds
iex> NaiveDateTime.diff(~N[2014-10-02 00:29:10], ~N[0000-01-01 00:00:00])
63579428950

from_erl!(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)Source 

@spec from_erl!(:calendar.datetime(), Calendar.microsecond(), Calendar.calendar()) ::
  t()

Преобразует кортеж Erlang datetime в структуру NaiveDateTime.

Вызывает исключение, если datetime некорректен. Попытка преобразования некорректной даты ISO-календаря приведёт к ошибке.

Примеры 

iex> NaiveDateTime.from_erl!({{2000, 1, 1}, {13, 30, 15}})
~N[2000-01-01 13:30:15]
iex> NaiveDateTime.from_erl!({{2000, 1, 1}, {13, 30, 15}}, {5000, 3})
~N[2000-01-01 13:30:15.005]
iex> NaiveDateTime.from_erl!({{2000, 13, 1}, {13, 30, 15}})
** (ArgumentError) cannot convert {{2000, 13, 1}, {13, 30, 15}} to naive datetime, reason: :invalid_date

from_erl(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)Source 

@spec from_erl(:calendar.datetime(), Calendar.microsecond(), Calendar.calendar()) ::
  {:ok, t()} | {:error, atom()}

Преобразует кортеж Erlang datetime в структуру NaiveDateTime.

Попытка преобразования некорректной даты ISO-календаря приведёт к ошибке.

Примеры 

iex> NaiveDateTime.from_erl({{2000, 1, 1}, {13, 30, 15}})
{:ok, ~N[2000-01-01 13:30:15]}
iex> NaiveDateTime.from_erl({{2000, 1, 1}, {13, 30, 15}}, {5000, 3})
{:ok, ~N[2000-01-01 13:30:15.005]}
iex> NaiveDateTime.from_erl({{2000, 13, 1}, {13, 30, 15}})
{:error, :invalid_date}
iex> NaiveDateTime.from_erl({{2000, 13, 1}, {13, 30, 15}})
{:error, :invalid_date}

from_gregorian_seconds(seconds, arg \\ {0, 0}, calendar \\ Calendar.ISO)Source 

@spec from_gregorian_seconds(integer(), Calendar.microsecond(), Calendar.calendar()) ::
  t()

Преобразует количество григорианских секунд в структуру NaiveDateTime.

Примеры 

iex> NaiveDateTime.from_gregorian_seconds(1)
~N[0000-01-01 00:00:01]
iex> NaiveDateTime.from_gregorian_seconds(63_755_511_991, {5000, 3})
~N[2020-05-01 00:26:31.005]
iex> NaiveDateTime.from_gregorian_seconds(-1)
~N[-0001-12-31 23:59:59]

from_iso8601!(string, calendar \\ Calendar.ISO)Source 

@spec from_iso8601!(String.t(), Calendar.calendar()) :: t()

Парсит расширенный формат "Дата и время" по ISO 8601:2019.

Вызывает исключение, если формат некорректен.

Примеры 

iex> NaiveDateTime.from_iso8601!("2015-01-23T23:50:07.123Z")
~N[2015-01-23 23:50:07.123]
iex> NaiveDateTime.from_iso8601!("2015-01-23T23:50:07,123Z")
~N[2015-01-23 23:50:07.123]
iex> NaiveDateTime.from_iso8601!("2015-01-23P23:50:07")
** (ArgumentError) cannot parse "2015-01-23P23:50:07" as naive datetime, reason: :invalid_format

from_iso8601(string, calendar \\ Calendar.ISO)Source 

@spec from_iso8601(String.t(), Calendar.calendar()) :: {:ok, t()} | {:error, atom()}

Парсит расширенный формат "Дата и время" по ISO 8601:2019.

Смещение часового пояса может быть включено в строку, но будет просто проигнорировано, так как информация о часовом поясе не включается в naive datetime.

Как указано в стандарте, разделитель "T" может быть опущен, если это необходимо, так как в этой функции нет неоднозначности.

Примечание: високосные секунды не поддерживаются встроенным Calendar.ISO.

Примеры 

iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:07")
{:ok, ~N[2015-01-23 23:50:07]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07")
{:ok, ~N[2015-01-23 23:50:07]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07Z")
{:ok, ~N[2015-01-23 23:50:07]}

iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:07.0")
{:ok, ~N[2015-01-23 23:50:07.0]}
iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:07,0123456")
{:ok, ~N[2015-01-23 23:50:07.012345]}
iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:07.0123456")
{:ok, ~N[2015-01-23 23:50:07.012345]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123Z")
{:ok, ~N[2015-01-23 23:50:07.123]}

iex> NaiveDateTime.from_iso8601("2015-01-23P23:50:07")
{:error, :invalid_format}
iex> NaiveDateTime.from_iso8601("2015:01:23 23-50-07")
{:error, :invalid_format}
iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:07A")
{:error, :invalid_format}
iex> NaiveDateTime.from_iso8601("2015-01-23 23:50:61")
{:error, :invalid_time}
iex> NaiveDateTime.from_iso8601("2015-01-32 23:50:07")
{:error, :invalid_date}

iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123+02:30")
{:ok, ~N[2015-01-23 23:50:07.123]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123+00:00")
{:ok, ~N[2015-01-23 23:50:07.123]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123-02:30")
{:ok, ~N[2015-01-23 23:50:07.123]}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123-00:00")
{:error, :invalid_format}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123-00:60")
{:error, :invalid_format}
iex> NaiveDateTime.from_iso8601("2015-01-23T23:50:07.123-24:00")
{:error, :invalid_format}

local_now(calendar \\ Calendar.ISO)Source 

@spec local_now(Calendar.calendar()) :: t()

Возвращает "локальное время" для машины, на которой работает программа Elixir.

ВНИМАНИЕ: Эта функция может привести к скрытым ошибкам. Она зависит от конфигурации часового пояса во время выполнения. Эта конфигурация может быть изменена и установлена на часовой пояс, имеющий переходы по летнему времени (перевод часов вперёд или назад).

Эта функция может быть использована для отображения текущего времени в соответствии с конфигурацией часового пояса на машине. Например, в настольной программе, отображающей часы пользователю. Для других случаев использование этой функции, вероятно, не рекомендуется.

В большинстве случаев используйте DateTime.now/2 или DateTime.utc_now/1 вместо неё.

Не включает дробные секунды.

Примеры 

iex> naive_datetime = NaiveDateTime.local_now()
iex> naive_datetime.year >= 2019
true

new!(date, time)Source 

@spec new!(Date.t(), Time.t()) :: t()

Создаёт naive datetime из структур date и time.

Примеры 

iex> NaiveDateTime.new!(~D[2010-01-13], ~T[23:00:07.005])
~N[2010-01-13 23:00:07.005]

new!(year, month, day, hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)Source 

@spec new!(
  Calendar.year(),
  Calendar.month(),
  Calendar.day(),
  Calendar.hour(),
  Calendar.minute(),
  Calendar.second(),
  Calendar.microsecond() | non_neg_integer(),
  Calendar.calendar()
) :: t()

Создаёт новую ISO naive datetime.

Ожидает все значения в виде целых чисел. Возвращает naive_datetime если каждое значение находится в допустимом диапазоне, в противном случае вызывает исключение.

Примеры 

iex> NaiveDateTime.new!(2000, 1, 1, 0, 0, 0)
~N[2000-01-01 00:00:00]
iex> NaiveDateTime.new!(2000, 2, 29, 0, 0, 0)
~N[2000-02-29 00:00:00]
iex> NaiveDateTime.new!(2000, 1, 1, 23, 59, 59, {0, 1})
~N[2000-01-01 23:59:59.0]
iex> NaiveDateTime.new!(2000, 1, 1, 23, 59, 59, 999_999)
~N[2000-01-01 23:59:59.999999]
iex> NaiveDateTime.new!(2000, 1, 1, 23, 59, 59, {0, 1}, Calendar.ISO)
~N[2000-01-01 23:59:59.0]
iex> NaiveDateTime.new!(2000, 1, 1, 24, 59, 59, 999_999)
** (ArgumentError) cannot build naive datetime, reason: :invalid_time

new(date, time)Source 

@spec new(Date.t(), Time.t()) :: {:ok, t()}

Создаёт naive datetime из структур date и time.

Примеры 

iex> NaiveDateTime.new(~D[2010-01-13], ~T[23:00:07.005])
{:ok, ~N[2010-01-13 23:00:07.005]}

new(year, month, day, hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)Source 

@spec new(
  Calendar.year(),
  Calendar.month(),
  Calendar.day(),
  Calendar.hour(),
  Calendar.minute(),
  Calendar.second(),
  Calendar.microsecond() | non_neg_integer(),
  Calendar.calendar()
) :: {:ok, t()} | {:error, atom()}

Создаёт новую ISO naive datetime.

Ожидает все значения в виде целых чисел. Возвращает {:ok, naive_datetime} если каждое значение находится в допустимом диапазоне, в противном случае возвращает {:error, reason}.

Примеры 

iex> NaiveDateTime.new(2000, 1, 1, 0, 0, 0)
{:ok, ~N[2000-01-01 00:00:00]}
iex> NaiveDateTime.new(2000, 13, 1, 0, 0, 0)
{:error, :invalid_date}
iex> NaiveDateTime.new(2000, 2, 29, 0, 0, 0)
{:ok, ~N[2000-02-29 00:00:00]}
iex> NaiveDateTime.new(2000, 2, 30, 0, 0, 0)
{:error, :invalid_date}
iex> NaiveDateTime.new(2001, 2, 29, 0, 0, 0)
{:error, :invalid_date}

iex> NaiveDateTime.new(2000, 1, 1, 23, 59, 59, {0, 1})
{:ok, ~N[2000-01-01 23:59:59.0]}
iex> NaiveDateTime.new(2000, 1, 1, 23, 59, 59, 999_999)
{:ok, ~N[2000-01-01 23:59:59.999999]}
iex> NaiveDateTime.new(2000, 1, 1, 24, 59, 59, 999_999)
{:error, :invalid_time}
iex> NaiveDateTime.new(2000, 1, 1, 23, 60, 59, 999_999)
{:error, :invalid_time}
iex> NaiveDateTime.new(2000, 1, 1, 23, 59, 60, 999_999)
{:error, :invalid_time}
iex> NaiveDateTime.new(2000, 1, 1, 23, 59, 59, 1_000_000)
{:error, :invalid_time}

iex> NaiveDateTime.new(2000, 1, 1, 23, 59, 59, {0, 1}, Calendar.ISO)
{:ok, ~N[2000-01-01 23:59:59.0]}

to_date(map)Source 

@spec to_date(Calendar.naive_datetime()) :: Date.t()

Преобразует NaiveDateTime в Date.

Так как Date не содержит информацию о времени, при преобразовании данные будут потеряны.

Примеры 

iex> NaiveDateTime.to_date(~N[2002-01-13 23:00:07])
~D[2002-01-13]

to_erl(naive_datetime)Source 

@spec to_erl(Calendar.naive_datetime()) :: :calendar.datetime()

Преобразует структуру NaiveDateTime в кортеж Erlang для даты и времени.

Поддерживает только преобразование наивных дат и времён, которые находятся в календаре ISO, попытка преобразования наивных дат и времён из других календарей приведёт к ошибке.

ВНИМАНИЕ: Возможно потеря точности, так как кортежи Erlang для даты и времени хранят только час, минуту и секунду.

Примеры 

iex> NaiveDateTime.to_erl(~N[2000-01-01 13:30:15])
{{2000, 1, 1}, {13, 30, 15}}

Эта функция также может использоваться для преобразования DateTime в кортеж Erlang для даты и времени без информации о часовом поясе:

iex> dt = %DateTime{year: 2000, month: 2, day: 29, zone_abbr: "CET",
...>                hour: 23, minute: 0, second: 7, microsecond: {0, 0},
...>                utc_offset: 3600, std_offset: 0, time_zone: "Europe/Warsaw"}
iex> NaiveDateTime.to_erl(dt)
{{2000, 2, 29}, {23, 00, 07}}

to_gregorian_seconds(map)Source 

@spec to_gregorian_seconds(Calendar.naive_datetime()) ::
  {integer(), non_neg_integer()}

Преобразует структуру NaiveDateTime в количество грегорианских секунд и микросекунд.

Примеры 

iex> NaiveDateTime.to_gregorian_seconds(~N[0000-01-01 00:00:01])
{1, 0}
iex> NaiveDateTime.to_gregorian_seconds(~N[2020-05-01 00:26:31.005])
{63_755_511_991, 5000}

to_iso8601(naive_datetime, format \\ :extended)Source 

@spec to_iso8601(Calendar.naive_datetime(), :basic | :extended) :: String.t()

Преобразует заданную наивную дату и время в ISO 8601:2019.

По умолчанию NaiveDateTime.to_iso8601/2 возвращает наивные даты и времена, отформатированные в формате «расширенном» для удобства чтения. Также поддерживается формат «базовый» через передачу опции :basic.

Поддерживает только преобразование наивных дат и времён, которые находятся в календаре ISO, попытка преобразования наивных дат и времён из других календарей приведёт к ошибке.

Примеры 

iex> NaiveDateTime.to_iso8601(~N[2000-02-28 23:00:13])
"2000-02-28T23:00:13"

iex> NaiveDateTime.to_iso8601(~N[2000-02-28 23:00:13.001])
"2000-02-28T23:00:13.001"

iex> NaiveDateTime.to_iso8601(~N[2000-02-28 23:00:13.001], :basic)
"20000228T230013.001"

Эта функция также может использоваться для преобразования DateTime в ISO 8601 без информации о часовом поясе:

iex> dt = %DateTime{year: 2000, month: 2, day: 29, zone_abbr: "CET",
...>                hour: 23, minute: 0, second: 7, microsecond: {0, 0},
...>                utc_offset: 3600, std_offset: 0, time_zone: "Europe/Warsaw"}
iex> NaiveDateTime.to_iso8601(dt)
"2000-02-29T23:00:07"

to_string(naive_datetime)Source 

@spec to_string(Calendar.naive_datetime()) :: String.t()

Преобразует заданную наивную дату и время в строку в соответствии с её календарём.

Примеры 

iex> NaiveDateTime.to_string(~N[2000-02-28 23:00:13])
"2000-02-28 23:00:13"
iex> NaiveDateTime.to_string(~N[2000-02-28 23:00:13.001])
"2000-02-28 23:00:13.001"
iex> NaiveDateTime.to_string(~N[-0100-12-15 03:20:31])
"-0100-12-15 03:20:31"

Эта функция также может использоваться для преобразования DateTime в строку без информации о часовом поясе:

iex> dt = %DateTime{year: 2000, month: 2, day: 29, zone_abbr: "CET",
...>                hour: 23, minute: 0, second: 7, microsecond: {0, 0},
...>                utc_offset: 3600, std_offset: 0, time_zone: "Europe/Warsaw"}
iex> NaiveDateTime.to_string(dt)
"2000-02-29 23:00:07"

to_time(map)Source 

@spec to_time(Calendar.naive_datetime()) :: Time.t()

Преобразует NaiveDateTime в Time.

Так как Time не содержит информацию о дате, при преобразовании данные будут потеряны.

Примеры 

iex> NaiveDateTime.to_time(~N[2002-01-13 23:00:07])
~T[23:00:07]

truncate(naive_datetime, precision)Source 

@spec truncate(t(), :microsecond | :millisecond | :second) :: t()

Возвращает заданную наивную дату и время с микросекундным значением, усеченным до заданной точности (:microsecond, :millisecond или :second).

Заданная наивная дата и время возвращается без изменений, если она уже имеет меньшую точность, чем заданная.

Примеры 

iex> NaiveDateTime.truncate(~N[2017-11-06 00:23:51.123456], :microsecond)
~N[2017-11-06 00:23:51.123456]

iex> NaiveDateTime.truncate(~N[2017-11-06 00:23:51.123456], :millisecond)
~N[2017-11-06 00:23:51.123]

iex> NaiveDateTime.truncate(~N[2017-11-06 00:23:51.123456], :second)
~N[2017-11-06 00:23:51]

utc_now(calendar \\ Calendar.ISO)Source 

@spec utc_now(Calendar.calendar()) :: t()

Возвращает текущую наивную дату и время в UTC.

В случае возможности используйте DateTime.utc_now/0, так как, в отличие от NaiveDateTime, она сохранит информацию о часовом поясе.

Примеры 

iex> naive_datetime = NaiveDateTime.utc_now()
iex> naive_datetime.year >= 2016
true

© 2012 Plataformatec
Licensed under the Apache License, Version 2.0.
https://hexdocs.pm/elixir/1.13.4/NaiveDateTime.html

Spec-Zone.ru

Настройки Оффлайн Что нового Помощь О нас
Spec-Zone .ru
спецификации, руководства, описания, API