MapSet

Функции, работающие со множествами.

MapSet является основной структурой данных для множеств в Elixir. Множество можно создать, используя MapSet.new/0:

iex> MapSet.new
#MapSet<[]>

Множество может содержать любые типы элементов, и элементы в множестве не обязательно должны быть одного типа. По определению, множества не могут содержать дубликатов: при добавлении элемента в множество, если он уже присутствует, добавление просто игнорируется.

iex> set = MapSet.new
iex> MapSet.put(set, "foo")
#MapSet<["foo"]>
iex> set |> MapSet.put("foo") |> MapSet.put("foo")
#MapSet<["foo"]>

Множество MapSet представляется во внутренней структуре с помощью структуры %MapSet{}. Эта структура может использоваться, когда необходимо сопоставить шаблон с чем-то, являющимся MapSet:

iex> match?(%MapSet{}, MapSet.new())
true

Обратите внимание, что поля структуры являются приватными и не должны напрямую использоваться; используйте функции в данном модуле для выполнения операций со множествами.

Множества также можно создавать, начиная с других структур данных, которые являются коллекциями: например, см. MapSet.new/1 или Enum.into/2.

Краткое описание

Функции

delete(set, value): Удаляет value из set
difference(mapset1, mapset2): Возвращает множество, содержащее только элементы set1 без элементов из set2
disjoint?(map_set1, map_set2): Проверяет, содержат ли set1 и set2 общие элементы
equal?(map_set1, map_set2): Проверяет, равны ли два множества
intersection(map_set1, map_set2): Возвращает множество, содержащее только элементы, которые set1 и set2 имеют общие
member?(map_set, value): Проверяет, содержит ли set элемент value
new(): Возвращает новое множество
new(mapset): Создает множество из перечисляемого объекта
new(enumerable, transform): Создает множество из перечисляемого объекта с помощью функции преобразования
put(set, value): Вставляет value в set если set его еще не содержит
size(map_set): Возвращает количество элементов в set
subset?(map_set1, map_set2): Проверяет, содержатся ли все элементы set1 в set2
to_list(map_set): Преобразует set в список
union(map_set1, map_set2): Возвращает множество, содержащее все элементы из set1 и set2

Типы

t()

t() :: t(term())

t(value) (opaque)

t(value)

value()

value() :: term()

Функции

delete(set, value)

delete(t(val1), val2) :: t(val1) when val1: value(), val2: value()

Удаляет value из set.

Возвращает новое множество, являющееся копией set без value.

Примеры

iex> set = MapSet.new([1, 2, 3])
iex> MapSet.delete(set, 4)
#MapSet<[1, 2, 3]>
iex> MapSet.delete(set, 2)
#MapSet<[1, 3]>

difference(mapset1, mapset2)

difference(t(val1), t(val2)) :: t(val1) when val1: value(), val2: value()

Возвращает множество, содержащее только элементы set1 без элементов из set2.

Примеры

iex> MapSet.difference(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
#MapSet<[1]>

disjoint?(map_set1, map_set2)

disjoint?(t(), t()) :: boolean()

Проверяет, не имеют ли set1 и set2 общих элементов.

Примеры

iex> MapSet.disjoint?(MapSet.new([1, 2]), MapSet.new([3, 4]))
true
iex> MapSet.disjoint?(MapSet.new([1, 2]), MapSet.new([2, 3]))
false

equal?(map_set1, map_set2)

equal?(t(), t()) :: boolean()

Проверяет, равны ли два множества.

Сравнение элементов должно выполняться с использованием ===.

Примеры

iex> MapSet.equal?(MapSet.new([1, 2]), MapSet.new([2, 1, 1]))
true
iex> MapSet.equal?(MapSet.new([1, 2]), MapSet.new([3, 4]))
false

intersection(map_set1, map_set2)

intersection(t(val), t(val)) :: t(val) when val: value()

Возвращает множество, содержащее только общие элементы set1 и set2.

Примеры

iex> MapSet.intersection(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
#MapSet<[2]>

iex> MapSet.intersection(MapSet.new([1, 2]), MapSet.new([3, 4]))
#MapSet<[]>

member?(map_set, value)

member?(t(), value()) :: boolean()

Проверяет, содержит ли set элемент value.

Примеры

iex> MapSet.member?(MapSet.new([1, 2, 3]), 2)
true
iex> MapSet.member?(MapSet.new([1, 2, 3]), 4)
false

new()

new() :: t()

Возвращает новое множество.

Примеры

iex> MapSet.new
#MapSet<[]>

new(mapset)

new(Enum.t()) :: t()

Создает множество из перечисляемого объекта.

Примеры

iex> MapSet.new([:b, :a, 3])
#MapSet<[3, :a, :b]>
iex> MapSet.new([3, 3, 3, 2, 2, 1])
#MapSet<[1, 2, 3]>

new(enumerable, transform)

new(Enum.t(), (term() -> val)) :: t(val) when val: value()

Создает множество из перечисляемого объекта с помощью функции преобразования.

Примеры

iex> MapSet.new([1, 2, 1], fn x -> 2 * x end)
#MapSet<[2, 4]>

put(set, value)

put(t(val), new_val) :: t(val | new_val) when val: value(), new_val: value()

Вставляет value в set если set его еще не содержит.

Примеры

iex> MapSet.put(MapSet.new([1, 2, 3]), 3)
#MapSet<[1, 2, 3]>
iex> MapSet.put(MapSet.new([1, 2, 3]), 4)
#MapSet<[1, 2, 3, 4]>

size(map_set)

size(t()) :: non_neg_integer()

Возвращает количество элементов в set.

Примеры

iex> MapSet.size(MapSet.new([1, 2, 3]))
3

subset?(map_set1, map_set2)

subset?(t(), t()) :: boolean()

Проверяет, содержатся ли все элементы set1 в set2.

Эта функция проверяет, является ли set1 подмножеством set2.

Примеры

iex> MapSet.subset?(MapSet.new([1, 2]), MapSet.new([1, 2, 3]))
true
iex> MapSet.subset?(MapSet.new([1, 2, 3]), MapSet.new([1, 2]))
false

to_list(map_set)

to_list(t(val)) :: [val] when val: value()

Преобразует set в список.

Примеры

iex> MapSet.to_list(MapSet.new([1, 2, 3]))
[1, 2, 3]

union(map_set1, map_set2)

union(t(val1), t(val2)) :: t(val1 | val2) when val1: value(), val2: value()

Возвращает множество, содержащее все элементы из set1 и set2.

Примеры

iex> MapSet.union(MapSet.new([1, 2]), MapSet.new([2, 3, 4]))
#MapSet<[1, 2, 3, 4]>