Наблюдатель, запускающий несколько партиций одного и того же дочернего процесса.

В больших системах некоторые процессы могут стать узкими местами. Если состояние этих процессов можно тривиально разделить на партиции, при этом между ними нет зависимости, то они могут использовать PartitionSupervisor для создания нескольких изолированных и независимых партиций.

После запуска PartitionSupervisor вы можете отправлять сообщения его дочерним процессам, используя {:via, PartitionSupervisor, {name, key}}, где name — имя PartitionSupervisor, а ключ используется для маршрутизации.

Этот модуль был представлен в Elixir v1.14.0.

Простой пример

Давайте начнем с примера, который сам по себе не полезен, но демонстрирует, как запускаются партиции и как к ним маршрутизируются сообщения.

Вот игрушечный GenServer, который просто собирает полученные сообщения. Он выводит их для наглядности.

defmodule Collector do
  use GenServer

  def start_link(args) do
    GenServer.start_link(__MODULE__, args)
  end

  def init(args) do
    IO.inspect([__MODULE__, " got args ", args, " in ", self()])
    {:ok, _initial_state = []}
  end

  def collect(server, msg) do
    GenServer.call(server, {:collect, msg})
  end

  def handle_call({:collect, msg}, _from, state) do
    new_state = [msg | state]
    IO.inspect(["current messages:", new_state, " in process", self()])
    {:reply, :ok, new_state}
  end
end

Чтобы запустить несколько таких GenServer'ов, мы можем запустить их под PartitionSupervisor, поместив это в нашу структуру наблюдения:

{PartitionSupervisor,
  child_spec: Collector.child_spec([some: :arg]),
  name: MyApp.PartitionSupervisor
}

Мы можем отправлять сообщения им, используя «кортеж в качестве адресата»:

# The key is used to route our message to a particular instance.
key = 1
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :hi)
# ["current messages:", [:hi], " in process", #PID<0.602.0>]
:ok
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :ho)
# ["current messages:", [:ho, :hi], " in process", #PID<0.602.0>]
:ok

# With a different key, the message will be routed to a different instance.
key = 2
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :a)
# ["current messages:", [:a], " in process", #PID<0.603.0>]
:ok
Collector.collect({:via, PartitionSupervisor, {MyApp.PartitionSupervisor, key}}, :b)
# ["current messages:", [:b, :a], " in process", #PID<0.603.0>]
:ok

Теперь перейдем к полезному примеру.

DynamicSupervisor Пример

Наблюдатель DynamicSupervisor — это один процесс, отвечающий за запуск других процессов. В некоторых приложениях DynamicSupervisor может стать узким местом. Для решения этой проблемы вы можете запустить несколько экземпляров DynamicSupervisor через PartitionSupervisor, а затем выбрать «случайный» экземпляр для запуска дочернего процесса.

Вместо запуска одного DynamicSupervisor:

children = [
  {DynamicSupervisor, name: MyApp.DynamicSupervisor}
]

Supervisor.start_link(children, strategy: :one_for_one)

и запуска дочерних процессов непосредственно на этом динамическом наблюдателе:

DynamicSupervisor.start_child(MyApp.DynamicSupervisor, {Agent, fn -> %{} end})

Вы можете запустить динамических наблюдателей под PartitionSupervisor:

children = [
  {PartitionSupervisor,
   child_spec: DynamicSupervisor,
   name: MyApp.DynamicSupervisors}
]

Supervisor.start_link(children, strategy: :one_for_one)

и затем:

DynamicSupervisor.start_child(
  {:via, PartitionSupervisor, {MyApp.DynamicSupervisors, self()}},
  {Agent, fn -> %{} end}
)

В приведенном выше коде мы запускаем наблюдатель партиций, который по умолчанию запускает динамический наблюдатель для каждого ядра вашей машины. Затем, вместо вызова DynamicSupervisor по имени, вы вызываете его через наблюдатель партиций, используя формат {:via, PartitionSupervisor, {name, key}}. Мы выбрали self() в качестве ключа маршрутизации, что означает, что каждый процесс будет назначен одному из существующих динамических наблюдателей. См. start_link/1, чтобы увидеть все поддерживаемые параметры PartitionSupervisor.

Примечания по реализации

Наблюдатель PartitionSupervisor использует таблицу ETS или Registry для управления всеми партициями. Под капотом, PartitionSupervisor генерирует спецификацию дочернего процесса для каждой партиции, а затем действует как обычный наблюдатель. Идентификатор каждой спецификации дочернего процесса — это номер партиции.

Для маршрутизации используются две стратегии. Если key — целое число, оно маршрутизируется с помощью rem(abs(key), partitions), где partitions — количество партиций. В противном случае используется :erlang.phash2(key, partitions). Конкретная маршрутизация может измениться в будущем, поэтому не следует на ней полагаться. Если вы хотите получить определённый PID для определённого ключа, вы можете использовать GenServer.whereis({:via, PartitionSupervisor, {name, key}}).