Карта

Набор функций для работы с картами.

Многие функции для карт, которые реализуют протокол Enumerable, находятся в модуле Enum. Кроме того, следующие функции для карт находятся в Kernel:

map_size/1

Карты являются основной структурой данных «ключ-значение» в Elixir. Карты можно создать с помощью синтаксиса %{}, а пары «ключ-значение» можно выразить как key => value:

iex> %{}
%{}
iex> %{"one" => :two, 3 => "four"}
%{3 => "four", "one" => :two}

Пары «ключ-значение» в карте не следуют никакому порядку (поэтому отпечатанная карта в примере выше имеет другой порядок, чем карта, которая была создана).

Карты не накладывают никаких ограничений на тип ключа: чем угодно может быть ключ в карте. Как структура «ключ-значение», карты не допускают дублирующих ключей. Ключи сравниваются с помощью оператора точного равенства (===/2). Если в литерале карты определены коллидирующие ключи, преобладает последний.

Когда ключ в паре «ключ-значение» является атомом, можно использовать сокращённый синтаксис key: value (как и во многих других специальных формах), при условии, что пары «ключ-значение» помещаются в конце:

iex> %{"hello" => "world", a: 1, b: 2}
%{:a => 1, :b => 2, "hello" => "world"}

К ключам в картах можно получить доступ через некоторые функции в этом модуле (например, Map.get/3 или Map.fetch/2) или через синтаксис map[], предоставляемый модулем Access:

iex> map = %{a: 1, b: 2}
iex> Map.fetch(map, :a)
{:ok, 1}
iex> map[:b]
2
iex> map["non_existing_key"]
nil

Для доступа к ключам-атомам также можно map.key. Обратите внимание, что в то время как map[key] вернёт nil если map не содержит key, map.key вызовет исключение, если map не содержит ключ :key.

iex> map = %{foo: "bar", baz: "bong"}
iex> map.foo
"bar"
iex> map.non_existing_key
** (KeyError) key :non_existing_key not found in: %{baz: "bong", foo: "bar"}

Два синтаксиса для доступа к ключам раскрывают двойственную природу карт. Синтаксис map[key] используется для динамически создаваемых карт, которые могут иметь любой ключ любого типа. map.key используется с картами, которые содержат предопределённый набор ключей-атомов, которые ожидается, что всегда будут присутствовать. Структуры, определённые с помощью defstruct/1, являются одним из примеров таких «статических карт», где ключи также могут быть проверены во время компиляции.

Карты можно использовать в шаблонах. Когда карта находится в левой части шаблона, она будет соответствовать, если карта в правой части содержит ключи в левой части и их значения соответствуют значениям в левой части. Это означает, что пустая карта соответствует любой карте.

iex> %{} = %{foo: "bar"}
%{foo: "bar"}
iex> %{a: a} = %{:a => 1, "b" => 2, [:c, :e, :e] => 3}
iex> a
1
iex> %{:c => 3} = %{:a => 1, 2 => :b}
** (MatchError) no match of right hand side value: %{2 => :b, :a => 1}

Переменные могут использоваться в качестве ключей карты как при написании литералов карты, так и при сопоставлении:

iex> n = 1
1
iex> %{n => :one}
%{1 => :one}
iex> %{^n => :one} = %{1 => :one, 2 => :two, 3 => :three}
%{1 => :one, 2 => :two, 3 => :three}

Карты также поддерживают специфичный синтаксис обновления для обновления значения, хранящегося по существующим ключам-атомам:

iex> map = %{one: 1, two: 2}
iex> %{map | one: "one"}
%{one: "one", two: 2}
iex> %{map | three: 3}
** (KeyError) key :three not found

Краткое описание

Функции

delete(map, key): Удаляет запись в map для определенного key
drop(map, keys): Удаляет заданные keys из map
equal?(map1, map2): Проверяет, равны ли две карты
fetch!(map, key): Получает значение для определенного key в заданной map, возвращая ошибку, если map не содержит key
fetch(map, key): Получает значение для определенного key в заданной map
from_struct(struct): Преобразует struct в карту
get(map, key, default \\ nil): Получает значение для определенного key в map
get_and_update!(map, key, fun): Получает значение из key и обновляет его. Возвращает ошибку, если нет key
get_and_update(map, key, fun): Получает значение из key и обновляет его за один проход
get_lazy(map, key, fun): Получает значение для определенного key в map
has_key?(map, key): Возвращает, существует ли данный key в данной map
keys(map): Возвращает все ключи из map
merge(map1, map2): Объединяет две карты в одну
merge(map1, map2, fun): Объединяет две карты в одну, разрешая конфликты с помощью заданной fun
new(): Возвращает новую пустую карту
new(enumerable): Создаёт карту из enumerable
new(enumerable, transform): Создаёт карту из enumerable с помощью заданной функции преобразования
pop(map, key, default \\ nil): Возвращает и удаляет значение, связанное с key в map
pop_lazy(map, key, fun): Лениво возвращает и удаляет значение, связанное с key в map
put(map, key, value): Помещает заданное value под key в map
put_new(map, key, value): Помещает заданное value под key если запись key ещё не существует в map
put_new_lazy(map, key, fun): Вычисляет fun и помещает результат под key в map если key ещё не присутствует
replace!(map, key, value): Изменяет значение, хранящееся под key на value, но только если запись key уже существует в map
split(map, keys): Берёт все записи, соответствующие заданным keys в map и извлекает их в отдельную карту
take(map, keys): Возвращает новую карту со всеми парами «ключ-значение» в map где ключ находится в keys
to_list(map): Преобразует map в список
update!(map, key, fun): Обновляет key с помощью данной функции
update(map, key, initial, fun): Обновляет key в map с помощью заданной функции
values(map): Возвращает все значения из map

Типы

key()

key() :: any()

value()

value() :: any()

Функции

delete(map, key)

delete(map(), key()) :: map()

Удаляет запись в map для определенного key.

Если key не существует, возвращает map без изменений.

Встроено компилятором.

Примеры

iex> Map.delete(%{a: 1, b: 2}, :a)
%{b: 2}
iex> Map.delete(%{b: 2}, :a)
%{b: 2}

drop(map, keys)

drop(map(), Enumerable.t()) :: map()

Удаляет заданные keys из map.

Если keys содержит ключи, которые не находятся в map, они просто игнорируются.

Примеры

iex> Map.drop(%{a: 1, b: 2, c: 3}, [:b, :d])
%{a: 1, c: 3}

equal?(map1, map2)

equal?(map(), map()) :: boolean()

Проверяет, равны ли две карты.

Две карты считаются равными, если они содержат одинаковые ключи и эти ключи содержат одинаковые значения.

Примеры

iex> Map.equal?(%{a: 1, b: 2}, %{b: 2, a: 1})
true
iex> Map.equal?(%{a: 1, b: 2}, %{b: 1, a: 2})
false

fetch!(map, key)

fetch!(map(), key()) :: value() | no_return()

Получает значение для определенного key в заданной map, возвращая ошибку, если map не содержит key.

Если map содержит данный key, возвращается соответствующее значение. Если map не содержит key, генерируется исключение KeyError.

Встроено компилятором.

Примеры

iex> Map.fetch!(%{a: 1}, :a)
1
iex> Map.fetch!(%{a: 1}, :b)
** (KeyError) key :b not found in: %{a: 1}

fetch(map, key)

fetch(map(), key()) :: {:ok, value()} | :error

Извлекает значение для определённого key в заданном map.

Если map содержит заданный key со значением value, то возвращается {:ok, value} . Если map не содержит key, возвращается :error.

Встраивается компилятором.

Примеры

iex> Map.fetch(%{a: 1}, :a)
{:ok, 1}
iex> Map.fetch(%{a: 1}, :b)
:error

from_struct(struct)

from_struct(atom() | struct()) :: map()

Преобразует struct в карту.

Принимает модуль структуры или саму структуру и просто удаляет поле __struct__ из заданной структуры или из новой структуры, сгенерированной из данного модуля.

Пример

defmodule User do
  defstruct [:name]
end

Map.from_struct(User)
#=> %{name: nil}

Map.from_struct(%User{name: "john"})
#=> %{name: "john"}

get(map, key, default \\ nil)

get(map(), key(), value()) :: value()

Получает значение для определённого key в map.

Если key присутствует в map со значением value, возвращается value . В противном случае, возвращается default (которое равно nil, если не указано иное).

Примеры

iex> Map.get(%{}, :a)
nil
iex> Map.get(%{a: 1}, :a)
1
iex> Map.get(%{a: 1}, :b)
nil
iex> Map.get(%{a: 1}, :b, 3)
3

get_and_update!(map, key, fun)

get_and_update!(map(), key(), (value() -> {get, value()} | :pop)) ::
  {get, map()} | no_return()
when get: term()

Получает значение из key и обновляет его. Вызывает исключение, если key отсутствует.

Ведёт себя точно так же, как get_and_update/3, но вызывает исключение KeyError, если key отсутствует в map.

Примеры

iex> Map.get_and_update!(%{a: 1}, :a, fn current_value ->
...>   {current_value, "new value!"}
...> end)
{1, %{a: "new value!"}}

iex> Map.get_and_update!(%{a: 1}, :b, fn current_value ->
...>   {current_value, "new value!"}
...> end)
** (KeyError) key :b not found in: %{a: 1}

iex> Map.get_and_update!(%{a: 1}, :a, fn _ ->
...>   :pop
...> end)
{1, %{}}

get_and_update(map, key, fun)

get_and_update(map(), key(), (value() -> {get, value()} | :pop)) ::
  {get, map()}
when get: term()

Получает значение из key и обновляет его за один проход.

fun вызывается с текущим значением под key в map (или nil, если key не присутствует в map) и должно вернуть кортеж из двух элементов: значение «получить» (полученное значение, которое может быть обработано перед возвратом) и новое значение для хранения под key в результирующей новой карте. fun также может вернуть :pop, что означает, что текущее значение должно быть удалено из map и возвращено (что делает эту функцию похожей на Map.pop(map, key)).

Возвращаемое значение представляет собой кортеж со значением «получить», возвращённым fun, и новой картой с обновлённым значением под key.

Примеры

iex> Map.get_and_update(%{a: 1}, :a, fn current_value ->
...>   {current_value, "new value!"}
...> end)
{1, %{a: "new value!"}}

iex> Map.get_and_update(%{a: 1}, :b, fn current_value ->
...>   {current_value, "new value!"}
...> end)
{nil, %{b: "new value!", a: 1}}

iex> Map.get_and_update(%{a: 1}, :a, fn _ -> :pop end)
{1, %{}}

iex> Map.get_and_update(%{a: 1}, :b, fn _ -> :pop end)
{nil, %{a: 1}}

get_lazy(map, key, fun)

get_lazy(map(), key(), (() -> value())) :: value()

Получает значение для определённого key в map.

Если key присутствует в map со значением value, возвращается value . В противном случае, вычисляется fun и возвращается его результат.

Это полезно, если значение по умолчанию очень дорого вычисляется или вообще сложно настроить и разобрать снова.

Примеры

iex> map = %{a: 1}
iex> fun = fn ->
...>   # some expensive operation here
...>   13
...> end
iex> Map.get_lazy(map, :a, fun)
1
iex> Map.get_lazy(map, :b, fun)
13

has_key?(map, key)

has_key?(map(), key()) :: boolean()

Возвращает, существует ли заданный key в заданной map.

Встраивается компилятором.

Примеры

iex> Map.has_key?(%{a: 1}, :a)
true
iex> Map.has_key?(%{a: 1}, :b)
false

keys(map)

keys(map()) :: [key()]

Возвращает все ключи из map.

Встраивается компилятором.

Примеры

iex> Map.keys(%{a: 1, b: 2})
[:a, :b]

merge(map1, map2)

merge(map(), map()) :: map()

Объединяет две карты в одну.

Все ключи в map2 будут добавлены в map1, перезаписывая любые существующие (т.е., ключи в map2 имеют «преимущество» над ключами в map1).

Если у вас есть структура, и вы хотите объединить набор ключей в структуру, не используйте эту функцию, так как она объединит все ключи справа в структуру, даже если ключ не является частью структуры. Вместо этого используйте Kernel.struct/2.

Встраивается компилятором.

Примеры

iex> Map.merge(%{a: 1, b: 2}, %{a: 3, d: 4})
%{a: 3, b: 2, d: 4}

merge(map1, map2, fun)

merge(map(), map(), (key(), value(), value() -> value())) :: map()

Объединяет две карты в одну, разрешая конфликты с помощью данной fun.

Все ключи в map2 будут добавлены в map1. Указанная функция будет вызвана при наличии дублирующих ключей; её аргументы — key (дублирующий ключ), value1 (значение key в map1 ), и value2 (значение key в map2). Возвращаемое значение fun используется в качестве значения под key в результирующей карте.

Примеры

iex> Map.merge(%{a: 1, b: 2}, %{a: 3, d: 4}, fn _k, v1, v2 ->
...>   v1 + v2
...> end)
%{a: 4, b: 2, d: 4}

new()

new() :: map()

Возвращает новую пустую карту.

Примеры

iex> Map.new()
%{}

new(enumerable)

new(Enumerable.t()) :: map()

Создаёт карту из enumerable.

Дублируемые ключи удаляются; сохраняется последнее значение.

Примеры

iex> Map.new([{:b, 1}, {:a, 2}])
%{a: 2, b: 1}
iex> Map.new([a: 1, a: 2, a: 3])
%{a: 3}

new(enumerable, transform)

new(Enumerable.t(), (term() -> {key(), value()})) :: map()

Создаёт карту из enumerable с помощью заданной функции преобразования.

Дублируемые ключи удаляются; сохраняется последнее значение.

Примеры

iex> Map.new([:a, :b], fn x -> {x, x} end)
%{a: :a, b: :b}

pop(map, key, default \\ nil)

pop(map(), key(), value()) :: {value(), map()}

Возвращает и удаляет значение, связанное с key в map.

Если key присутствует в map со значением value, возвращается {value, new_map}, где new_map — результат удаления key из map . Если key отсутствует в map, возвращается {default, map}.

Примеры

iex> Map.pop(%{a: 1}, :a)
{1, %{}}
iex> Map.pop(%{a: 1}, :b)
{nil, %{a: 1}}
iex> Map.pop(%{a: 1}, :b, 3)
{3, %{a: 1}}

pop_lazy(map, key, fun)

pop_lazy(map(), key(), (() -> value())) :: {value(), map()}

Лениво возвращает и удаляет значение, связанное с key в map.

Примеры

iex> map = %{a: 1}
iex> fun = fn ->
...>   # some expensive operation here
...>   13
...> end
iex> Map.pop_lazy(map, :a, fun)
{1, %{}}
iex> Map.pop_lazy(map, :b, fun)
{13, %{a: 1}}

put(map, key, value)

put(map(), key(), value()) :: map()

Сохраняет заданное value под key в map.

Встраивается компилятором.

Примеры

iex> Map.put(%{a: 1}, :b, 2)
%{a: 1, b: 2}
iex> Map.put(%{a: 1, b: 2}, :a, 3)
%{a: 3, b: 2}

put_new(map, key, value)

put_new(map(), key(), value()) :: map()

Сохраняет заданное value под key , если запись key ещё не существует в map.

Примеры

iex> Map.put_new(%{a: 1}, :b, 2)
%{a: 1, b: 2}
iex> Map.put_new(%{a: 1, b: 2}, :a, 3)
%{a: 1, b: 2}

put_new_lazy(map, key, fun)

put_new_lazy(map(), key(), (() -> value())) :: map()

Вычисляет fun и сохраняет результат под key в map , если запись key ещё не существует.

Эта функция полезна в случае, когда вы хотите вычислить значение для хранения под key только в том случае, если key ещё не существует (например, если вычисление значения дорогостоящее или его сложно настраивать и разбирать).

Примеры

iex> map = %{a: 1}
iex> fun = fn ->
...>   # some expensive operation here
...>   3
...> end
iex> Map.put_new_lazy(map, :a, fun)
%{a: 1}
iex> Map.put_new_lazy(map, :b, fun)
%{a: 1, b: 3}

replace!(map, key, value) (since 1.5.0)

replace!(map(), key(), value()) :: map()

Изменяет значение, хранящееся под key на value, только если запись key уже существует в map.

Если key отсутствует в map, генерируется исключение KeyError.

Встраивается компилятором.

Примеры

iex> Map.replace!(%{a: 1, b: 2}, :a, 3)
%{a: 3, b: 2}

iex> Map.replace!(%{a: 1}, :b, 2)
** (KeyError) key :b not found in: %{a: 1}

split(map, keys)

split(map(), Enumerable.t()) :: {map(), map()}

Берёт все записи, соответствующие заданным keys в map и извлекает их в отдельную карту.

Возвращает кортеж с новой картой и старой картой с удалёнными ключами.

Ключи, для которых нет записей в map игнорируются.

Примеры

iex> Map.split(%{a: 1, b: 2, c: 3}, [:a, :c, :e])
{%{a: 1, c: 3}, %{b: 2}}

take(map, keys)

take(map(), Enumerable.t()) :: map()

Возвращает новый словарь со всеми парами ключ-значение в map, где ключ находится в keys.

Если keys содержит ключи, которых нет в map, они просто игнорируются.

Примеры

iex> Map.take(%{a: 1, b: 2, c: 3}, [:a, :c, :e])
%{a: 1, c: 3}

to_list(map)

to_list(map()) :: [{term(), term()}]

Преобразует map в список.

Каждая пара ключ-значение в словаре преобразуется в кортеж из двух элементов {key, value} в результирующем списке.

Встраивается компилятором.

Примеры

iex> Map.to_list(%{a: 1})
[a: 1]
iex> Map.to_list(%{1 => 2})
[{1, 2}]

update!(map, key, fun)

update!(map(), key(), (value() -> value())) :: map()

Обновляет key с помощью заданной функции.

Если key присутствует в map со значением value, fun вызывается с аргументом value и ее результат используется в качестве нового значения key. Если key не присутствует в map, возникает исключение KeyError.

Примеры

iex> Map.update!(%{a: 1}, :a, &(&1 * 2))
%{a: 2}

iex> Map.update!(%{a: 1}, :b, &(&1 * 2))
** (KeyError) key :b not found in: %{a: 1}

update(map, key, initial, fun)

update(map(), key(), value(), (value() -> value())) :: map()

Обновляет key в map с помощью заданной функции.

Примеры

iex> Map.update(%{a: 1}, :a, 13, &(&1 * 2))
%{a: 2}
iex> Map.update(%{a: 1}, :b, 11, &(&1 * 2))
%{a: 1, b: 11}

values(map)

values(map()) :: [value()]

Возвращает все значения из map.

Встраивается компилятором.

Примеры

iex> Map.values(%{a: 1, b: 2})
[1, 2]