OptionParser

Этот модуль содержит функции для разбора командной строки.

Краткое описание

Типы

argv()
errors()
options()
parsed()

Функции

next(argv, opts \\ []): Функция низкого уровня, которая анализирует один параметр.
parse!(argv, opts \\ []): То же, что и parse/2, но вызывает исключение OptionParser.ParseError, если предоставлены какие-либо недопустимые параметры.
parse(argv, opts \\ []): Разбирает argv в список ключевых слов.
parse_head!(argv, opts \\ []): То же, что и parse_head/2, но вызывает исключение OptionParser.ParseError, если предоставлены какие-либо недопустимые параметры.
parse_head(argv, opts \\ []): Аналогично parse/2, но анализирует только начало argv; как только обнаруживает параметр, не являющийся переключателем, прекращает анализ.
split(string): Разбивает строку на куски типа argv/0.
to_argv(enum, opts \\ []): Принимает перечисляемый объект ключ-значение и преобразует его в argv/0.

Типы

argv()

argv() :: [String.t()]

errors()

errors() :: [{String.t(), String.t() | nil}]

options()

options() :: [switches: keyword(), strict: keyword(), aliases: keyword()]

parsed()

parsed() :: keyword()

Функции

next(argv, opts \\ [])

next(argv(), options()) ::
  {:ok, key :: atom(), value :: term(), argv()}
  | {:invalid, String.t(), String.t() | nil, argv()}
  | {:undefined, String.t(), String.t() | nil, argv()}
  | {:error, argv()}

Функция низкого уровня, которая анализирует один параметр.

Она принимает те же параметры, что и parse/2 и parse_head/2, так как обе функции основаны на этой функции. Эта функция может возвращать:

{:ok, key, value, rest} - параметр key с value был успешно проанализирован
{:invalid, key, value, rest} - параметр key недопустим с value (возвращается, когда значение не может быть проанализировано в соответствии с типом переключателя)
{:undefined, key, value, rest} - параметр key не определён (возвращается в строгом режиме, когда переключатель неизвестен или не существует атомов)
{:error, rest} - переключателей в начале заданного argv нет

parse!(argv, opts \\ [])

parse!(argv(), options()) :: {parsed(), argv()} | no_return()

То же, что и parse/2, но вызывает исключение OptionParser.ParseError, если предоставлены какие-либо недопустимые параметры.

Если ошибок нет, возвращает кортеж {parsed, rest}, где:

parsed — список проанализированных переключателей (так же, как в parse/2)
rest — список аргументов (так же, как в parse/2)

Примеры

iex> OptionParser.parse!(["--debug", "path/to/file"], strict: [debug: :boolean])
{[debug: true], ["path/to/file"]}

iex> OptionParser.parse!(["--limit", "xyz"], strict: [limit: :integer])
** (OptionParser.ParseError) 1 error found!
--limit : Expected type integer, got "xyz"

iex> OptionParser.parse!(["--unknown", "xyz"], strict: [])
** (OptionParser.ParseError) 1 error found!
--unknown : Unknown option

iex> OptionParser.parse!(["-l", "xyz", "-f", "bar"],
...>                     switches: [limit: :integer, foo: :integer], aliases: [l: :limit, f: :foo])
** (OptionParser.ParseError) 2 errors found!
-l : Expected type integer, got "xyz"
-f : Expected type integer, got "bar"

parse(argv, opts \\ [])

parse(argv(), options()) :: {parsed(), argv(), errors()}

Разбирает argv в список ключевых слов.

Возвращает кортеж из трёх элементов в формате {parsed, args, invalid}, где:

parsed — список ключевых слов проанализированных переключателей с кортежами {switch_name, value} в нём; switch_name — атом, представляющий имя переключателя, а value — значение для этого переключателя, проанализированное в соответствии с opts (см. раздел «Примеры» для получения дополнительной информации)
args — список оставшихся аргументов в argv в виде строк
invalid — список недопустимых параметров в виде {option_name, value}, где option_name — исходный параметр, а value — nil, если параметр не был ожидаем, или строковое значение, если значение не имело ожидаемого типа для соответствующего параметра

Elixir преобразует переключатели в атомы с нижним подчеркиванием, поэтому --source-path становится :source_path. Это сделано для лучшего соответствия соглашениям Elixir. Однако это означает, что переключатели не могут содержать нижние подчеркивания, а переключатели, содержащие нижние подчеркивания, всегда возвращаются в списке недопустимых переключателей.

При анализе обычно необходимо перечислить переключатели и ожидаемые типы:

iex> OptionParser.parse(["--debug"], strict: [debug: :boolean])
{[debug: true], [], []}

iex> OptionParser.parse(["--source", "lib"], strict: [source: :string])
{[source: "lib"], [], []}

iex> OptionParser.parse(["--source-path", "lib", "test/enum_test.exs", "--verbose"],
...>                    strict: [source_path: :string, verbose: :boolean])
{[source_path: "lib", verbose: true], ["test/enum_test.exs"], []}

Ниже мы рассмотрим допустимые переключатели и режимы работы парсера параметров.

Параметры

Поддерживаются следующие параметры:

:switches или :strict — см. раздел «Определения переключателей» ниже
:allow_nonexistent_atoms — см. раздел «Анализ неизвестных переключателей» ниже
:aliases — см. раздел «Псевдонимы» ниже

Определения переключателей

Переключатели можно указать с помощью одного из двух параметров:

:strict — определяет строгие переключатели. Любой переключатель в argv, который не указан в списке, возвращается в списке недопустимых параметров.
:switches — определяет некоторые переключатели и их типы. Эта функция всё равно пытается проанализировать переключатели, которые не находятся в этом списке.

Оба этих параметра принимают список ключевых слов кортежей {name, type}, где name — атом, определяющий имя переключателя, а type — атом, определяющий тип значения этого переключателя (см. раздел «Типы» ниже для возможных типов и дополнительной информации о приведении типов).

Обратите внимание, что вы должны указать только параметр :switches или параметр :strict. Если вы укажете оба параметра, будет вызвано исключение ArgumentError.

Типы

Переключатели, проанализированные функцией OptionParser, могут принимать ноль или один аргумент.

Следующие типы переключателей не принимают аргументов:

:boolean — устанавливает значение в true при его предоставлении (см. также раздел «Отрицающие переключатели» ниже)
:count — считает количество раз, когда переключатель задан

Следующие переключатели принимают один аргумент:

:integer — анализирует значение как целое число
:float — анализирует значение как число с плавающей точкой
:string — анализирует значение как строку

Если переключатель не может быть проанализирован в соответствии с заданным типом, он возвращается в списке недопустимых параметров.

Модификаторы

Переключатели могут быть указаны с модификаторами, которые изменяют их поведение. Поддерживаются следующие модификаторы:

:keep — сохраняет дублированные элементы вместо их перезаписи; работает со всеми типами, кроме :count. Указание switch_name: :keep предполагает, что тип :switch_name будет :string.

Чтобы использовать :keep с типом, отличным от :string, используйте список в качестве типа переключателя. Например: [foo: [:integer, :keep]].

Отрицающие переключатели

Если переключатель SWITCH задан с типом :boolean, его можно также передать как --no-SWITCH, что установит параметр в значение false.

iex> OptionParser.parse(["--no-op", "path/to/file"], switches: [op: :boolean])
{[op: false], ["path/to/file"], []}

Анализ неизвестных переключателей

Когда указан параметр :switches, OptionParser попытается проанализировать неизвестные переключатели.

iex> OptionParser.parse(["--debug"], switches: [key: :string])
{[debug: true], [], []}

Хотя мы не указали --debug в списке переключателей, он входит в возвращаемые параметры. Это также сработает:

iex> OptionParser.parse(["--debug", "value"], switches: [key: :string])
{[debug: "value"], [], []}

Переключателям, за которыми следует значение, будет присвоено это значение в виде строки. Переключатели без аргумента будут автоматически установлены в значение true. Поскольку мы не можем гарантировать тип значения переключателя, рекомендуется использовать параметр :strict, принимающий только известные переключатели, и всегда проверять их типы.

Если вы всё же хотите анализировать неизвестные переключатели, помните, что Elixir преобразует переключатели в атомы. Поскольку атомы не подлежат сборке мусора, OptionParser будет анализировать только переключатели, которые преобразуются в атомы, используемые во время выполнения, чтобы избежать утечки атомов. Например, код ниже отбросит переключатель --option-parser-example, потому что атом :option_parser_example нигде не используется:

OptionParser.parse(["--option-parser-example"], switches: [debug: :boolean])
# The :option_parser_example atom is not used anywhere below

Однако код ниже будет работать, пока атом :option_parser_example используется где-то позже (или раньше) в том же модуле:

{opts, _, _} = OptionParser.parse(["--option-parser-example"], switches: [debug: :boolean])
opts[:option_parser_example]

Другими словами, Elixir сделает правильную вещь и проанализирует только параметры, которые используются во время выполнения, игнорируя все остальные. Если вы хотите проанализировать все переключатели, независимо от их существования, вы можете принудительно создать атомы, передав allow_nonexistent_atoms: true в качестве параметра. Используйте этот параметр с осторожностью. Он полезен только при создании приложений командной строки, которые получают динамически именованные аргументы, и его следует избегать в долгоживущих системах.

Псевдонимы

Набор псевдонимов можно указать в параметре :aliases:

iex> OptionParser.parse(["-d"], aliases: [d: :debug], strict: [debug: :boolean])
{[debug: true], [], []}

Примеры

Вот несколько примеров работы с разными типами и модификаторами:

iex> OptionParser.parse(["--unlock", "path/to/file"], strict: [unlock: :boolean])
{[unlock: true], ["path/to/file"], []}

iex> OptionParser.parse(["--unlock", "--limit", "0", "path/to/file"],
...>                    strict: [unlock: :boolean, limit: :integer])
{[unlock: true, limit: 0], ["path/to/file"], []}

iex> OptionParser.parse(["--limit", "3"], strict: [limit: :integer])
{[limit: 3], [], []}

iex> OptionParser.parse(["--limit", "xyz"], strict: [limit: :integer])
{[], [], [{"--limit", "xyz"}]}

iex> OptionParser.parse(["--verbose"], switches: [verbose: :count])
{[verbose: 1], [], []}

iex> OptionParser.parse(["-v", "-v"], aliases: [v: :verbose], strict: [verbose: :count])
{[verbose: 2], [], []}

iex> OptionParser.parse(["--unknown", "xyz"], strict: [])
{[], ["xyz"], [{"--unknown", nil}]}

iex> OptionParser.parse(["--limit", "3", "--unknown", "xyz"],
...>                    switches: [limit: :integer])
{[limit: 3, unknown: "xyz"], [], []}

iex> OptionParser.parse(["--unlock", "path/to/file", "--unlock", "path/to/another/file"], strict: [unlock: :keep])
{[unlock: "path/to/file", unlock: "path/to/another/file"], [], []}

parse_head!(argv, opts \\ [])

parse_head!(argv(), options()) :: {parsed(), argv()} | no_return()

То же самое, что и parse_head/2, но при наличии каких-либо недопустимых опций генерирует исключение OptionParser.ParseError.

Если ошибок нет, возвращает кортеж {parsed, rest}, где:

parsed — список обработанных переключателей (такой же, как в parse_head/2)
rest — список аргументов (такой же, как в parse_head/2)

Примеры

iex> OptionParser.parse_head!(["--source", "lib", "path/to/file", "--verbose"],
...>                         switches: [source: :string, verbose: :boolean])
{[source: "lib"], ["path/to/file", "--verbose"]}

iex> OptionParser.parse_head!(["--number", "lib", "test/enum_test.exs", "--verbose"],
...>                          strict: [number: :integer])
** (OptionParser.ParseError) 1 error found!
--number : Expected type integer, got "lib"

iex> OptionParser.parse_head!(["--verbose", "--source", "lib", "test/enum_test.exs", "--unlock"],
...>                          strict: [verbose: :integer, source: :integer])
** (OptionParser.ParseError) 2 errors found!
--verbose : Missing argument of type integer
--source : Expected type integer, got "lib"

parse_head(argv, opts \\ [])

parse_head(argv(), options()) :: {parsed(), argv(), errors()}

Аналогично parse/2, но обрабатывает только начало argv; как только встречается элемент, не являющийся переключателем, обработка прекращается.

Дополнительную информацию см. в parse/2.

Пример

iex> OptionParser.parse_head(["--source", "lib", "test/enum_test.exs", "--verbose"],
...>                         switches: [source: :string, verbose: :boolean])
{[source: "lib"], ["test/enum_test.exs", "--verbose"], []}

iex> OptionParser.parse_head(["--verbose", "--source", "lib", "test/enum_test.exs", "--unlock"],
...>                         switches: [source: :string, verbose: :boolean, unlock: :boolean])
{[verbose: true, source: "lib"], ["test/enum_test.exs", "--unlock"], []}

split(string)

split(String.t()) :: argv()

Разделяет строку на фрагменты argv/0.

Эта функция разделяет заданную string на список строк, аналогично многим оболочкам.

Примеры

iex> OptionParser.split("foo bar")
["foo", "bar"]

iex> OptionParser.split("foo \"bar baz\"")
["foo", "bar baz"]

to_argv(enum, opts \\ [])

to_argv(Enumerable.t(), options()) :: argv()

Принимает перечислимый объект ключ-значение и преобразует его в argv/0.

Ключи должны быть атомами. Ключи со значением nil игнорируются, булевы значения преобразуются в --key или --no-key (если значение соответственно true или false ), а все остальные значения преобразуются с помощью Kernel.to_string/1.

Рекомендуется передавать в to_argv/2 тот же набор options опций, что и в parse/2. Некоторые переключатели могут быть корректно восстановлены только при наличии информации switches.

Примеры

iex> OptionParser.to_argv(foo_bar: "baz")
["--foo-bar", "baz"]
iex> OptionParser.to_argv(bool: true, bool: false, discarded: nil)
["--bool", "--no-bool"]

Некоторые переключатели будут выводить разные значения в зависимости от флага переключателей:

iex> OptionParser.to_argv([number: 2], switches: [])
["--number", "2"]
iex> OptionParser.to_argv([number: 2], switches: [number: :count])
["--number", "--number"]