@spec close(pid()) :: {:ok, {binary(), binary()}}

Останавливает устройство ввода-вывода и возвращает оставшиеся буферы ввода-вывода.

Примеры

iex> {:ok, pid} = StringIO.open("in")
iex> IO.write(pid, "out")
iex> StringIO.close(pid)
{:ok, {"in", "out"}}

@spec contents(pid()) :: {binary(), binary()}

Возвращает текущие буферы ввода-вывода для данного устройства ввода-вывода.

Примеры

iex> {:ok, pid} = StringIO.open("in")
iex> IO.write(pid, "out")
iex> StringIO.contents(pid)
{"in", "out"}

@spec flush(pid()) :: binary()

Очищает буфер вывода и возвращает его текущее содержимое.

Примеры

iex> {:ok, pid} = StringIO.open("in")
iex> IO.write(pid, "out")
iex> StringIO.flush(pid)
"out"
iex> StringIO.contents(pid)
{"in", ""}

@spec open(
  binary(),
  keyword()
) :: {:ok, pid()}

@spec open(binary(), (pid() -> res)) :: {:ok, res} when res: var

Создаёт устройство ввода-вывода.

string будет начальным вводом созданного устройства.

options_or_function может быть списком ключевых слов или функцией.

Если заданы параметры, результатом будет {:ok, pid}, возвращая созданное устройство ввода-вывода. Параметр :capture_prompt, при установке в true, включает подсказки (которые задаются аргументами для функций IO.get* ) в выводе устройства.

Если предоставлена функция, устройство будет создано и отправлено в функцию. Когда функция вернётся, устройство будет закрыто. Конечным результатом будет кортеж с :ok и результатом функции.

Примеры

iex> {:ok, pid} = StringIO.open("foo")
iex> IO.gets(pid, ">")
"foo"
iex> StringIO.contents(pid)
{"", ""}

iex> {:ok, pid} = StringIO.open("foo", capture_prompt: true)
iex> IO.gets(pid, ">")
"foo"
iex> StringIO.contents(pid)
{"", ">"}

iex> StringIO.open("foo", fn pid ->
...>   input = IO.gets(pid, ">")
...>   IO.write(pid, "The input was #{input}")
...>   StringIO.contents(pid)
...> end)
{:ok, {"", "The input was foo"}}

@spec open(binary(), keyword(), (pid() -> res)) :: {:ok, res} when res: var

Создаёт устройство ввода-вывода.

string будет начальным вводом созданного устройства.

Устройство будет создано и отправлено в заданную функцию. Когда функция вернётся, устройство будет закрыто. Конечным результатом будет кортеж с :ok и результатом функции.

Параметры

• :capture_prompt - если установлен в true, подсказки (заданные в качестве аргументов функциям IO.get* ) будут захвачены в выводе. По умолчанию false.

• :encoding (с версии 1.10.0) - кодировка устройства ввода-вывода. Допустимые значения :unicode (по умолчанию) и :latin1.

Примеры

iex> StringIO.open("foo", [], fn pid ->
...>   input = IO.gets(pid, ">")
...>   IO.write(pid, "The input was #{input}")
...>   StringIO.contents(pid)
...> end)
{:ok, {"", "The input was foo"}}

iex> StringIO.open("foo", [capture_prompt: true], fn pid ->
...>   input = IO.gets(pid, ">")
...>   IO.write(pid, "The input was #{input}")
...>   StringIO.contents(pid)
...> end)
{:ok, {"", ">The input was foo"}}