Исходный код Regex

Предоставляет регулярные выражения для Elixir.

Regex основан на PCRE (Perl Compatible Regular Expressions) и построен поверх Erlang's :re модуля. Более подробная информация доступна в документации модуля :re.

Регулярные выражения в Elixir можно создавать с помощью сигилов ~r (см. sigil_r/2):

# A simple regular expression that matches foo anywhere in the string
~r/foo/

# A regular expression with case insensitive and Unicode options
~r/foo/iu

Регулярные выражения, созданные с помощью сигилов, предварительно компилируются и сохраняются в файле .beam. Обратите внимание, что это может быть проблемой при предварительной компиляции Elixir, см. раздел «Предварительная компиляция» для получения дополнительной информации.

Regex интерпретируется как структура Regex. Таким образом, %Regex{} можно использовать при необходимости проверки соответствия. Имейте в виду, что все поля структур являются приватными. Также нет гарантии, что два регулярных выражения из одного источника равны, например:

~r/(?<foo>.)(?<bar>.)/ == ~r/(?<foo>.)(?<bar>.)/

может вернуть true или false в зависимости от вашей машины, порядка байтов, доступных оптимизаций и других факторов. Однако вы можете получить исходный код скомпилированного регулярного выражения, обратившись к полю source, и затем сравнить их напрямую:

~r/(?<foo>.)(?<bar>.)/.source == ~r/(?<foo>.)(?<bar>.)/.source

Экранирование

Последовательности экранирования разделены на две категории.

Непечатаемые символы

\a - Сигнал тревоги, то есть символ BEL (шестнадцатеричный 07)
\e - Экранирование (шестнадцатеричный 1B)
\f - Форматор страницы (шестнадцатеричный 0C)
\n - Перевод строки (шестнадцатеричный 0A)
\r - Возврат каретки (шестнадцатеричный 0D)
\t - Табуляция (шестнадцатеричный 09)
\xhh - Символ с шестнадцатеричным кодом hh
\x{hhh..} - Символ с шестнадцатеричным кодом hhh..

\u и \U не поддерживаются. Другие последовательности экранирования, такие как \ddd для восьмеричных чисел, поддерживаются, но не рекомендуются.

Общие типы символов

\d - Любая десятичная цифра
\D - Любой символ, который не является десятичной цифрой
\h - Любой символ горизонтального пробела
\H - Любой символ, который не является символом горизонтального пробела
\s - Любой символ пробела
\S - Любой символ, который не является символом пробела
\v - Любой символ вертикального пробела
\V - Любой символ, который не является символом вертикального пробела
\w - Любой символ «слова»
\W - Любой символ «не слова»

Модификаторы

Доступные модификаторы при создании Regex:

:unicode (u) - включает Unicode-специфичные шаблоны, такие как \p, и заставляет классы символов, такие как \w, \W, \s, и аналогичные, также соответствовать Unicode (см. примеры ниже в разделе «Классы символов»). Ожидаются корректные Unicode-строки при проверке соответствия
:caseless (i) - добавляет нечувствительность к регистру
:dotall (s) - заставляет точку соответствовать символам новой строки, а также устанавливает новую строку на любой crlf; настройка новой строки может быть переопределена, установив (*CR) или (*LF) или (*CRLF) или (*ANY) в соответствии с документацией :re
:multiline (m) - заставляет ^ и $ помечать начало и конец каждой строки; используйте \A и \z для сопоставления конца или начала строки
:extended (x) - символы пробела игнорируются, за исключением случаев экранирования, и позволяют # определять комментарии
:firstline (f) - заставляет неопределенный шаблон совпадать до или на первой новой строке, хотя сопоставленный текст может продолжаться через новую строку
:ungreedy (U) - инвертирует «жадность» regexp (предыдущий r параметр устарел в пользу U )

Недоступные параметры:

:anchored - недоступен, используйте ^ или \A вместо этого
:dollar_endonly - недоступен, используйте \z вместо этого
:no_auto_capture - недоступен, используйте ?: вместо этого
:newline - недоступен, используйте (*CR) или (*LF) или (*CRLF) или (*ANYCRLF) или (*ANY) в начале regexp в соответствии с документацией :re

Захваты

Многие функции в этом модуле обрабатывают захват в совпадении regex через параметр :capture. Поддерживаемые значения:

:all - все захваченные подшаблоны, включая всю строку совпадения (это значение по умолчанию)
:first - только первый захваченный подшаблон, который всегда является полной сопоставленной частью строки; все явно захваченные подшаблоны отбрасываются
:all_but_first - все, кроме первого сопоставленного подшаблона, т.е. все явно захваченные подшаблоны, но не полная сопоставленная часть строки
:none - не возвращает сопоставленные подшаблоны вообще
:all_names - захватывает все совпадения именованных подшаблонов в Regex в виде списка, отсортированного по алфавиту по именам подшаблонов
list(binary) - список именованных захватов для захвата

Классы символов

Regex поддерживает несколько встроенных именованных классов символов. Они используются, помещая имя класса в [: :] внутри группы. Например:

iex> String.match?("123", ~r/^[[:alnum:]]+$/)
true
iex> String.match?("123 456", ~r/^[[:alnum:][:blank:]]+$/)
true

Поддерживаемые имена классов:

alnum - Буквы и цифры
alpha - Буквы
blank - Только пробел или табуляция
cntrl - Управляющие символы
digit - Десятичные цифры (также как \d)
graph - Печатаемые символы, за исключением пробела
lower - Строчные буквы
print - Печатаемые символы, включая пробел
punct - Печатаемые символы, за исключением букв, цифр и пробела
space - Пробелы (также как \s из PCRE 8.34)
upper - Заглавные буквы
word - Символы «слова» (также как \w)
xdigit - Шестнадцатеричные цифры

Есть еще один класс символов, ascii, который ошибочно соответствует символам Latin-1 вместо диапазона 0-127, указанного в POSIX. Это невозможно исправить без изменения поведения других классов, поэтому мы рекомендуем сопоставить диапазон с [\\0-\x7f] вместо этого.

Обратите внимание, что поведение этих классов может меняться в зависимости от Unicode и других модификаторов:

iex> String.match?("josé", ~r/^[[:lower:]]+$/)
false
iex> String.match?("josé", ~r/^[[:lower:]]+$/u)
true
iex> Regex.replace(~r/\s/, "Unicode\u00A0spaces", "-")
"Unicode spaces"
iex> Regex.replace(~r/\s/u, "Unicode\u00A0spaces", "-")
"Unicode-spaces"

Предварительная компиляция

Регулярные выражения, созданные с помощью сигила, предварительно компилируются и сохраняются в файлах .beam. Проверенные предварительно скомпилированные регулярные выражения могут работать медленнее между операционными системами и выпусками OTP. Это редко проблема, так как большая часть кода Elixir, используемого во время разработки, компилируется на целевой системе (например, зависимости, архивы и escripts), а при работе в продакшене код должен либо компилироваться на целевой системе (через mix compile или аналогично), либо выпущен на хосте (через mix releases или аналогично) с соответствующей версией OTP, операционной системой и архитектурой, как и на целевой.

Если вам известно, что вы работаете на другой системе, чем текущая, и вы выполняете несколько сопоставлений с регулярным выражением, вы можете вручную вызвать Regex.recompile/1 или Regex.recompile!/1, чтобы проверить версию во время выполнения и перекомпилировать регулярное выражение при необходимости.

Краткое описание

Типы

t()

Функции

compile(source, options \\ ""): Компилирует регулярное выражение.
compile!(source, options \\ ""): Компилирует регулярное выражение и вызывает Regex.CompileError в случае ошибок.
escape(string): Экранирует строку для буквального соответствия в регулярном выражении.
match?(regex, string): Возвращает логическое значение, указывающее, было ли совпадение или нет.
named_captures(regex, string, options \\ []): Возвращает заданные захватчики в виде карты или nil если захватчиков не найдено.
names(regex): Возвращает список имён в регулярном выражении.
opts(regex): Возвращает опции регулярного выражения в виде строки или списка в зависимости от способа компиляции.
re_pattern(regex): Возвращает базовое re_pattern регулярного выражения.
recompile(regex): Перекомпилирует существующее регулярное выражение при необходимости.
recompile!(regex): Перекомпилирует существующее регулярное выражение и вызывает Regex.CompileError в случае ошибок.
replace(regex, string, replacement, options \\ []): Получает регулярное выражение, бинарное значение и замену, возвращает новое бинарное значение, где все совпадения заменены заменой.
run(regex, string, options \\ []): Выполняет регулярное выражение против заданной строки до первого совпадения. Возвращает список со всеми захваченными значениями или nil если совпадение не найдено.
scan(regex, string, options \\ []): Аналогично run/3, но сканирует целевой объект несколько раз, собирая все совпадения регулярного выражения.
source(regex): Возвращает исходный код регулярного выражения в виде бинарного значения.
split(regex, string, options \\ []): Разделяет заданный целевой объект на основе заданного шаблона и заданного количества частей.
version(): Возвращает версию базового движка регулярных выражений.

Типы

t()Source

@type t() :: %Regex{
  opts: binary() | [term()],
  re_pattern: term(),
  re_version: term(),
  source: binary()
}

Функции

compile(source, options \\ "")Source

@spec compile(binary(), binary() | [term()]) :: {:ok, t()} | {:error, any()}

Компилирует регулярное выражение.

Указанные параметры могут быть либо двоичной строкой с символами, представляющими те же параметры регулярного выражения, что и для ~r (см. sigil_r/2) сигнала, либо списком параметров, как ожидается в модуле Erlang's :re.

Возвращает {:ok, regex} в случае успеха, {:error, reason} в противном случае.

Примеры

iex> Regex.compile("foo")
{:ok, ~r/foo/}

iex> Regex.compile("*foo")
{:error, {'nothing to repeat', 0}}

iex> Regex.compile("foo", "i")
{:ok, ~r/foo/i}

iex> Regex.compile("foo", [:caseless])
{:ok, Regex.compile!("foo", [:caseless])}

compile!(source, options \\ "")Source

@spec compile!(binary(), binary() | [term()]) :: t()

Компилирует регулярное выражение и вызывает исключение Regex.CompileError в случае ошибок.

escape(string)Source

@spec escape(String.t()) :: String.t()

Экранирует строку для буквального сопоставления в регулярном выражении.

Примеры

iex> Regex.escape(".")
"\\."

iex> Regex.escape("\\what if")
"\\\\what\\ if"

match?(regex, string)Source

@spec match?(t(), String.t()) :: boolean()

Возвращает логическое значение, указывающее, было ли сопоставление или нет.

Примеры

iex> Regex.match?(~r/foo/, "foo")
true

iex> Regex.match?(~r/foo/, "bar")
false

Elixir также предоставляет текстовый оператор сопоставления =~/2 и функцию String.match?/2 в качестве альтернативы для проверки строк на соответствие регулярным выражениям и строкам.

named_captures(regex, string, options \\ [])Source

@spec named_captures(t(), String.t(), [term()]) :: map() | nil

Возвращает заданные совпадения в виде карты или nil если совпадений не найдено.

Параметры

:return - при установке в :index, возвращает индекс байта и длину совпадения. По умолчанию :binary.

Примеры

iex> Regex.named_captures(~r/c(?<foo>d)/, "abcd")
%{"foo" => "d"}

iex> Regex.named_captures(~r/a(?<foo>b)c(?<bar>d)/, "abcd")
%{"bar" => "d", "foo" => "b"}

iex> Regex.named_captures(~r/a(?<foo>b)c(?<bar>d)/, "efgh")
nil

names(regex)Source

@spec names(t()) :: [String.t()]

Возвращает список имен в регулярном выражении.

Примеры

iex> Regex.names(~r/(?<foo>bar)/)
["foo"]

opts(regex)Source

@spec opts(t()) :: String.t() | [term()]

Возвращает параметры регулярного выражения в виде строки или списка, в зависимости от способа компиляции.

См. документацию по Regex.compile/2 для получения дополнительной информации.

Примеры

iex> Regex.opts(~r/foo/m)
"m"

iex> Regex.opts(Regex.compile!("foo", [:caseless]))
[:caseless]

re_pattern(regex)Source

@spec re_pattern(t()) :: term()

Возвращает базовое re_pattern в регулярном выражении.

recompile(regex)Source

@spec recompile(t()) :: {:ok, t()} | {:error, any()}

Перекомпилирует существующее регулярное выражение при необходимости.

Это проверяет версию, хранящуюся в регулярном выражении, и перекомпилирует регулярное выражение в случае несоответствия версий.

recompile!(regex)Source

@spec recompile!(t()) :: t()

Перекомпилирует существующее регулярное выражение и вызывает исключение Regex.CompileError в случае ошибок.

replace(regex, string, replacement, options \\ [])Source

@spec replace(t(), String.t(), String.t() | (... -> String.t()), [term()]) ::
  String.t()

Получает регулярное выражение, двоичную строку и замену, возвращает новую двоичную строку, где все совпадения заменены заменой.

Замена может быть либо строкой, либо функцией, которая возвращает строку. Результирующая строка используется в качестве замены для каждого совпадения.

Когда замена является строкой, она допускает конкретные совпадения совпадения с использованием скобок в выражении регулярного выражения и доступ к ним в замене через \N или \g{N}, где N — номер совпадения. В случае использования \0, вставляется все совпадение. Обратите внимание, что в регулярных выражениях обратный слэш необходимо экранировать, поэтому на практике вам нужно использовать \\N и \\g{N}.

Когда замена — функция, она также допускает конкретные совпадения. Функция может иметь арность N, где каждый аргумент сопоставляется с захватом, при этом первый аргумент — это все совпадение. Если функция ожидает больше аргументов, чем найдено захватов, оставшиеся аргументы получат "".

Параметры

:global - когда false, заменяет только первое вхождение (по умолчанию true)

Примеры

iex> Regex.replace(~r/d/, "abc", "d")
"abc"

iex> Regex.replace(~r/b/, "abc", "d")
"adc"

iex> Regex.replace(~r/b/, "abc", "[\\0]")
"a[b]c"

iex> Regex.replace(~r/a(b|d)c/, "abcadc", "[\\1]")
"[b][d]"

iex> Regex.replace(~r/\.(\d)$/, "500.5", ".\\g{1}0")
"500.50"

iex> Regex.replace(~r/a(b|d)c/, "abcadc", fn _, x -> "[#{x}]" end)
"[b][d]"

iex> Regex.replace(~r/(\w+)@(\w+).(\w+)/, "abc@def.com", fn _full, _c1, _c2, c3 -> "TLD: #{c3}" end)
"TLD: com"

iex> Regex.replace(~r/a/, "abcadc", "A", global: false)
"Abcadc"

run(regex, string, options \\ [])Source

@spec run(t(), binary(), [term()]) :: nil | [binary()] | [{integer(), integer()}]

Выполняет регулярное выражение по заданной строке до первого совпадения. Возвращает список со всеми захватами или nil если совпадение не найдено.

Параметры

:return - при установке в :index, возвращает индекс байта и длину совпадения. По умолчанию :binary.
:capture - что захватывать в результате. Проверьте модульную документацию для Regex, чтобы увидеть возможные значения захвата.
:offset - (с версии 1.12.0) указывает начальный смещение для поиска в заданной строке. По умолчанию ноль.

Примеры

iex> Regex.run(~r/c(d)/, "abcd")
["cd", "d"]

iex> Regex.run(~r/e/, "abcd")
nil

iex> Regex.run(~r/c(d)/, "abcd", return: :index)
[{2, 2}, {3, 1}]

scan(regex, string, options \\ [])Source

@spec scan(t(), String.t(), [term()]) :: [[String.t()]] | [[{integer(), integer()}]]

То же самое, что и run/3, но сканирует целевой объект несколько раз, собирая все совпадения регулярного выражения.

Возвращается список списков, где каждая запись в основном списке представляет собой совпадение, а каждая запись во вторичном списке представляет собой содержимое захваченного элемента.

Параметры

:return - при установке в :index, возвращает индекс байта и длину совпадения. По умолчанию :binary.
:capture - что захватывать в результате. Проверьте модульную документацию для Regex, чтобы увидеть возможные значения захвата.
:offset - (с версии 1.12.0) указывает начальный смещение для поиска в заданной строке. По умолчанию ноль.

Примеры

iex> Regex.scan(~r/c(d|e)/, "abcd abce")
[["cd", "d"], ["ce", "e"]]

iex> Regex.scan(~r/c(?:d|e)/, "abcd abce")
[["cd"], ["ce"]]

iex> Regex.scan(~r/e/, "abcd")
[]

iex> Regex.scan(~r/\p{Sc}/u, "$, £, and €")
[["$"], ["£"], ["€"]]

iex> Regex.scan(~r/=+/, "=ü†ƒ8===", return: :index)
[[{0, 1}], [{9, 3}]]

source(regex)Source

@spec source(t()) :: String.t()

Возвращает исходный текст регулярного выражения в виде двоичной строки.

Примеры

iex> Regex.source(~r/foo/)
"foo"

split(regex, string, options \\ [])Source

@spec split(t(), String.t(), [term()]) :: [String.t()]

Разделяет заданную цель на основе заданного шаблона и заданного числа частей.

Параметры

:parts - при указании, разделяет строку на заданное число частей. Если не указано, :parts по умолчанию равно :infinity, что разделит строку на максимальное возможное число частей на основе заданного шаблона.
:trim - когда true, удаляет пустые строки ("") из результата. По умолчанию false.
:on - указывает, какие группы захвата использовать для разделения строки и в каком порядке. По умолчанию :first, что означает, что группы захвата внутри регулярного выражения не влияют на процесс разделения. Обратитесь к модульной документации по Regex для просмотра возможных значений для захвата.
:include_captures - когда true, включает в результат совпадения регулярного выражения. Совпадения не учитываются в максимальном числе частей, если объединены с параметром :parts. По умолчанию false.

Примеры

iex> Regex.split(~r{-}, "a-b-c")
["a", "b", "c"]

iex> Regex.split(~r{-}, "a-b-c", parts: 2)
["a", "b-c"]

iex> Regex.split(~r{-}, "abc")
["abc"]

iex> Regex.split(~r{}, "abc")
["", "a", "b", "c", ""]

iex> Regex.split(~r{a(?<second>b)c}, "abc")
["", ""]

iex> Regex.split(~r{a(?<second>b)c}, "abc", on: [:second])
["a", "c"]

iex> Regex.split(~r{(x)}, "Elixir", include_captures: true)
["Eli", "x", "ir"]

iex> Regex.split(~r{a(?<second>b)c}, "abc", on: [:second], include_captures: true)
["a", "b", "c"]

version()Source

@spec version() :: term()

Возвращает версию движка регулярных выражений.