Inspect.Algebra

Набор функций для создания и обработки документов алгебры.

Этот модуль реализует функциональность, описанную в «Strictly Pretty» (2000) Кристиана Линдига с небольшими дополнениями, такими как поддержка бинарных узлов и режим перевода, который максимизирует использование горизонтального пространства.

iex> Inspect.Algebra.empty
:doc_nil

iex> "foo"
"foo"

С помощью функций в этом модуле мы можем конкатенировать различные элементы вместе и отобразить их:

iex> doc = Inspect.Algebra.concat(Inspect.Algebra.empty, "foo")
iex> Inspect.Algebra.format(doc, 80)
["foo"]

Функции nest/2, space/2 и line/2 помогают вам организовать документ в жёсткую структуру. Однако алгебра документов становится интересной при использовании таких функций, как glue/3 и group/1. Glue вставляет разрыв между двумя документами. Группа указывает документ, который должен поместиться в текущей строке, в противном случае разрывы отображаются как новые строки. Давайте склеим два документа с разрывом, сгруппируем их и затем отобразим:

iex> doc = Inspect.Algebra.glue("a", " ", "b")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 80)
["a", " ", "b"]

Обратите внимание, что разрыв был представлен как есть, потому что мы не достигли предела строки. Как только мы достигнем предела, он заменяется новой строкой:

iex> doc = Inspect.Algebra.glue(String.duplicate("a", 20), " ", "b")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 10)
["aaaaaaaaaaaaaaaaaaaa", "\n", "b"]

Этот модуль использует размер байтов для вычисления оставшегося пространства. Если ваш документ содержит строки, то их необходимо заключить в string/1, который затем полагается на String.length/1 для предварительного вычисления размера документа.

Наконец, этот модуль также содержит функции, связанные с Elixir, немного связанные с форматированием Elixir, такие как to_doc/2.

Детали реализации

Реализация Inspect.Algebra основана на статье «Strictly Pretty» Линдига, которая строится на основе предыдущих алгоритмов красивого форматирования, но адаптирована к строгим языкам, таким как Elixir. Основная идея в статье — использование явных групп документов, которые отображаются как плоские (разрывы как пробелы) или как разрывы (разрывы как новые строки).

Эта реализация предоставляет два типа разрывов: :strict и :flex. Когда группа не помещается, все строгие разрывы обрабатываются как новые строки. Однако гибкие разрывы переоцениваются при каждом появлении и могут все еще отображаться как плоские. Дополнительную информацию см. в break/1 и flex_break/1.

Эта реализация также добавляет force_unfit/1 и next_break_fits/2, которые обеспечивают больший контроль над размещением документа.

Обзор

Типы

t()

Функции

break(string \\ " "): Возвращает документ-разрыв, основанный на заданном string
collapse_lines(max): Сжимает любые новые строки и пробелы, следующие за этим узлом, выводит до max новых строк
color(doc, color_key, opts): Изменяет цвет документа, если у color_key есть цвет в параметрах
concat(docs): Конкатенирует список документов, возвращая новый документ
concat(doc1, doc2): Конкатенирует два сущности документа, возвращая новый документ
container_doc(left, collection, right, inspect, fun, opts \\ []): Оборачивает collection в left и right в соответствии с лимитом и содержимым
empty(): Возвращает сущность документа, используемую для представления пустоты
flex_break(string \\ " "): Возвращает документ гибкого разрыва, основанный на заданном string
flex_glue(doc1, break_string \\ " ", doc2): Склеивает два документа (doc1 и doc2) вставляя flex_break/1, заданный break_string между ними
fold_doc(docs, folder_fun): Складывает список документов в документ с помощью заданной функции-складывателя
force_unfit(doc): Заставляет текущую группу не подходить
format(doc, width): Форматирует заданный документ для заданной ширины
glue(doc1, break_string \\ " ", doc2): Склеивает два документа (doc1 и doc2) вставляя заданный разрыв break_string между ними
group(doc, mode \\ :self): Возвращает группу, содержащую указанный документ doc
line(): Обязательный разрыв строки
line(doc1, doc2): Вставляет обязательный разрыв строки между двумя документами
nest(doc, level, mode \\ :always): Вкладывает заданный документ на заданный level
next_break_fits(doc, mode \\ :enabled): Рассматривает следующий разрыв как подходящий
space(doc1, doc2): Вставляет обязательный одиночный пробел между двумя документами
string(string): Создаёт документ, представленный строкой
to_doc(term, opts): Преобразует термин Elixir в документ алгебры в соответствии с протоколом Inspect

Типы

t()

t() ::
  binary()
  | :doc_nil
  | :doc_line
  | doc_string()
  | doc_cons()
  | doc_nest()
  | doc_break()
  | doc_group()
  | doc_color()
  | doc_force()
  | doc_fits()
  | doc_collapse()

Функции

break(string \\ " ")

break(binary()) :: doc_break()

Возвращает документ-разрыв, основанный на заданном string.

Этот разрыв может отображаться как разрыв строки или как заданный string, в зависимости от mode выбранного макета.

Примеры

Давайте создадим документ, конкатенируя две строки с разрывом между ними:

iex> doc = Inspect.Algebra.concat(["a", Inspect.Algebra.break("\t"), "b"])
iex> Inspect.Algebra.format(doc, 80)
["a", "\t", "b"]

Обратите внимание, что разрыв был представлен заданной строкой, потому что мы не достигли предела строки. Как только мы достигнем предела, он заменяется новой строкой:

iex> break = Inspect.Algebra.break("\t")
iex> doc = Inspect.Algebra.concat([String.duplicate("a", 20), break, "b"])
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 10)
["aaaaaaaaaaaaaaaaaaaa", "\n", "b"]

collapse_lines(max)

collapse_lines(pos_integer()) :: doc_collapse()

Сжимает любые новые строки и пробелы, следующие за этим узлом, выводит до max новых строк.

color(doc, color_key, opts)

color(t(), Inspect.Opts.color_key(), Inspect.Opts.t()) :: doc_color()

Изменяет цвет документа, если у color_key есть цвет в параметрах.

concat(docs)

concat([t()]) :: t()

Конкатенирует список документов, возвращая новый документ.

Примеры

iex> doc = Inspect.Algebra.concat(["a", "b", "c"])
iex> Inspect.Algebra.format(doc, 80)
["a", "b", "c"]

concat(doc1, doc2)

concat(t(), t()) :: t()

Конкатенирует два сущности документа, возвращая новый документ.

Примеры

iex> doc = Inspect.Algebra.concat("hello", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", "world"]

container_doc(left, collection, right, inspect, fun, opts \\ [])

container_doc(
  t(),
  [any()],
  t(),
  Inspect.Opts.t(),
  (term(), Inspect.Opts.t() -> t()),
  keyword()
) :: t()

Оборачивает collection в left и right в соответствии с лимитом и содержимым.

Он использует заданные left и right документы как окружающие и документ-разделитель separator для разделения элементов в docs. Если все элементы в коллекции являются простыми документами (текстами или строками), то эта функция пытается поместить как можно больше элементов в одну строку. Если это не так, то по одной записи на строку отображается только один элемент, если они не помещаются.

Предел в заданном Inspect.Opts соблюдается, и при достижении предела эта функция прекращает обработку и выводит "..." вместо этого.

Параметры

:separator - разделитель, используемый между каждым документом
:break - Если :strict, всегда разрывать между каждым элементом. Если :flex, разрывы только при необходимости. Если :maybe, выбирает :flex только если все элементы основаны на тексте, иначе :strict

Примеры

iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]",
...>         %Inspect.Opts{limit: :infinity}, fn i, _opts -> to_string(i) end)
iex> Inspect.Algebra.format(doc, 5) |> IO.iodata_to_binary
"[1,\n 2,\n 3,\n 4,\n 5]"

iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]",
...>         %Inspect.Opts{limit: 3}, fn i, _opts -> to_string(i) end)
iex> Inspect.Algebra.format(doc, 20) |> IO.iodata_to_binary
"[1, 2, 3, ...]"

iex> doc = Inspect.Algebra.container_doc("[", Enum.to_list(1..5), "]",
...>         %Inspect.Opts{limit: 3}, fn i, _opts -> to_string(i) end, separator: "!")
iex> Inspect.Algebra.format(doc, 20) |> IO.iodata_to_binary
"[1! 2! 3! ...]"

empty()

empty() :: :doc_nil

Возвращает сущность документа, используемую для представления пустоты.

Примеры

iex> Inspect.Algebra.empty
:doc_nil

flex_break(string \\ " ")

flex_break(binary()) :: doc_break()

Возвращает документ гибкого разрыва, основанный на заданном string.

Гибкий разрыв всё ещё заставляет группу прерываться, как break/1, но он переоценивается при отрисовке документа.

Например, рассмотрите документ группы, представленный как [1, 2, 3], где пробел после каждой запятой является разрывом. Когда документ выше не помещается в одну строку, все разрывы включаются, что приводит к отображению документа как:

[1,
 2,
 3]

Однако, если используются перерывы flex, каждый перерыв переоценивается при рендеринге, поэтому документ может быть отображен следующим образом:

[1, 2,
 3]

Отсюда и название «flex». Они более гибкие, когда дело доходит до подгонки документа. С другой стороны, они более ресурсоемки, так как каждый перерыв необходимо переоценивать.

Эта функция используется container_doc/4 и аналогичными функциями для максимального количества записей в одной строке.

flex_glue(doc1, break_string \\ " ", doc2)

flex_glue(t(), binary(), t()) :: t()

Склеивает два документа (doc1 и doc2) с вставкой flex_break/1, заданного break_string между ними.

Эта функция используется container_doc/6 и аналогичными функциями для максимального количества записей в одной строке.

fold_doc(docs, folder_fun)

fold_doc([t()], (t(), t() -> t())) :: t()

Складывает список документов в документ с использованием заданной функции сложения.

Список документов складывается «справа»; в этом функция похожа на List.foldr/3, за исключением того, что она не ожидает начального накопителя и использует последний элемент docs в качестве начального накопителя.

Примеры

iex> docs = ["A", "B", "C"]
iex> docs = Inspect.Algebra.fold_doc(docs, fn(doc, acc) ->
...>   Inspect.Algebra.concat([doc, "!", acc])
...> end)
iex> Inspect.Algebra.format(docs, 80)
["A", "!", "B", "!", "C"]

force_unfit(doc)

force_unfit(t()) :: doc_force()

Принудительно делает текущую группу непригодной.

format(doc, width)

format(t(), non_neg_integer() | :infinity) :: iodata()

Форматирует заданный документ для заданной ширины.

Принимает максимальную ширину и документ для печати в качестве аргументов и возвращает представление данных IO лучшего макета для отображения документа в заданной ширине.

Документ начинается плоским (без перерывов) до тех пор, пока не будет найдена группа.

Примеры

iex> doc = Inspect.Algebra.glue("hello", " ", "world")
iex> doc = Inspect.Algebra.group(doc)
iex> doc |> Inspect.Algebra.format(30) |> IO.iodata_to_binary()
"hello world"
iex> doc |> Inspect.Algebra.format(10) |> IO.iodata_to_binary()
"hello\nworld"

glue(doc1, break_string \\ " ", doc2)

glue(t(), binary(), t()) :: t()

Склеивает два документа (doc1 и doc2) с вставкой заданного разрыва break_string между ними.

Для получения дополнительной информации о том, как вставляется разрыв, см. break/1.

Примеры

iex> doc = Inspect.Algebra.glue("hello", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", " ", "world"]

iex> doc = Inspect.Algebra.glue("hello", "\t", "world")
iex> Inspect.Algebra.format(doc, 80)
["hello", "\t", "world"]

group(doc, mode \\ :self)

Возвращает группу, содержащую указанный документ doc.

Документы в группе пытаются отображаться вместе по возможности.

Режим группы также может быть установлен на :inherit, что означает автоматическое прерывание, если родительская группа также прервана.

Примеры

iex> doc = Inspect.Algebra.group(
...>   Inspect.Algebra.concat(
...>     Inspect.Algebra.group(
...>       Inspect.Algebra.concat(
...>         "Hello,",
...>         Inspect.Algebra.concat(
...>           Inspect.Algebra.break,
...>           "A"
...>         )
...>       )
...>     ),
...>     Inspect.Algebra.concat(
...>       Inspect.Algebra.break,
...>       "B"
...>     )
...> ))
iex> Inspect.Algebra.format(doc, 80)
["Hello,", " ", "A", " ", "B"]
iex> Inspect.Algebra.format(doc, 6)
["Hello,", "\n", "A", "\n", "B"]

line()

line() :: t()

Обязательный перевод строки.

Группа с переводами строк поместится, если все строки в группе поместятся.

Примеры

iex> doc = Inspect.Algebra.concat( …> Inspect.Algebra.concat( …> “Hughes”, …> Inspect.Algebra.line() …> ), “Wadler” …> ) iex> Inspect.Algebra.format(doc, 80) [“Hughes”, “\n”, “Wadler”]

line(doc1, doc2)

line(t(), t()) :: t()

Вставляет обязательный перевод строки между двумя документами.

См. line/1.

Примеры

iex> doc = Inspect.Algebra.line("Hughes", "Wadler")
iex> Inspect.Algebra.format(doc, 80)
["Hughes", "\n", "Wadler"]

nest(doc, level, mode \\ :always)

Вкладывает данный документ на данный level.

Если level — целое число, это отступ, добавляемый к переводам строк при их появлении. Если уровень равен :cursor, текущее положение «курсора» в документе становится вложенным. Если уровень равен :reset, он устанавливается обратно в 0.

mode может быть :always, что означает, что вложение всегда происходит, или :break, что означает, что вложение происходит только внутри группы, которая была прервана.

Примеры

iex> doc = Inspect.Algebra.nest(Inspect.Algebra.glue("hello", "world"), 5)
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 5)
["hello", "\n     ", "world"]

next_break_fits(doc, mode \\ :enabled)

Рассматривает следующий разрыв как подходящий.

mode может быть :enabled или :disabled. В случае :enabled, документ будет считаться подходящим, как только будет найден следующий разрыв, эффективно отменяя разрыв. Он также проигнорирует любые force_unfit/1 при поиске следующего разрыва.

В случае отключения он ведет себя как обычно и игнорирует любые дальнейшие инструкции next_break_fits/2.

Примеры

Это используется в форматировщике кода Elixir для предотвращения разрыва кода в некоторых определенных местах. Например, рассмотрите этот код:

some_function_call(%{..., key: value, ...})

Теперь представьте, что этот код не помещается в строку. Форматировщик кода вводит разрывы внутри ( и ) и внутри %{ и }. Поэтому документ был бы прерван так:

some_function_call(
  %{
    ...,
    key: value,
    ...
  }
)

Форматировщик оборачивает алгебраический документ, представляющий карту, в next_break_fits/1, поэтому код форматируется следующим образом:

some_function_call(%{
  ...,
  key: value,
  ...
})

space(doc1, doc2)

space(t(), t()) :: t()

Вставляет обязательный одиночный пробел между двумя документами.

Примеры

iex> doc = Inspect.Algebra.space("Hughes", "Wadler")
iex> Inspect.Algebra.format(doc, 5)
["Hughes", " ", "Wadler"]

string(string)

string(String.t()) :: doc_string()

Создаёт документ, представленный строкой.

В то время как Inspect.Algebra принимает двоичные данные в качестве документов, они учитываются по размеру двоичных данных. С другой стороны, документы string измеряются в терминах графем по отношению к размеру документа.

Примеры

Следующий документ имеет 10 байтов и поэтому не форматируется до ширины 9 без разрывов:

iex> doc = Inspect.Algebra.glue("olá", " ", "mundo")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 9)
["olá", "\n", "mundo"]

Однако, если мы используем string, длина строки используется вместо размера байта, что правильно подходит:

iex> string = Inspect.Algebra.string("olá")
iex> doc = Inspect.Algebra.glue(string, " ", "mundo")
iex> doc = Inspect.Algebra.group(doc)
iex> Inspect.Algebra.format(doc, 9)
["olá", " ", "mundo"]

to_doc(term, opts)

to_doc(any(), Inspect.Opts.t()) :: t()

Преобразует термин Elixir в алгебраический документ в соответствии с протоколом Inspect.

© 2012 Plataformatec
Licensed under the Apache License, Version 2.0.
https://hexdocs.pm/elixir/1.6.6/Inspect.Algebra.html