Время

Структура Time и функции.

Структура Time содержит поля час, минута, секунда и микросекунды. Новые времена можно создать с помощью функции new/4 или используя сигил ~T.

iex> ~T[23:00:07.001]
~T[23:00:07.001]

И new/4, и сигил возвращают структуру, где поля времени можно получить напрямую:

iex> time = ~T[23:00:07.001]
iex> time.hour
23
iex> time.microsecond
{1000, 3}

Функции в этом модуле работают со структурой Time, а также с любой структурой, содержащей те же поля, что и структура Time, такие как NaiveDateTime и DateTime. Такие функции ожидают Calendar.time/0 в своих типовспеках (вместо t/0).

Разработчики должны избегать непосредственного создания структур Time и вместо этого полагаться на функции, предоставляемые этим модулем, а также на функции библиотек календарей сторонних разработчиков.

Сравнение времен

Сравнения в Elixir с использованием ==, >, < и подобных основаны на структуре Time. Для правильного сравнения времен используйте функцию compare/2.

Резюме

Типы

t()

Функции

add(time, number, unit \\ :second): Добавляет number unit к заданному time
compare(time1, time2): Сравнивает две структуры времени
convert(time, calendar): Преобразует данное time в другой календарь
convert!(time, calendar): Аналогично Time.convert/2, но вызывает ArgumentError, если преобразование между двумя календарями невозможно
diff(time1, time2, unit \\ :second): Возвращает разницу между двумя временами, учитывая только час, минуту, секунду и микросекунду
from_erl(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO): Преобразует кортеж времени Erlang в структуру Time
from_erl!(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO): Преобразует кортеж времени Erlang в структуру Time
from_iso8601(string, calendar \\ Calendar.ISO): Парсит расширенный формат «Локальное время», описанный в ISO 8601:2004
from_iso8601!(string, calendar \\ Calendar.ISO): Парсит расширенный формат «Локальное время», описанный в ISO 8601:2004
new(hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO): Создает новое время
to_erl(time): Преобразует данное time в кортеж времени Erlang
to_iso8601(time, format \\ :extended): Преобразует заданное время в ISO 8601:2004
to_string(time): Преобразует заданное time в строку
truncate(time, precision): Возвращает заданное время с полем микросекунд, усеченным до заданной точности (:microsecond, millisecond или :second)
utc_now(calendar \\ Calendar.ISO): Возвращает текущее время в UTC

Типы

t()

t() :: %Time{
  calendar: Calendar.calendar(),
  hour: Calendar.hour(),
  microsecond: Calendar.microsecond(),
  minute: Calendar.minute(),
  second: Calendar.second()
}

Функции

add(time, number, unit \\ :second)

add(Calendar.time(), integer(), System.time_unit()) :: t()

Добавляет number unit к заданному time.

Эта функция принимает number, измеренное в соответствии с Calendar.ISO. Время возвращается в том же календаре, в котором оно было задано.

Обратите внимание, что возвращаемое значение представляет время суток, то есть оно циклическое, например, для календаря ISO оно никогда не превысит 24 часов.

Примеры

iex> Time.add(~T[10:00:00], 27000)
~T[17:30:00.000000]
iex> Time.add(~T[11:00:00.005], 2400)
~T[11:40:00.005000]
iex> Time.add(~T[00:00:00], 86399999, :millisecond)
~T[23:59:59.999000]
iex> Time.add(~T[17:10:05], 86400)
~T[17:10:05.000000]
iex> Time.add(~T[23:00:00], -60)
~T[22:59:00.000000]

compare(time1, time2)

compare(Calendar.time(), Calendar.time()) :: :lt | :eq | :gt

Сравнивает две структуры времени.

Возвращает :gt , если первое время позже второго, и :lt в противном случае. Если два времени равны, возвращается :eq.

Примеры

iex> Time.compare(~T[16:04:16], ~T[16:04:28])
:lt
iex> Time.compare(~T[16:04:16], ~T[16:04:16])
:eq
iex> Time.compare(~T[16:04:16.01], ~T[16:04:16.001])
:gt

Эта функция также может использоваться для сравнения в более сложных типах календарей, рассматривая только поля времени:

iex> Time.compare(~N[1900-01-01 16:04:16], ~N[2015-01-01 16:04:16])
:eq
iex> Time.compare(~N[2015-01-01 16:04:16], ~N[2015-01-01 16:04:28])
:lt
iex> Time.compare(~N[2015-01-01 16:04:16.01], ~N[2000-01-01 16:04:16.001])
:gt

convert(time, calendar)

convert(Calendar.time(), Calendar.calendar()) ::
  {:ok, t()} | {:error, atom()}

Преобразует заданное time в другой календарь.

Возвращает {:ok, time} , если преобразование было успешным, или {:error, reason} , если оно не удалось по какой-либо причине.

Примеры

Представьте, что кто-то реализовал Calendar.Holocene, календарь, основанный на григорианском календаре, который добавляет ровно 10 000 лет к текущему григорианскому году:

iex> Time.convert(~T[13:30:15], Calendar.Holocene)
{:ok, %Time{calendar: Calendar.Holocene, hour: 13, minute: 30, second: 15, microsecond: {0, 0}}}

convert!(time, calendar)

convert!(Calendar.time(), Calendar.calendar()) :: t()

Аналогично Time.convert/2, но вызывает исключение ArgumentError, если преобразование между двумя календарями невозможно.

Примеры

iex> Time.convert!(~T[13:30:15], Calendar.Holocene)
%Time{calendar: Calendar.Holocene, hour: 13, minute: 30, second: 15, microsecond: {0, 0}}

diff(time1, time2, unit \\ :second)

diff(Calendar.time(), Calendar.time(), System.time_unit()) :: integer()

Возвращает разницу между двумя временами, учитывая только час, минуту, секунду и микросекунду.

Как и в функции compare/2, могут быть использованы как структуры Time, так и другие структуры, содержащие время. Например, если передается NaiveDateTime или DateTime, учитываются только час, минута, секунда и микросекунда. Любая дополнительная информация о дате или часовом поясе игнорируется при вычислении разницы.

Ответ может быть возвращен в любом unit , доступном из System.time_unit/0. Если первая единица меньше второй, возвращается отрицательное число.

Эта функция возвращает разницу в секундах, где секунды измеряются в соответствии с Calendar.ISO.

Примеры

iex> Time.diff(~T[00:29:12], ~T[00:29:10])
2

# When passing a [`NaiveDateTime`](NaiveDateTime.html) the date part is ignored.
iex> Time.diff(~N[2017-01-01 00:29:12], ~T[00:29:10])
2

# Two [`NaiveDateTime`](NaiveDateTime.html) structs could have big differences in the date
# but only the time part is considered.
iex> Time.diff(~N[2017-01-01 00:29:12], (~N[1900-02-03 00:29:10]))
2

iex> Time.diff(~T[00:29:12], ~T[00:29:10], :microsecond)
2_000_000
iex> Time.diff(~T[00:29:10], ~T[00:29:12], :microsecond)
-2_000_000

from_erl(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

from_erl(:calendar.time(), Calendar.microsecond(), Calendar.calendar()) ::
  {:ok, t()} | {:error, atom()}

Преобразует кортеж времени Erlang в структуру Time.

Примеры

iex> Time.from_erl({23, 30, 15}, {5000, 3})
{:ok, ~T[23:30:15.005]}
iex> Time.from_erl({24, 30, 15})
{:error, :invalid_time}

from_erl!(tuple, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

from_erl!(:calendar.time(), Calendar.microsecond(), Calendar.calendar()) ::
  t()

Преобразует кортеж времени Erlang в структуру Time.

Примеры

iex> Time.from_erl!({23, 30, 15})
~T[23:30:15]
iex> Time.from_erl!({23, 30, 15}, {5000, 3})
~T[23:30:15.005]
iex> Time.from_erl!({24, 30, 15})
** (ArgumentError) cannot convert {24, 30, 15} to time, reason: :invalid_time

from_iso8601(string, calendar \\ Calendar.ISO)

from_iso8601(String.t(), Calendar.calendar()) ::
  {:ok, t()} | {:error, atom()}

Парсит расширенный формат «Локальное время», описанный в ISO 8601:2004.

Смещение часового пояса может быть включено в строку, но оно будет просто проигнорировано, так как такая информация не включена во время.

Как указано в стандарте, разделитель «T» можно опустить при необходимости, так как в этой функции нет неоднозначности.

Представления времени с уменьшенной точностью не поддерживаются.

Обратите внимание, что, хотя ISO 8601 допускает указание времени 24:00:00 как нулевого часа следующего дня, эта запись не поддерживается Elixir.

Примеры

iex> Time.from_iso8601("23:50:07")
{:ok, ~T[23:50:07]}
iex> Time.from_iso8601("23:50:07Z")
{:ok, ~T[23:50:07]}
iex> Time.from_iso8601("T23:50:07Z")
{:ok, ~T[23:50:07]}

iex> Time.from_iso8601("23:50:07,0123456")
{:ok, ~T[23:50:07.012345]}
iex> Time.from_iso8601("23:50:07.0123456")
{:ok, ~T[23:50:07.012345]}
iex> Time.from_iso8601("23:50:07.123Z")
{:ok, ~T[23:50:07.123]}

iex> Time.from_iso8601("2015:01:23 23-50-07")
{:error, :invalid_format}
iex> Time.from_iso8601("23:50:07A")
{:error, :invalid_format}
iex> Time.from_iso8601("23:50:07.")
{:error, :invalid_format}
iex> Time.from_iso8601("23:50:61")
{:error, :invalid_time}

from_iso8601!(string, calendar \\ Calendar.ISO)

from_iso8601!(String.t(), Calendar.calendar()) :: t()

Парсит расширенный формат «Локальное время», описанный в ISO 8601:2004.

Возникает исключение, если формат неверный.

Примеры

iex> Time.from_iso8601!("23:50:07,123Z")
~T[23:50:07.123]
iex> Time.from_iso8601!("23:50:07.123Z")
~T[23:50:07.123]
iex> Time.from_iso8601!("2015:01:23 23-50-07")
** (ArgumentError) cannot parse "2015:01:23 23-50-07" as time, reason: :invalid_format

new(hour, minute, second, microsecond \\ {0, 0}, calendar \\ Calendar.ISO)

new(
  Calendar.hour(),
  Calendar.minute(),
  Calendar.second(),
  Calendar.microsecond() | integer(),
  Calendar.calendar()
) :: {:ok, t()} | {:error, atom()}

Создает новое время.

Ожидаются все целочисленные значения. Возвращает {:ok, time} , если каждое значение находится в допустимом диапазоне; возвращает {:error, reason} в противном случае.

Обратите внимание, что время может иметь 60 секунд в случае високосных секунд. Микросекунды также могут быть заданы с точностью, которая должна быть целым числом от 0 до 6.

Примеры

iex> Time.new(0, 0, 0, 0)
{:ok, ~T[00:00:00.000000]}
iex> Time.new(23, 59, 59, 999_999)
{:ok, ~T[23:59:59.999999]}
iex> Time.new(23, 59, 60, 999_999)
{:ok, ~T[23:59:60.999999]}

# Time with microseconds and their precision
iex> Time.new(23, 59, 60, {10_000, 2})
{:ok, ~T[23:59:60.01]}

iex> Time.new(24, 59, 59, 999_999)
{:error, :invalid_time}
iex> Time.new(23, 60, 59, 999_999)
{:error, :invalid_time}
iex> Time.new(23, 59, 61, 999_999)
{:error, :invalid_time}
iex> Time.new(23, 59, 59, 1_000_000)
{:error, :invalid_time}

# Invalid precision
Time.new(23, 59, 59, {999_999, 10})
{:error, :invalid_time}

to_erl(time)

to_erl(Calendar.time()) :: :calendar.time()

Преобразует заданное time в кортеж времени Erlang.

ВНИМАНИЕ: Может произойти потеря точности, так как кортежи времени Erlang содержат только часы/минуты/секунды.

Примеры

iex> Time.to_erl(~T[23:30:15.999])
{23, 30, 15}

iex> Time.to_erl(~N[2010-04-17 23:30:15.999])
{23, 30, 15}

to_iso8601(time, format \\ :extended)

to_iso8601(Calendar.time(), :extended | :basic) :: String.t()

Преобразует заданное время в формат ISO 8601:2004.

По умолчанию, Time.to_iso8601/2 возвращает время в формате «расширенном» для удобства чтения человеком. Также поддерживается формат «базовый» через передачу :basic опции.

Примеры

iex> Time.to_iso8601(~T[23:00:13])
"23:00:13"

iex> Time.to_iso8601(~T[23:00:13.001])
"23:00:13.001"

iex> Time.to_iso8601(~T[23:00:13.001], :basic)
"230013.001"

iex> Time.to_iso8601(~N[2010-04-17 23:00:13])
"23:00:13"

to_string(time)

to_string(Calendar.time()) :: String.t()

Преобразует заданное time в строку.

Примеры

iex> Time.to_string(~T[23:00:00])
"23:00:00"
iex> Time.to_string(~T[23:00:00.001])
"23:00:00.001"
iex> Time.to_string(~T[23:00:00.123456])
"23:00:00.123456"

iex> Time.to_string(~N[2015-01-01 23:00:00.001])
"23:00:00.001"
iex> Time.to_string(~N[2015-01-01 23:00:00.123456])
"23:00:00.123456"

truncate(time, precision)

truncate(t(), :microsecond | :millisecond | :second) :: t()

Возвращает заданное время с усечённым полем микросекунд до заданной точности (:microsecond, millisecond или :second).

Примеры

iex> Time.truncate(~T[01:01:01.123456], :microsecond)
~T[01:01:01.123456]

iex> Time.truncate(~T[01:01:01.123456], :millisecond)
~T[01:01:01.123]

iex> Time.truncate(~T[01:01:01.123456], :second)
~T[01:01:01]

utc_now(calendar \\ Calendar.ISO)

utc_now(Calendar.calendar()) :: t()

Возвращает текущее время в UTC.

Примеры

iex> time = Time.utc_now()
iex> time.hour >= 0
true